AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Delphi-PRAXiS - Lounge Klatsch und Tratsch Übung macht den Meister - zeigt her eure Lösungen

Übung macht den Meister - zeigt her eure Lösungen

Ein Thema von generic · begonnen am 13. Sep 2021 · letzter Beitrag vom 13. Sep 2021
Antwort Antwort
generic

Registriert seit: 24. Mär 2004
Ort: bei Hannover
2.376 Beiträge
 
Delphi XE5 Professional
 
#1

Übung macht den Meister - zeigt her eure Lösungen

  Alt 13. Sep 2021, 12:27
Moin, bei Heise war neulich ein CleanCode Artikel:
https://www.heise.de/hintergrund/Sch...html?seite=all

Diesen hatte ich als Thema für das letzte Video genommen:
https://www.youtube.com/watch?v=NCUajyNGYHY

Baut doch auch mal eine Lösung zur Übung in Delphi und fügt diese hier als Antwort ein.
Coding BOTT - Video Tutorials rund um das Programmieren - https://www.youtube.com/channel/UCUG...aXLclwO9qA-lzA

Geändert von generic (13. Sep 2021 um 17:06 Uhr)
  Mit Zitat antworten Zitat
TiGü

Registriert seit: 6. Apr 2011
Ort: Berlin
2.812 Beiträge
 
Delphi 10.2 Tokyo Enterprise
 
#2

AW: Übung macht den Meister - zeigt her eure Lösungen

  Alt 13. Sep 2021, 14:32
Grob der ursprüngliche Java-Code eins zu eins nach Delphi übersetzt:

Delphi-Quellcode:
program Project6;

{$APPTYPE CONSOLE}

{$R *.res}


uses
    System.SysUtils;

procedure start();
begin
    Writeln('Duplikate: ');
end;

procedure Main;
var
    s: string;
    yc, i, j: Integer;
    strings: TArray<string>;
begin
    s := 'Ohne Clean Code ist Code nicht wartbar.';

    s := s.ToLower();

    strings := s.split([' ']);

    start();
    for i := 0 to Length(strings) - 1 do
    begin
        yc := 1;

        for j := i + 1 to Length(strings) - 1 do
        begin
            if (strings[i].equals(strings[j])) then
            begin
                Inc(yc);

                strings[j] := '0';
            end;
        end;

        if ((yc > 1) and (strings[i] <> '0')) then
        begin
            Writeln(strings[i]);
        end;
    end;
end;

begin
    try
        Main;
    except
        on E: Exception do
            Writeln(E.ClassName, ': ', E.Message);
    end;
    Readln;
end.
Und hier eine hausbackende und hemdsärmelige Lösung, die Build-In-Funktionalität nutzt (ab Delphi XE7) und mithilfe flacher Funktionen die Duplikate im String sucht und ausgibt.
Es muss nicht immer gleich eine ganze Klasse sein.
Oft reicht einfach nur eine flache Funktion.

Delphi-Quellcode:
program Project7;

{$APPTYPE CONSOLE}

{$R *.res}

uses
    System.SysUtils,
    System.Generics.Collections;

function GetDuplicatesFromString(const AString: string): TArray<string>;
var
    Map: TDictionary<string, Integer>;
    WordCount: Integer;
    SingleString: string;
    Strings: TArray<string>;
begin
    Result := [];
    Strings := AString.ToLower.Split([' ']);
    Map := TDictionary<string, Integer>.Create;
    try
        for SingleString in Strings do
        begin
            if Map.TryGetValue(SingleString, WordCount) then
            begin
                Map[SingleString] := WordCount + 1; //optionale Zeile, falls man später die Häufigkeit noch braucht
                if WordCount = 1 then
                    Result := Result + [SingleString];
            end
            else
            begin
                WordCount := 1;
                Map.Add(SingleString, WordCount);
            end;
        end;
    finally
        Map.Free;
    end;
end;

procedure PrintStringArray(const AStrings: TArray<string>);
var
    SingleString: string;
begin
    for SingleString in AStrings do
        Writeln(SingleString);
end;

procedure Main;
var
    TestString: string;
    Duplicates: TArray<string>;
begin
    TestString := 'Ohne Clean Code ist Code nicht wartbar.';
    Duplicates := GetDuplicatesFromString(TestString);
    PrintStringArray(Duplicates);
end;

begin
    try
        Main;
    except
        on E: Exception do
            Writeln(E.ClassName, ': ', E.Message);
    end;
    Readln;

end.

Geändert von TiGü (13. Sep 2021 um 14:46 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
8.680 Beiträge
 
Delphi 10.4 Sydney
 
#3

AW: Übung macht den Meister - zeigt her eure Lösungen

  Alt 13. Sep 2021, 15:16
Ich spar mir mal das drumherum (erstellt in Delphi 11):
Delphi-Quellcode:
function GetDuplicatesFromString(const AString: string): TArray<string>;
const
  cWordDelims: TArray<string> = [' ', ',', '.'];
  cCaseSensitive = False;
var
  KnownWords: TStringList;
  Duplicates: TStringList;
begin
  KnownWords := TStringList.Create(dupIgnore, True, cCaseSensitive);
  try
    Duplicates := TStringList.Create(dupIgnore, True, cCaseSensitive);
    try
      for var CurrentWord in AString.Split(cWordDelims) do
        if KnownWords.IndexOf(CurrentWord) < 0 then
          KnownWords.Add(CurrentWord)
        else
          Duplicates.Add(CurrentWord);
      Result := Duplicates.ToStringArray;
    finally
      Duplicates.Free;
    end;
  finally
    KnownWords.Free;
  end;
end;
Die Ausgabe der Duplikate erfolgt hier alphabetisch und in Bezug auf Groß-/Kleinschreibung wird die Schreibweise des zweiten Vorkommens des Wortes verwendet.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
generic

Registriert seit: 24. Mär 2004
Ort: bei Hannover
2.376 Beiträge
 
Delphi XE5 Professional
 
#4

AW: Übung macht den Meister - zeigt her eure Lösungen

  Alt 13. Sep 2021, 17:05
@TiGü Danke für die Übersetzung des Beispiels
@Uwe die VAR/Array Sachen sind schon schön in den neuen Compiler. Hab nur XE5

Delphi-Quellcode:
uses
  System.SysUtils,
  System.Generics.Collections;

procedure DuplicatesFromString(source: string; duplicateFound: TProc<string>);
var
  dict: TDictionary<String, integer>;
  s: string;
  i: integer;
  p: TPair<string, integer>;
begin
  dict:=TDictionary<String, integer>.Create();
  try
    for s in source.ToLower().Split([' ']) do
    begin
      i:=0;
      if dict.TryGetValue(s, i) then
        i:=i+1;
      dict.AddOrSetValue(s, i);
    end;

    for p in dict do
      if p.Value>0 then
        duplicateFound(p.Key);
  finally
    dict.Free;
  end;
end;

begin
  try
    Writeln('Duplikate: ');
    DuplicatesFromString('Ohne Clean Code ist Code nicht wartbar.',
      procedure(s: string)
      begin
        Writeln(s);
      end);
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;
end.
Coding BOTT - Video Tutorials rund um das Programmieren - https://www.youtube.com/channel/UCUG...aXLclwO9qA-lzA
  Mit Zitat antworten Zitat
Rollo62

Registriert seit: 15. Mär 2007
3.226 Beiträge
 
Delphi 10.4 Sydney
 
#5

AW: Übung macht den Meister - zeigt her eure Lösungen

  Alt 13. Sep 2021, 19:58
for var ... sehe ich in letzter Zeit öfters.

Kann man wohl mittlerweile verwenden, wenn es mit Arrays geht.
Sind nur eben nicht rückwärtskompatibel.

Geändert von Rollo62 (13. Sep 2021 um 20:03 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 19:14 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf