AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

NSImage

Ein Thema von Peter666 · begonnen am 27. Sep 2021 · letzter Beitrag vom 29. Sep 2021
Antwort Antwort
Peter666

Registriert seit: 11. Aug 2007
339 Beiträge
 
#1

NSImage

  Alt 27. Sep 2021, 14:58
Hi,

hat schon mal jemand auf OSX/iOS ein NSImage über das bestehende Canvas gezeichnet? Der Hintergrund ist der: Ich wollte gerne über den Browser eine Art einblendbares Halbtransparentes OSD packen und das geht mit Firemonkey ja nicht wirklich.

Delphi-Quellcode:
unit UOSD;

interface

uses System.Types, System.Classes, FMX.Graphics, FMX.Controls;

type
  TOSD = class(TControl)
  protected
    FBitmap: TBitmap;
    FNativePaint: Boolean;

    procedure Paint; override;
    procedure SetBitmap(const ABitmap: TBitmap);
    procedure SetNativePaint(const ANativePaint: Boolean);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Bitmap: TBitmap read FBitmap write SetBitmap;
    property Opacity;
    property NativePaint: Boolean read FNativePaint write SetNativePaint
      default false;
  end;

implementation

constructor TOSD.Create(AOwner: TComponent);
begin
  inherited;
  Width := 100;
  Height := 100;
  FBitmap := TBitmap.Create;
end;

destructor TOSD.Destroy;
begin
  FBitmap.Free;
  inherited;
end;

procedure TOSD.SetNativePaint(const ANativePaint: Boolean);
begin
  if FNativePaint <> ANativePaint then
  begin
    FNativePaint := ANativePaint;
    Repaint;
  end;
end;

procedure TOSD.SetBitmap(const ABitmap: TBitmap);
begin
  FBitmap.Assign(ABitmap);
  Repaint;
end;

//WindowHandleToPlatform(FForm.Handle).View
procedure TOSD.Paint;
var
  DstRect: TRectF;
begin
{$IFDEF MACOS}
  if FNativePaint then
  begin
    exit;
  end;
{$ENDIF}
  DstRect := FBitmap.BoundsF;
  DstRect.Fit(BoundsRect);
  Canvas.DrawBitmap(FBitmap, FBitmap.BoundsF, DstRect, Opacity)
end;

end.
Peter

Geändert von Peter666 (27. Sep 2021 um 15:45 Uhr)
  Mit Zitat antworten Zitat
Rollo62

Registriert seit: 15. Mär 2007
3.301 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: NSImage

  Alt 27. Sep 2021, 17:09
Ich hab es nicht probiert, aber es sollten doch angeblich die Z-Orders mit den NativeComponents kompatibler geworden sein in Rx10.4/Rx11.
Hast Du mal probiert ein TLayout IN den WebBrowser zu werfen und dann mit Client/Content voll auszufüllen.
Dann sollten doch im TLayout weitere Komponenten wie TRectangle oder TImage den Webbrowser verdecken können,
wobei man die Opacity frei einstellen könnte.

Ich mache das an einigen Stellen so, OK aber ich habe auch aktuell keinen WebBrowser da drunterliegen.
  Mit Zitat antworten Zitat
Peter666

Registriert seit: 11. Aug 2007
339 Beiträge
 
#3

AW: NSImage

  Alt 28. Sep 2021, 11:38
Danke für die Rückmeldung. Leider geht das immer noch nicht und ich denke mal das wird auch in Zukunft nicht so gehen, aber eventuell ein TLayout Abkömmling der ein eigenes NSView oder UIView hält auf dem dann die restlichen Inhalte gezeichnet werden. Leider hab ich nicht wirklich viel Ahnung von MacOS und iOS.
  Mit Zitat antworten Zitat
CHackbart

Registriert seit: 22. Okt 2012
243 Beiträge
 
#4

AW: NSImage

  Alt 29. Sep 2021, 13:12
Auf MacOS kannst du NSImageView nutzen. Das ist relativ einfach und du hast keine Huddelei mit nativen Elementen. Auf IOS und Android bzw. unter Windows geht das denke ich ähnlich. Ich wüsste auch gerne, wie man das möglichst Elegant und großen Codeaufwand beheben kann.

Delphi-Quellcode:
unit UOSD;

interface

uses System.Types, System.Classes, FMX.Graphics, FMX.Controls
    {$IFDEF MACOS}
     , Macapi.AppKit
    {$ENDIF};

type
  TOSD = class(TControl)
  protected
    FBitmap: TBitmap;
    FNativePaint: Boolean;
    FNeedUpdate: Boolean;
{$IFDEF MACOS}
    FOverlayView: NSImageView;
{$ENDIF}
    procedure Paint; override;
    procedure Resize; override;
    procedure SetBitmap(const ABitmap: TBitmap);
    procedure SetNativePaint(const ANativePaint: Boolean);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Bitmap: TBitmap read FBitmap write SetBitmap;
    property Opacity;
    property NativePaint: Boolean read FNativePaint write SetNativePaint
      default false;
  end;

implementation

uses FMX.Types, FMX.Forms
{$IFDEF MACOS}, FMX.Platform.Mac, FMX.Helpers.Mac, Macapi.CocoaTypes, Macapi.CoreGraphics {$ENDIF};

function GetParentForm(Control: TFmxObject): TCommonCustomForm;
begin
  if (Control.Root <> nil) and (Control.Root.GetObject is TCommonCustomForm)
  then
    Result := TCommonCustomForm(Control.Root.GetObject)
  else
    Result := nil;
end;

constructor TOSD.Create(AOwner: TComponent);
begin
  inherited;
  Width := 100;
  Height := 100;
  FBitmap := TBitmap.Create;
end;

destructor TOSD.Destroy;
begin
  FBitmap.free;
  inherited;
end;

procedure TOSD.SetNativePaint(const ANativePaint: Boolean);
begin
  if FNativePaint <> ANativePaint then
  begin
    FNativePaint := ANativePaint;
{$IFDEF MACOS}
    if assigned(FOverlayView) then
      FOverlayView.release;
    FNeedUpdate := true;
{$ENDIF}
    Repaint;
  end;
end;

procedure TOSD.SetBitmap(const ABitmap: TBitmap);
begin
  FBitmap.Assign(ABitmap);
  FNeedUpdate := true;
  Repaint;
end;

procedure TOSD.Resize;
{$IFDEF MACOS}
var
  R: TRectF;
{$ENDIF}
begin
  inherited;
{$IFDEF MACOS}
  if assigned(FOverlayView) then
  begin
    R := GetAbsoluteRect;
    FOverlayView.setFrame(MakeNSRect(R.Left, R.Top, R.Width, R.Height));
  end;
{$ENDIF}
end;

procedure TOSD.Paint;
var
  DstRect: TRectF;
{$IFDEF MACOS}
  FormView: NSView;
  Form: TCommonCustomForm;
  R: TRectF;
{$ENDIF}
begin
{$IFDEF MACOS}
  if FNativePaint then
  begin
    if FNeedUpdate then
    begin
      if not assigned(FOverlayView) then
      begin
        R := BoundsRect;

        FOverlayView := TNSImageView.Wrap
          (TNSImageView.Alloc.initWithFrame(MakeNSRect(R.Left, R.Top, R.Width,
          R.Height)));
        FOverlayView.retain;

        Form := GetParentForm(self);

        if assigned(Form) then
        begin
          FormView := TNSView.Wrap(WindowHandleToPlatform(Form.Handle)
            .Wnd.contentView);
          FormView.addSubview(FOverlayView, NSWindowAbove, nil);
        end;
        FOverlayView.setWantsLayer(true);
        FOverlayView.setFrame(MakeNSRect(R.Left, R.Top, R.Width, R.Height));
      end;
      FOverlayView.setImage(BitmapToMacBitmap(FBitmap));
      FNeedUpdate := false;
    end;
    exit;
  end;
{$ENDIF}
  DstRect := FBitmap.BoundsF;
  DstRect.Fit(BoundsRect);
  Canvas.DrawBitmap(FBitmap, FBitmap.BoundsF, DstRect, Opacity)
end;

end.
  Mit Zitat antworten Zitat
Rollo62

Registriert seit: 15. Mär 2007
3.301 Beiträge
 
Delphi 10.4 Sydney
 
#5

AW: NSImage

  Alt 29. Sep 2021, 13:53
Hier gibt es auch weitere Ideen wie man NativeControl einsetzen kann.
https://github.com/DelphiWorlds/Kast...ativeImage.pas
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 08:47 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf