AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TList 10.1 Berlin vs 10.3 Rio

Ein Thema von Int3g3r · begonnen am 18. Aug 2020 · letzter Beitrag vom 18. Aug 2020
Antwort Antwort
Seite 1 von 2  1 2   
Int3g3r

Registriert seit: 28. Nov 2018
Ort: Schweiz
118 Beiträge
 
Delphi 10.3 Rio
 
#1

TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 11:42
Delphi-Version: 10.3 Rio
Guten Tag,

Ich verwende unter Delphi 10.3 Rio folgende routine:

Delphi-Quellcode:
procedure Tfrm_Umsatz_Statistik.GUIUmsatzMitKunde(_visible: boolean);
var elements : TList;
      ele : TObject;
begin
   elements := Tlist.Create;
   elements.Add(Label3);
   elements.Add(lblDatumUnbestimmt);
   elements.Add(ChkBoxDatumsbereich);
   elements.Add(chkBoxGattungSelect);
   elements.Add(lblTitelGattung);
   elements.Add(ChkBoxAlleGattung);
   elements.Add(Label7);


   for ele in elements do
   begin
       if ele is TLabel then
       begin
            Tlabel(ele).Visible := _visible;
       end
       else if ele is TCheckBox then
       begin
            TCheckBox(ele).Visible := _visible;
       else if ele is TListBox then
       begin
            TListBox(ele).Visible := _visible;
       end;
   end;
   elements.Free;
end;
Lässt sich unter 10.3 Rio ohne weiteres compillieren.

Unter 10.1 erhalte ich folgende Fehlermeldung:
Zitat:
[dcc32 Fehler] form_Umsatz_Statistik.pas(1412): E2010 Inkompatible Typen: 'TObject' und 'Pointer'
Die Fehlermeldung ist bezogen auf die for-in-Schleife.

Wie lässt sich diese procedure in 10.1 verwenden ?

Ich habe es versucht mit Pointern wie folgt zu realisieren :
Delphi-Quellcode:
procedure Tfrm_Umsatz_Statistik.GUIUmsatzMitKunde(_visible: boolean);
var elements : TList;
      ele : ^TObject;
begin
   elements := Tlist.Create;
   elements.Add(Label3);
   elements.Add(lblDatumUnbestimmt);
   elements.Add(ChkBoxDatumsbereich);
   elements.Add(chkBoxGattungSelect);
   elements.Add(lblTitelGattung);
   elements.Add(ChkBoxAlleGattung);
   elements.Add(Label7);


   for ele in elements do
   begin
       if ele^ is TLabel then
       begin
            Tlabel(ele^).Visible := _visible;
       end
       else if ele^ is TCheckBox then
       begin
            TCheckBox(ele^).Visible := _visible;
       else if ele^ is TListBox then
       begin
            TListBox(ele^).Visible := _visible;
       end;
   end;
   elements.Free;
end;
Hier erhalte ich eine access-violation beim dereferenzieren zur Laufzeit. An der Stelle if ele^ is TLabel then

Gruss Int3g3r
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
3.055 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 11:55
Mach doch ne generische elements : TList<TControl>; draus;

Delphi-Quellcode:
procedure Tfrm_Umsatz_Statistik.GUIUmsatzMitKunde(_visible: boolean);
var
  Controls: TList<TControl>;
  Control: TControl;
begin
  Controls := TList<TControl>.Create;
  try
    Controls.Add(Label3);
    Controls.Add(lblDatumUnbestimmt);
    Controls.Add(ChkBoxDatumsbereich);
    Controls.Add(chkBoxGattungSelect);
    Controls.Add(lblTitelGattung);
    Controls.Add(ChkBoxAlleGattung);
    Controls.Add(Label7);

    for Control in Controls do
    begin
        Control.Visible := _visible
    end;
  finally
    Controls.Free;
  end;
end;
  Mit Zitat antworten Zitat
UliBru

Registriert seit: 10. Mai 2010
152 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 12:18
What about
Delphi-Quellcode:
procedure TTestForm.Button1Click(Sender: TObject);
var
  elements: TList;
  i: integer;
begin
  elements := TList.Create;
  try
    elements.Add(Label1);
    for i := 0 to elements.Count - 1 do
    begin
      if TObject(elements.Items[i]) is TLabel then
        TLabel(elements.Items[i]).Visible := true;
    end;
  finally
    elements.Free;
  end;
end;
?

Grüsse
Uli
Er wollte so richtig in Delphi einsteigen. Nun steckt er ganz tief drin ...
  Mit Zitat antworten Zitat
Int3g3r

Registriert seit: 28. Nov 2018
Ort: Schweiz
118 Beiträge
 
Delphi 10.3 Rio
 
#4

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 12:32
Vielen Dank für die Lösungsvorschläge.
Die Generische Liste zu verwenden ist wohl die einfachste Lösung.

Trotzdem möchte ich wissen warum ich eine access-violation erhalte im Beispiel mit dem Pointer oben.
Solche Fehlermeldungen sind für mich sehr schwierig nachvollziebar.

if ele^ is TLabel then ist doch fast das gleiche wie TObject(elements.Items[i]) is TLabel then ?!
Darum habe ich oben auch ein typisierten-^TObject-Pointer genommen, somit wird beim dereferenzieren der Wert/Objekt in ein TObject gecastet.

Gruss Int3g3r
  Mit Zitat antworten Zitat
UliBru

Registriert seit: 10. Mai 2010
152 Beiträge
 
Delphi 11 Alexandria
 
#5

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 12:37
Ich hab noch mal weitergespielt:
Delphi-Quellcode:
procedure TTestForm.Button1Click(Sender: TObject);
var
  elements: TList;
  ele: Pointer;
begin
  elements := TList.Create;
  try
    elements.Add(Label1);
    for ele in elements do
    begin
      if TObject(ele) is TLabel then
        TLabel(ele).Visible := true;
    end;
  finally
    elements.Free;
  end;
end;
TList enhält eine Liste von Pointern. Mit ele vom Typ Pointer klappts denn auch.

Grüsse
Uli
Er wollte so richtig in Delphi einsteigen. Nun steckt er ganz tief drin ...
  Mit Zitat antworten Zitat
Int3g3r

Registriert seit: 28. Nov 2018
Ort: Schweiz
118 Beiträge
 
Delphi 10.3 Rio
 
#6

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 13:17
Ich hab noch mal weitergespielt:
TList enhält eine Liste von Pointern. Mit ele vom Typ Pointer klappts denn auch.
Grüsse
Uli
Danke Uli!
Warum muss man bei TObject(ele) nicht dereferenzieren ?
Ich möchte ja das Objekt an der Adresse "ele" casten und nicht die Adresse selbst.
TObject(ele) lese ich so das die Adresse "ele" in ein TObject gecastet wird, dies sollte aber nicht möglich sein.

Gruss Int3g3r
  Mit Zitat antworten Zitat
Benutzerbild von Bernhard Geyer
Bernhard Geyer

Registriert seit: 13. Aug 2002
17.169 Beiträge
 
Delphi 10.4 Sydney
 
#7

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 13:43
Wieso nicht das?

https://www.delphipraxis.net/1471996-post2.html
Windows Vista - Eine neue Erfahrung in Fehlern.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
42.982 Beiträge
 
Delphi 12 Athens
 
#8

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 14:17
Du hast eine TList mit Pointern, also muß ele ein Pointer sein.
Delphi-Quellcode:
var ele: Pointer;

for ele in elements do
  if TObject(ele) is ... then
Man kann sowas versuchen, aber leider mag der Compiler das oft nicht. "... muß eine Variable sein, bla bla bla"
Delphi-Quellcode:
var ele: TObject;

for Pointer(ele) in elements do
Oder man ist mal etwas böse.
Delphi-Quellcode:
var
  _ele: Pointer;
  ele: TObject absolute _ele;

for _ele in elements do
  if ele is ... then

Wieso keine TObjektList oder gar eine generische TList<TObject> (oder TComponent/TMyIrgendwas/...) ?



Und ja, da hier überall VISIBLE vorkommt, ist es eigentlich nötig sich den gemeinsamen Vorfahren rauszusuchen und dann das nur einmal zu machen.
Da Visible aber in der Basis protected ist, und man hier weiß, dass ALLEs ein Visible (das Selbe) hat, kann man hier auch blind in einen Typen casten, wo es public ist ... siehe UliBru.

Delphi-Quellcode:
procedure TTestForm.Button1Click(Sender: TObject);
var ele: Pointer;

for ele in elements do
  if TObject(ele) is TControl then
    TLabel(ele).Visible := true;
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu (18. Aug 2020 um 14:54 Uhr)
  Mit Zitat antworten Zitat
Rollo62
Online

Registriert seit: 15. Mär 2007
3.863 Beiträge
 
Delphi 12 Athens
 
#9

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 14:47

Oder man ist mal etwas böse.
Delphi-Quellcode:
var
  _ele: Pointer;
  ele: TObject absolute _ele;

for _ele in elements do
  if ele is ... then
Wieso böse, ist das kein valider Code ?
Ich denke das ist gensu für sowas erfunden worden
  Mit Zitat antworten Zitat
Int3g3r

Registriert seit: 28. Nov 2018
Ort: Schweiz
118 Beiträge
 
Delphi 10.3 Rio
 
#10

AW: TList 10.1 Berlin vs 10.3 Rio

  Alt 18. Aug 2020, 14:49
Wieso keine TObjektList oder gar eine generische TList<TObject> (oder TComponent/TMyIrgendwas/...) ?
Was bietet mir eine TObjectList im gegensatz zu einer TList ?
Bei einer TObjectList ist es noch notwendig eine unit einzubinden.
Den Namen dieser unit vergesse ich sehr schnell daher ist es für mich einfacher mit einer TList zu arbeiten.
In meinem Fall ist es doch nicht notwenig eine TObjectList zu benutzen, eine TList reicht komplett aus für mein vorhaben.
Dazu kommt das eine TObjectList auch einen Pointer erwartet.

Somit ist dann eine generische TList<> die bessere Wahl.

Mir geht es aber darum etwas zu lernen. Damit ich mir bei solchen Problemen selbst helfen könnte.
Daher möchte ich auch wissen warum das obere Beispiel mit dem Pointer nicht funktioniert.
ele : ^TObject ist auch ein Pointer.
Warum muss beim casten von TObject(ele) der Pointer nicht dereferenziert werden ?
Warum erhalte ich bei meinem Beispiel(mit Pointer) oben eine access-violation exception ?

Gruss Int3g3r

Geändert von Int3g3r (18. Aug 2020 um 14:51 Uhr)
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 09:25 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz