AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

unit von Delphi 2005 nach RIO

Ein Thema von dpKlaus · begonnen am 1. Nov 2020 · letzter Beitrag vom 3. Nov 2020
Antwort Antwort
dpKlaus

Registriert seit: 1. Nov 2020
7 Beiträge
 
#1

unit von Delphi 2005 nach RIO

  Alt 1. Nov 2020, 03:58
Guten Morgen,

ich versuche mich gerade daran eine Unit von Delphi 2005 nach Delphi RIO (Community Edition) zu übertragen. Strings wurden in WideString und hPrinter wurde von Cardinal zu. THandle. Es läßt sich auch fehlerfrei kompilieren. Allerdings bekomme ich kein Ergebnis. Die function OpenPrinter liefert kein Ergebnis.

Was mache ich falsch?

Der Quelltext:
Delphi-Quellcode:
unit RawPrint;

{ Invisible Printer Component that allows to send stuff directly to the spooler,
  bypassing the printer driver. Ideal for bar code printers and other stuff.
  Modelled by [email]bhoc@surfeu.ch[/email]
  This code is GPL.
  HOWTO:
  MyPrinter := TRawPrint.Create(nil);
  MyPrinter.DeviceName := 'HP LaserJet Series II';
  MyPrinter.JobName := 'europos';
  if MyPrinter.OpenDevice then
  begin
    MyPrinter.WriteString('This is page 1');
    MyPrinter.NewPage;
    MyPrinter.WriteString('This is page 2');
    MyPrinter.CloseDevice;
  end;
  MyPrinter.Destroy;
}


// {$ASSERTIONS OFF}

interface

uses
  Windows, WinSpool, Printers, Dialogs, Classes;

type
  TError = procedure(Sender: TObject; var ErrorMessage: String) of object;
  TRawPrint = class(TComponent)
  private
    { Private declarations }
// MyDeviceName: String;
    MyDeviceName: WideString;
    MyJobName: String;
    MyError: TError;
// hPrinter: Cardinal;
    hPrinter: THandle;
    IsOpenDevice: Boolean;
    IsOpenPage: Boolean;
  protected
    { Protected declarations }
    function GetLastErrMsg: String;
    procedure RaiseError(ErrMsg: String);
  public
    { Public declarations }
    function OpenDevice: Boolean;
    function CloseDevice: Boolean;
    function WriteString(Text: String): Boolean;
    function NewPage: Boolean;
    procedure SelectPrinter;
    constructor Create(AOwner : TComponent); override;
    destructor Destroy; override;
  published
    { Published declarations }
// property DeviceName: WideString read MyDeviceName write MyDeviceName;
    property DeviceName: widestring read MyDeviceName write MyDeviceName;
    property JobName: String read MyJobName write MyJobName;
    property OnError: TError read MyError write MyError;
  end;

procedure Register;

implementation

constructor TRawPrint.Create(AOwner : TComponent);
begin
  inherited;
  MyDeviceName := Printer.Printers.Strings[Printer.PrinterIndex];
  MyJobName := 'RawPrint';
  IsOpenDevice := False;
  IsOpenPage := False;
end;

destructor TRawPrint.Destroy;
begin
  if IsOpenDevice then CloseDevice;
  inherited;
end;


procedure Register;
begin
  RegisterComponents('bhoc@surfeu.ch', [TRawPrint]);
end;


function TRawPrint.OpenDevice: Boolean;
type _DocInfo = record
// pDocName: PChar;
// pOutputFile: PChar;
// pDatatype: PChar;
                  pDocName: PAnsiChar;
                  pOutputFile: PAnsiChar;
                  pDatatype: PAnsiChar;
                end;
var DocInfo: _DocInfo;
begin
  Result := True;

// if not OpenPrinter(PChar(DeviceName), hPrinter, nil) then
  if not OpenPrinter((@DeviceName), hPrinter, nil) then
  begin
    RaiseError(GetLastErrMsg);
    Result := False;
  end else begin
    DocInfo.pDocName := pAnsiChar(JobName);
    DocInfo.pOutputFile := pAnsiChar(#0);
    DocInfo.pDatatype := pAnsiChar(#0);
    if StartDocPrinter(hPrinter, 1, @DocInfo) = 0 then begin
      RaiseError(GetLastErrMsg);
      ClosePrinter(hPrinter);
      Result := False;
    end else begin
      IsOpenDevice := True;
      NewPage;
    end;
  end;

end;

function TRawPrint.NewPage: Boolean;
begin
  Result := True;
  if IsOpenDevice then begin
    if IsOpenPage then begin
      if not EndPagePrinter(hPrinter) then begin
        RaiseError(GetLastErrMsg);
      end;
    end;
    if not StartPagePrinter(hPrinter) then begin
      RaiseError(GetLastErrMsg);
      Result := False;
    end else begin
      IsOpenPage := True;
    end;
  end;
end;

function TRawPrint.WriteString(Text: String): Boolean;
var WrittenChars: Cardinal;
begin
  Result := False;
  if IsOpenDevice then begin
    Result := True;
    if not WritePrinter(hPrinter, PChar(Text), Length(Text), WrittenChars) then begin
      RaiseError(GetLastErrMsg);
      Result := False;
    end;
  end;
end;

function TRawPrint.CloseDevice: Boolean;
begin
  Result := True;
  if IsOpenDevice then begin
    if IsOpenPage then begin;
      if not EndPagePrinter(hPrinter) then begin
        RaiseError(GetLastErrMsg);
      end;
    end;
    if not EndDocPrinter(hPrinter) then begin
      RaiseError(GetLastErrMsg);
      Result := False;
    end else begin
      if not ClosePrinter(hPrinter) then begin
        RaiseError(GetLastErrMsg);
        Result := False;
      end else begin
        Result := True;
        IsOpenDevice := False;
      end;
    end;
  end;
end;

procedure TRawPrint.RaiseError(ErrMsg: String);
begin
  if Assigned(OnError) then MyError(Self,ErrMsg);
end;

function TRawPrint.GetLastErrMsg: String;
var Buf: Array[0..499] of char;
    BufLen: Integer;
begin
  BufLen := FormatMessage(FORMAT_MESSAGE_FROM_SYSTEM, nil, GetLastError, 0, Buf, SizeOf(Buf), nil);
  Result := Copy(Buf, 1, BufLen);
end;

Procedure TRawPrint.SelectPrinter;
var PrtDlg: TPrintDialog;
begin
  PrtDlg := TPrintDialog.Create(Self);
  prtdlg.Options := [poPrintToFile];
  if PrtDlg.Execute then begin
    DeviceName := Printer.Printers.Strings[Printer.PrinterIndex];
  end;
  PrtDlg.Free;
end;

end.

Geändert von TBx ( 2. Nov 2020 um 05:57 Uhr) Grund: Delphi-Tags gesetzt
  Mit Zitat antworten Zitat
Benutzerbild von jaenicke
jaenicke

Registriert seit: 10. Jun 2003
Ort: Berlin
8.177 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: unit von Delphi 2005 nach RIO

  Alt 1. Nov 2020, 10:06
Hallo und willkommen!

Die erste Zeile, die auskommentiert ist, ist korrekt:
Delphi-Quellcode:
if not OpenPrinter(PChar(DeviceName), hPrinter, nil) then
begin
Alternativ ginge es auch so:
Delphi-Quellcode:
if not OpenPrinter(@DeviceName[1], hPrinter, nil) then
begin
Hintergrund ist, dass DeviceName ein Pointer auf den String mit dem Druckernamen ist. Wenn du nun einen Pointer auf DeviceName nimmst, hast du die Adresse des Pointers auf den Druckernamen. Du musst aber die Adresse des Druckernamens übergeben. Deshalb kannst du den Pointer auf das erste Zeichen übergeben.

Es geht daher auch so:
Delphi-Quellcode:
if not OpenPrinter(Pointer(DeviceName), hPrinter, nil) then
begin
Am sinnvollsten ist aber die erste Variante mit dem Cast auf PChar, weil man dann direkt sieht was gemeint ist.
Sebastian Jänicke
Alle eigenen Projekte sind eingestellt, ebenso meine Homepage, Downloadlinks usw. im Forum bleiben aktiv!
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
8.936 Beiträge
 
Delphi 10.4 Sydney
 
#3

AW: unit von Delphi 2005 nach RIO

  Alt 1. Nov 2020, 10:34
Im weiteren Verlauf sind auch alle PAnsiChar in PChar zu ändern, da du mit den Unicode-Versionen der Api arbeitest. Dann ist in WriteString noch zu beachten, dass WritePrinter einen Byte-Buffer erwartet, Text aber ein 2-Byte String ist.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
dpKlaus

Registriert seit: 1. Nov 2020
7 Beiträge
 
#4

AW: unit von Delphi 2005 nach RIO

  Alt 1. Nov 2020, 13:36
Vielen Dank für die Hinweise und Hilfe. Da mach ich mich an die Arbeit.

Ich hatte wohl auch ein Problem mit dem Ansprechen des Druckers. Ich arbeite in einem RemoteDesktop da werden die Drucker mit Nummern versehen wenn sie vom Hauptrechner bereit gestellt werden. Lesen von GetLastErrMsg half!!!

Viele Grüße
Miniaturansicht angehängter Grafiken
drucker.jpg  
  Mit Zitat antworten Zitat
Frickler

Registriert seit: 6. Mär 2007
Ort: Osnabrück
383 Beiträge
 
Delphi XE6 Enterprise
 
#5

AW: unit von Delphi 2005 nach RIO

  Alt 3. Nov 2020, 09:54
Diese Nummer ist die "Session ID".

Man kann sie ermitteln mittels

Code:
var SessionID: cardinal;

...

ProcessIdToSessionID(GetCurrentProcessId, SessionID)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 17:02 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf