Javascript zum Download?

[Stewag]

Thank you Kas Ob. - Curl solved my problem!

Danke auch an Thomas! Curl einzubinden erschien mir in diesem Fall als die einfachere Lösung.

[jaenicke]

Das hat nichts mit Curl oder Indy zu tun, denn das kann der Server gar nicht mitbekommen. Der Unterschied liegt in der Anfrage. Vermutlich ist schlicht der Useragent ein anderer, der ja auch schon erwähnt wurde...

[himitsu]

Delphi-Quellcode:

uses Winapi.UrlMon;
if URLDownloadToFile(nil, 'deine URL', 'der Dateiname', 0, nil) <> S_OK then
  raise EProgrammerNotFound.Create('Peng');

Delphi-Quellcode:

uses Vcl.ExtActns;
var DownLoadURL: TDownLoadURL;
...
DownLoadURL.URL := ...;
DownLoadURL.Filename := ...;
if not DownLoadURL.Execute then
  raise EProgrammerNotFound.Create('Peng');

Aber so, wie die Fehlermeldung klingt, müssten es zwei Abfragen werden.
z.B. einmal die Seite aufrufen, auf welcher der Download verlinkt wird, das soll wohl ein Cookie bei dir speichern und dann die zweite Abfrage, inkl. des Cookie, um die Datei runterzuladen.
Aber natürlich kann diese Fehlermeldung absoluter Bullshit sein und es ist am Ende ganz einfach.

Wie mehrmals gesagt, kannst du einfach mal mit alt und neu eine Abfrage machen, schaust dir den Unterschied an und behebst Jenen.


Manche Server sperren z.B. gewisse "standard"-Dinge, wie z.B. einige Useragent-Strings,
weil andere Programme, die auch das Gleiche ausgeben, zu oft Mist gebaut wurde.

z.B. illegal automatisiert Daten abgefragt, obwohl es vielleicht nicht erlaubt war.

Außerdem gibt so manche API / Webserver gern auf, wenn man nicht den gewünschten, bzw. einen der unterstürtzen Typen angibt. (Accept)

[Klaus01]

.. dies hier läd auch die csv Datei ohne Probleme:

Delphi-Quellcode:

program ssltest;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils, system.Classes, idhttp, IdSSLOpenSSL;

const
  url = 'https://www.bundesbank.de/statistic-rmi/StatisticDownload?tsId=BBEX3.M.JPY.EUR.BB.AC.A02';
var
  httpClient: TIDHttp;
  ioHandler: TIdSSLIOHandlerSocketOpenSSL;
  sResponse: TStringStream;
begin
  try
    httpClient := TIdHttp.Create(nil);
    try
      ioHandler := TIdSSLIOHandlerSocketOpenSSL.Create(httpClient);
      ioHandler.SSLOptions.Method := sslvTLSv1_2;
      ioHandler.SSLOptions.SSLVersions := [sslvTLSv1_2];
      httpClient.IOHandler := ioHandler;
      sResponse := TStringStream.Create;
      try
        httpClient.Get(url, sResponse);
        case httpClient.ResponseCode of
          200: sResponse.SaveToFile('c:\tmp\bb.csv');
        end;
      finally
        sResponse.Free;
      end;
    finally
      httpClient.Free;
    end;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

Delphi 11.3

Grüße
Klaus

[Bbommel]

Und noch eine Lösung mit Delphi-Bordmitteln, also ohne curl und ohne Mormot - und auch ohne Indy, was es ggf. mit https etwas leichter macht:

Delphi-Quellcode:

program getPage;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, System.Net.HttpClient;

var
  myClient: THTTPClient;
  response: IHTTPResponse;
  success: boolean;
  address: string;

begin
  try
    { TODO -oUser -cConsole Main : Code hier einfügen }
    success:=true;
    address:='https://www.bundesbank.de/statistic-rmi/StatisticDownload?tsId=BBEX3.M.JPY.EUR.BB.AC.A02';

    myClient:=THTTPClient.Create;
    try
      response:=myClient.Get(address);
    except
      writeln('Request failed');
      success:=false;
    end;

    if success and (response<>nil) then begin
      Writeln('Success. Displaying content.');
      Writeln(response.ContentAsString);
    end;
    myClient.Free;
    readln;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
end.

[Stewag]

Danke an alle - ihr seid großartig!!!

Die Lösung von Klaus funktioniert auch unter dem älteren XE2, das ich aus Kompatibilitätsgründen zu einer älteren Komponente hierfür noch verwenden muss.

Bbommels Lösung erfordert ein neueres Delphi und läuft prima unter Delphi 11.

[Union]

Hast Du mal die Versionen der OpenSSL Dlls geprüft, die Du beim IOHandler lädst?