Mein Programm (-feature) zur Abfrage von Metadaten von Spotify funktioniert nach ausgesprochen mühsamer Einarbeitung(siehe hier) mittlerweile im Großen und Ganzen so, wie es soll. Nicht ganz unerwartet taucht aber mal wieder ein neues Problem auf. Das Accesstoken, das bei der Authentifizierung zugeteilt wird, ist ja nur eine begrenzte Zeit (1 Stunde) gültig. So geschah es, dass irgendwann die Daten-Übertragung von Spotify unvermittelt abbrach, weil die Gültigkeitsdauer des Accesstoken abgelaufen war. Nun versuche ich seit Tagen, eine Abfrage für ein neues Accesstoken zu implementieren. Dabei müssen in einem Post - Request einige Daten übermittelt werden (s.Anhang). Bisher ist mir das leider nicht gelungen. Ich bekomme immer nur einen Error 400 (Bad Request).

zusammenfalten · markieren

Delphi-Quellcode:

Function TSpManager.GetRefreshToken:string;
  var s,EncodedAccessData: string;
       Client: TRestClient;
       Request: TRESTRequest;
begin
  Client := TRestClient.Create('https://accounts.spotify.com/api/token');
  try
    s := stcf.AccessData.clientID + ':' + stcf.AccessData.clientsecret;
    EncodedAccessData := TNetEncoding.Base64.Encode(s);
    //showmessage(s + #13#10 + encoded);
    Request := TRESTRequest.Create(Client);
    Request.Method := TRESTRequestMethod.rmPOST;
    Request.AddParameter('Authorization', 'Basic ' + EncodedAccessData, pkHTTPHEADER);
    Request.AddBody('grant_type=refresh_token', ctAPPLICATION_X_WWW_FORM_URLENCODED);
    Request.AddBody('refresh_token=' + stcf.AccessData.RefreshToken, ctAPPLICATION_X_WWW_FORM_URLENCODED);
    Request.Execute;

    [...]

  finally
    FreeAndNIL(Client);
  end;

stcf.AccessData.RefreshToken enthält den bei der Authentifizierung zugeteilten Refresh-Token.
Was mache ich falsch?

Hast Du es einmal mit PlainText versucht? Bei meinem PayPal-Problem hat das geholfen.

Zitat von DeddyH:

Hast Du es einmal mit PlainText versucht? Bei meinem PayPal-Problem hat das geholfen.

Die Doku zur Spotify Web API verlangt ausdrücklich die Codierung als application/x-www-form-urlencoded (siehe Anhang)

Gruß LP

Die von PayPal auch, trotzdem funktioniert es nur mit PlainText.

Alle Versuche waren leider vergeblich, ich habe es (vorerst) aufgegeben. Als Workaround starte ich aus meinem Programm das Kommandozeilen-Tool 'Curl', mit Parametern wie im Spotify Web API Authorization Guide beschrieben (S.Anhang in #3). Das funktionierte auf Anhieb einwandfrei. Aber das wird mir sicherlich keine Ruhe lassen, bis ich doch eine 'ordentliche' Lösung gefunden habe

Gruß LP

Heureka!
Ich bin ja hartnäckig, ja geradezu gnadenlos, wenn es darum geht, ein Problem, in das ich mich einmal verbissen habe, doch noch zu lösen. Nach unzähligen Versuchen und dem Studium etlicher Beiträge im DP-Archiv und anderer Quellen im Netz, wo es immer wieder Hinweise auf mögliche Fehlerquellen gab, hat es dann wirklich geklappt. Ich war tatsächlich etwas überrascht, als irgendwann das 'Request.Execute' ohne Fehlermeldung durchlief und das korrekte Ergebnis zu sehen war.
Hier der Code:

zusammenfalten · markieren

Delphi-Quellcode:

Function TSpManager.GetRefreshToken(Quiet: Boolean):Boolean;
  var s,Encoded: string;
       Client: TRestClient;
       Request: TRESTRequest;
       Response: TRestResponse;
       MValue:TJSONValue;
begin
  result:= false;
  Client := TRestClient.Create('https://accounts.spotify.com/api/token');
  Response := TREStResponse.Create(NIL);
  Request := TRESTRequest.Create(NIL);
  try
    s := stcf.AccessData.clientID + ':' + stcf.AccessData.clientsecret;
    Encoded:= replacestr(TNetEncoding.Base64.Encode(s),#13#10,''); // Zeilen-Umbruch entfernen
    Client.contentType := 'application/x-www-form-urlencoded';
    Request.Client := Client;
    Request.Response := Response;
    Request.Method := rmPOST;
    Request.AddParameter('Authorization','Basic ' + encoded, pkHTTPHEADER, [poDoNotEncode]);
    Request.AddParameter('grant_type','refresh_token', pkGETorPOST, [poDoNotEncode]);
    Request.AddParameter('refresh_token',stcf.AccessData.RefreshToken, pkGETorPOST, [poDoNotEncode]);
    Request.Execute;
    MValue := response.JSONValue;
    If MValue <> NIL Then
    begin
      [...]
    end;
  finally
    FreeAndNIL(Request);
    FreeAndNIL(Response);
    FreeAndNIL(Client);
  end;
end;

Gruß LP

Statt im Nachgang die Linebreaks zu entfernen, kannst du auch einen eigenen Encoder erstellen, der erst gar keine einbaut:

    encoder := TBase64Encoding.Create(0, '');

Danke für den Hinweis. Ich hab's sofort eingebaut und so sieht es natürlich deutlich besser aus:

zusammenfalten · markieren

Delphi-Quellcode:

Function TSpManager.GetRefreshToken(Quiet: Boolean):Boolean;
  var s,Encoded: string;
       Client: TRestClient;
       Request: TRESTRequest;
       Response: TRestResponse;
       MValue:TJSONValue;
       encoder: TBase64Encoding;

begin
  result:= false;
  Client := TRestClient.Create('https://accounts.spotify.com/api/token');
  Response := TREStResponse.Create(NIL);
  Request := TRESTRequest.Create(NIL);
  encoder := TBase64Encoding.Create(0, '');
  try
    s := stcf.AccessData.clientID + ':' + stcf.AccessData.clientsecret;
    Encoded:= encoder.encode(s);
      [...]
  finally
    FreeAndNIL(Request);
    FreeAndNIL(Response);
    FreeAndNIL(Client);
    FreeAndNIL(Encoder);
  end;
end

Im 'Versuchs-Aufbau' war meine Lösung die erste, die mir einfiel und sich ohne lange Recherchen umsetzen ließ. Wieder mal ein deutliches Zeichen dafür, dass ich eigentlich nur einen geringen Teil des Sprachumfangs von Delphi kenne und auf vieles nur durch Zufall oder wie hier durch einen Hinweis stoße

Gruß LP