AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

TLisstBox mit anderer Value

Ein Thema von delphinia · begonnen am 10. Feb 2021 · letzter Beitrag vom 10. Feb 2021
Antwort Antwort
delphinia

Registriert seit: 16. Feb 2006
444 Beiträge
 
Delphi 11 Alexandria
 
#1

TLisstBox mit anderer Value

  Alt 10. Feb 2021, 14:02
Delphi-Version: 5
Hallo,

eine TListBox zu befülle ist ja kein Akt. Aber ich brauche zwar einen Sinnigen Text aber dahinter soll ein bestimmter String stehen so wie es auch bei dem HTML Select ist. Option Value und Text


Wie mache ich dies mit Delphi??
Doreen
Gruss Doreen
  Mit Zitat antworten Zitat
Delphi.Narium

Registriert seit: 27. Nov 2017
2.451 Beiträge
 
Delphi 7 Professional
 
#2

AW: TLisstBox mit anderer Value

  Alt 10. Feb 2021, 14:22
Wenn man in 'ner ListBox 'nen Eintrag auswählt, erhält man ja seinen ItemIndex.

Geht man nun her und befüllt die Items mit "sinnvollem Text" kann man in der gleichen Reihenfolge eine Stringliste (oder adäquates) mit "bestimmtem String" befüllen.

Wird nun in der ListBox ein Eintrag ausgewählt, nimmt man seinen ItemIndex und holt damit den entsprechenden Eintrag aus der Stringliste.

Man könnte auch hergehen und 'nen Nachfahren von TListBox mit 'ner zweiten Itemeigenschaft (Values) machen, dann kann man die entsprechenden Lese- und Schreibmethoden darin kapseln ...
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.558 Beiträge
 
Delphi 11 Alexandria
 
#3

AW: TLisstBox mit anderer Value

  Alt 10. Feb 2021, 15:08
Denkbar wäre auch eine eigene kleine Klasse mit 2 String-Feldern, deren Instanzen man in einer TObjectList verwaltet. Über diese Liste iteriert man und fügt jede Instanz der ListBox hinzu. Im OnCick oder sonstwo kann man dann auf die gespeicherte Referenz zugreifen und den dahinterliegenden Wert abfragen. Kleines Beispiel (ohne Generics, da Delphi 5 angegeben), zuerst die simple Klasse:
Delphi-Quellcode:
type
  TWuppdi = class
  public
    // Ich habe hier bewusst auf Properties verzichtet
    DisplayString: string;
    IDString: string;
    constructor Create(const ADisplay, AID: string);
  end;

...

{ TWuppdi }

constructor TWuppdi.Create(const ADisplay, AID: string);
begin
  inherited Create;
  DisplayString := ADisplay;
  IDString := AID;
end;
Und jetzt das Formular mit der ListBox:
Delphi-Quellcode:
type
  TfrmDemo = class(TForm)
    lbWuppdis: TListBox;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure lbWuppdisClick(Sender: TObject);
  private
    { Private-Deklarationen }
    FWuppdis: TObjectList; // aus Contnrs
    procedure CreateWuppdis;
    procedure DisplayWuppdis;
  public
    { Public-Deklarationen }
  end;

...

procedure TfrmDemo.CreateWuppdis;
var
  i: integer;
begin
  FWuppdis.Clear;
  for i := 1 to 10 do
    FWuppdis.Add(TWuppdi.Create(Format('Display %d', [i]),
      Format('ID %d', [i])));
end;

procedure TfrmDemo.DisplayWuppdis;
var
  i: integer;
  lWuppdi: TWuppdi;
begin
  lbWuppdis.Items.BeginUpdate;
  try
    lbWuppdis.Clear;
    for i := 0 to FWuppdis.Count - 1 do
      begin
        lWuppdi := FWuppdis[i] as TWuppdi;
        lbWuppdis.Items.AddObject(lWuppdi.DisplayString, lWuppdi);
      end;
  finally
    lbWuppdis.Items.EndUpdate;
  end;
end;

procedure TfrmDemo.FormCreate(Sender: TObject);
begin
  FWuppdis := TObjectList.Create;
  CreateWuppdis;
  DisplayWuppdis;
end;

procedure TfrmDemo.FormDestroy(Sender: TObject);
begin
  FWuppdis.Free;
end;

procedure TfrmDemo.lbWuppdisClick(Sender: TObject);
var
  lWuppdi: TWuppdi;
begin
  if lbWuppdis.ItemIndex > -1 then
    begin
      lWuppdi := lbWuppdis.Items.Objects[lbWuppdis.ItemIndex] as TWuppdi;
      ShowMessage(lWuppdi.IDString);
    end;
end;
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 19:53 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz