Generisch Maximum bestimmen

[mytbo]

Zitat von freimatz:

Müsste dann der Record einen IComparer implementerien? Oder die Liste. Habt ihr mir da auch ein Beispiel dazu? Basierend auf Spring4D reicht mir mal vorläufig.

Zur Veranschaulichung der Fälle. Kombination ist möglich. Beispiel für TComparison<T>:

Delphi-Quellcode:

type
  TRec = record
    x, y: Integer;
  end;

function CompareRecY(const pmcLeft, pmcRight: TRec): Integer;
begin
  Result := (pmcLeft.y - pmcRight.y);
end;

const
  RECS: array[0..2] of TRec = ((x: 1; y: 4), (x: 5; y: 6), (x: 3; y: 2));
var
  list: IList<TRec>;
begin
  list := TCollections.CreateList<TRec>(RECS);
  list.Sort(CompareRecY);
  ShowMessage(Format('First Y: %d, Max Y: %d',[list[0].y, list.Max(CompareRecY).y]));
end;

Beispiel für IComparer<T>:

Delphi-Quellcode:

type
  TData = class
  private
    FX, FY: Integer;
  public
    constructor Create(pmX, pmY: Integer);
    property X: Integer
      read FX;
    property Y: Integer
      read FY;
  end;

  TDataYComparer<T: TData> = class(TComparer<T>)
  public
    function Compare(const pmcLeft, pmcRight: T): Integer; override;
  end;

constructor TData.Create(pmX, pmY: Integer);
begin
  inherited Create;
  FX := pmX;
  FY := pmY;
end;

function TDataYComparer<T>.Compare(const pmcLeft, pmcRight: T): Integer;
begin
  Result := (T(pmcLeft).Y - T(pmcRight).Y);
end;

var
  list: IList<TData>;
  comp: IComparer<TData>;
begin
  comp := TDataYComparer<TData>.Create;
  list := TCollections.CreateObjectList<TData>(comp, True);
  list.Add(TData.Create(1, 4));
  list.Add(TData.Create(5, 6));
  list.Add(TData.Create(3, 2));
  list.Sort;
  ShowMessage(Format('First Y: %d, Max Y: %d',[list[0].Y, list.Max.Y]));
end;

Bis bald...
Thomas

[freimatz]

Danke. Ich denke ich komme damit weiter. Task ist eingeplant

[Stevie]

3 kleine Anmerkungen:
- idR hat jede Methode in den Spring Collections, die IComparer<T> entgegen nimmt, auch einen overload für TComparison<T> und macht das explizite Erstellen einer comparer Klasse unnötig.
- Subtraktion für das Vergleichen von Integer verursacht möglicherweise einen negativen Overflow wenn das delta zwischen left und right > MaxInt ist - also wenn left eine sehr große negative und right eine sehr große positive Zahl ist.
- in TDataYComparer<T>.Compare ist der hardcast von left und right auf T überflüssig (die sind ja schon vom Typ T).

[himitsu]

Zitat:

- Subtraktion für das Vergleichen von Integer verursacht möglicherweise

Also einfach CompareValue benutzen,
bzw. SameValue für den anderen Overload.