Threadklasse mit Event aktualisiert nicht

[Inspur1]

Greetings!

Ich entwickel in FreePascal eine Threadklasse mit einem Event und einigen Eigenschaften.
Um das Problem besser zu erklären, habe ich das Beispiel kompromiert.

Delphi-Quellcode:

unit uTest;

interface

uses Classes;

type
  TTestThread = class(TThread)
  private
    FTestProperty: string;
    FOnTest: TNotifyEvent;
  protected
    procedure DoTest; virtual;
    procedure Execute; override;
  public
    constructor Create(CreateSuspended: Boolean);
    destructor Destroy; override;
    property TestProperty: string read FTestProperty write FTestProperty;
    property OnTest: TNotifyEvent read FOnTest write FOnTest;
  end;

implementation

constructor TTestThread.Create(CreateSuspended: Boolean);
begin
  inherited Create(CreateSuspended);
  FTestProperty := 'default';
end;

destructor TTestThread.Destroy;
begin
  inherited;
end;

procedure TTestThread.DoTest;
begin
  if not Assigned(FOnTest) then
    FOnTest(self);
end;

procedure TTestThread.Execute;
begin
  DoTest;
end;


end.



// Call

private
  FTest: TTestThread;
  procedure MyTest(Sender: TObject);

procedure TForm1.MyTest(Sender: TObject);
begin
  FTest.TestProperty := '>>> Test2 <<<';
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FTest := TTestThread.Create(false);
  FTest.FreeOnTerminate := false;
  FTest.OnTest := MyTest;
  FTest.Resume;
  Caption := FTest.TestProperty;
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
  if Assigned(FTest) then
    FTest.Free;
end;

Ich will im Event die Eigenschaft ändern aber es bleibt bei "default".
Wie mache ich das richtig?

[jaenicke]

Du liest die Eigenschaft direkt nach dem Resume aus. Ein Thread läuft aber eben parallel. Daher wird das Event erst danach ausgeführt.

Dass das Event ausgeführt wird, würdest du mit einem Haltepunkt sofort sehen.

Eine Aktualisierung müsste daher auch dort im Event angestoßen werden, was in dem Beispiel natürlich wenig Sinn macht. Die Konstruktion macht eher Sinn, wenn der Thread den Wert setzt und im Event dann die Aktualisierung angestoßen wird.

Was möchtest du denn erreichen?

[Olli73]

Ein "Not" zu viel:

Delphi-Quellcode:

if not Assigned(FOnTest) then
    FOnTest(self);

[jaenicke]

Zitat von Olli73:

Ein "Not" zu viel:

Delphi-Quellcode:

if not Assigned(FOnTest) then
    FOnTest(self);

Oh ja, das habe ich am Handy glatt übersehen.

[Rollo62]

TL;DR;

Delphi-Quellcode:

procedure TTestThread.Execute;
begin
  Synchronize(DoTest);
end;

Das macht nicht so viel Sinn, denn damit läuft ja dein zu "threadender" Code wieder im Main UI-Thread, wenn ich das richtig interpretiere.
Es sollte doch nur das Ergebnis synchronisiert werden.

[himitsu]

DoTest ist quasi die Methode, welche OnTest auslöst, womit dieses Synchronize schon stimmt. (die Namensgebung ist in der VCL Vielerorts genauso)


Am Ende klingt es so, als wenn der "eigentliche" Code noch viel mehr macht, wie z.B. vorher scheinbar eine Datei runterladen. (natürlich außerhalb des Synchronize)




Prinzipiell sind LongStrings (String/AnsiString/UnicodeString) und ihre Referenzzählung per se thread-save.

Funktional quasi so, als wenn man einen Integer/Boolean/LongBool/Pointer mit den Interlocked-, bzw. Atomic-Funktionen schreibend (Inc/Dec) und kopierend behandelt.

[Inspur1]

Ich möchte mehrere HTML auslesen, im Event möchte ich festlegen wonach gesucht wird und die Ergebnisse den Eigenschaften übergeben.

[Rollo62]

Du nutzt FTestProperty innerhalb des Threads und außerhalb im UI Thread, ohne irgendeine Art der Synchronisation,
wenn ich das richtig sehe.

Auf jeden Fall sollte man den Zugriff im UI Thread dann synchronisieren, aber die Frage siehe oben, was willst Du erreichen?

[Blup]

vorgeschlagene Änderungen:

Delphi-Quellcode:

uses Classes, System.SyncObjs;

type
  TTestThread = class(TThread)
  private
    FTestProperty: string;
    FOnTest: TNotifyEvent;
    function GetTestProperty: string;
    procedure SetTestProperty(const AValue: string);
  protected
    FCS: TCriticalSection;
    procedure DoTest; virtual;
    procedure Execute; override;
  public
    constructor Create(CreateSuspended: Boolean);
    destructor Destroy; override;
    {kann aus einem anderen Thread gelesen und verändert werden}
    property TestProperty: string read GetTestProperty write SetTestProperty;
    {wird im Hauptthread aufgerufen (ermöglicht Zugriff auf die VCL)}
    property OnTest: TNotifyEvent read FOnTest write FOnTest;
  end;

implementation

procedure TTestThread.DoTest;
begin
  if Assigned(FOnTest) then  // ???: if not Assigned(FOnTest) then
    FOnTest(self);
end;

constructor TTestThread.Create(CreateSuspended: Boolean);
begin
  inherited Create(CreateSuspended);
  FTestProperty := 'default';
  FCS := TCriticalSection.Create;
end;

destructor TTestThread.Destroy;
begin
  FCS.Free;
  inherited;
end;

procedure TTestThread.Execute;
begin
  Synchronize(DoTest);
end;

function TTestThread.GetTestProperty: string;
begin
  FCS.Enter;
  try
    Result := FTestProperty;
  finally
    FCS.Leave;
  end;
end;

procedure TTestThread.SetTestProperty(const AValue: string);
begin
  FCS.Enter;
  try
    FTestProperty := AValue;
  finally
    FCS.Leave;
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  FTest := TTestThread.Create(false);
  FTest.FreeOnTerminate := false;
  FTest.OnTest := MyTest;
  FTest.Resume;
  repeat
    CheckSynchronize(10);
  until FTest.Terminated;
  Caption := FTest.TestProperty;
  FTest.Free;
end;