AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Call by value statt Call by reference

Ein Thema von Maliko · begonnen am 20. Okt 2020 · letzter Beitrag vom 20. Okt 2020
Antwort Antwort
Maliko

Registriert seit: 20. Jun 2019
44 Beiträge
 
Delphi 10.3 Rio
 
#1

Call by value statt Call by reference

  Alt 20. Okt 2020, 08:41
Moin,

ich hätte da mal ne Frage zu den Objektübergaben in Delphi. Ich musste mir Delphi für die Arbeit in innerhalb weniger Tage selbst beibringen und daher fehlen mir doch noch einige wichtige Grundlagen. Jetzt stehe ich vor genau so einem Problem, wo meine Kenntnisse in Delphi nicht mehr ausreichen. Daher hoffe ich dass ihr mir da vielleicht kurz auf die Sprünge helfen könntet.

Und zwar habe ich ein TJSONArray, in welches ich mehrere TJSONObjects speichern möchte. Die Datenbasis befindet sich in einer TList, welche ich mit einer for-Schleife durchlaufe. Die einzelnen TList-Objekt-Values schmeiße ich anschließend mit AddPair in das JSONObject wofür ich mir ein Objekt erstellt habe. Anschließend landet das JSONObject im JSONArray und das JSONObject wird mit FreeAndNil wieder freigegeben und im nächsten Schleifendurchlauf neu erstellt.

Das Problem an der Sache ist, dass sobald ich das JSONObject mit FreeAndNil wieder freigebe, auch im JSONArray nur noch leere Objekte vorhanden sind. Über die Add-Funktion des JSONArrays wird an das Array nämlich scheinbar nur der Pointer des JSONObjects übergeben und nicht das JSONObject an sich. Wenn ich jetzt aber das JSONObject nicht freigebe, wird es ja immer mehr Platz im Arbeitsspeicher benötigen und damit zu nem MemoryLeak führen, oder werden Variablen die ein Teil von Result sind auch automatisch wieder freigegeben?

Nun meine Frage. Wie bitte kann ich dem Compiler sagen, dass er bitte das komplette Objekt übergeben soll (also call by value, sprich das Objekt wird in das Array kopiert) und nicht nur den Pointer. In anderen Sprachen kann ich das lösen indem ich vor die Variable noch ein entsprechendes Zeichen setze (bei PHP z.B. das &). Nur wie funktioniert das in Delphi?

Ich hab das ganze jetzt gelöst indem ich die Methode ObjectToJsonObject verwendet habe, aber wie das allgemein Funktioniert würde mich sehr interessieren, da ich wahrscheinlich nicht immer die Möglichkeit haben werde auf soweis ausweichen zu können. Vielen Dank schon einmal im Voraus.

Viele Grüße
Maliko

Geändert von Maliko (20. Okt 2020 um 08:43 Uhr)
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.787 Beiträge
 
Delphi 10 Seattle Enterprise
 
#2

AW: Call by value statt Call by reference

  Alt 20. Okt 2020, 09:24
Du machst dir das zu kompliziert. Du musst das, was du in dein JSON-Array reinsteckst nicht nachhalten um es irgendwann freizugeben. Das JSON-Array selbst muss alles, was in ihm drin steckt auch mit freigeben wenn es sich freigibt.

Das ist genauso wie bei einer TObjectList<T> im Vergleich zu einer TList<T>. Erstere gibt die in im enthaltenen Objekte auch mit frei.

Falls ich dein Problem nicht falsch verstanden habe bringt dich das Beispiel hier hoffentlich weiter:

Delphi-Quellcode:
program Project1;

{$APPTYPE CONSOLE}
{$R *.res}

uses System.SysUtils, System.JSON, System.Generics.Collections, Rest.Json;

type
   TPerson = class
      var name: String;
   end;

function createPersonList(): TList<TPerson>;
var
   newPerson: TPerson;
begin
   Result := TObjectList<TPerson>.Create({ownsObjects:}True);

   newPerson := TPerson.Create();
   newPerson.name := 'Jupp Schmitz';
   Result.Add(newPerson);

   newPerson := TPerson.Create();
   newPerson.name := 'Dagobert Duck';
   Result.Add(newPerson);
end;

procedure fillJsonArray(
   const jsonArray: TJSONArray;
   const persons: TList<TPerson>
);
var
   asJsonObject: TJsonObject;
   person: TPerson;
begin
   for person in persons do
      begin
         asJsonObject := Rest.Json.TJson.ObjectToJsonObject(person);
         jsonArray.Add(asJsonObject);
         // Das TJsonObject gehört nun zum JSON-Array. Wenn das JSON-Array
         // freigegeben wird, dann auch alles was in ihm drinsteckt
      end;
end;

procedure p();
var
   personList: TList<TPerson>;
   jsonArray: TJsonArray;
begin
   personList := nil;
   jsonArray := nil;

   try
      personList := createPersonList();
      jsonArray := TJsonArray.Create();
      fillJsonArray(jsonArray, personList);

      WriteLn( jsonArray.ToString() );
   finally
      jsonArray.Free();
      personList.Free();
   end;
end;

begin
   p();
   readln;
end.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 22:40 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf