Gesperrte Dateien löschen

[sakura]

Aufgrund der Nachfrage, wie man die Datei index.dat löschen kann, und meinen neuen Erkenntnissen über diese Datei, habe ich hier für Euch die "Delphi-Lösung".

Folgende Funktion (für Windows 9x/ME und NT/2K/XP) ermöglicht es, Windows ein Datei zu nennen, welche beim nächsten Systemstart gelöscht werden soll. Diese Lösung entstand mal im Rahmen einer Virenbeseitigung. Dateien, wie auch die index.dat, welche durch eine Anwendung, oder das System, blockiert sind, können meistens weder umbenannt, noch gelöscht werden. Windows bietet aber die Möglichkeit solche Dateien zu "markieren", so dass diese beim nächsten Systembootvorgang gelöscht werden. Danke Microsoft.

Einfach diese Funktion aufrufen und den Dateinamen übergeben. Beim nächsten Systemstart ist es vollbracht. Btw, die wichtigsten Systemdateien, alá kernel32.dll sollten nicht gelöscht werden können.

Delphi-Quellcode:

function DeleteFileDuringNextSystemBoot(aFileName: string): Boolean;
var
  Dummy, ShortFileName: array [0..MAX_PATH + 1] of Char;
  WinIni: string;
  SystemType: TOSVersionInfoA;
begin
  Result := False;

  SystemType.dwOSVersionInfoSize := SizeOf(SystemType);
  GetVersionEx(SystemType);

  if SystemType.dwPlatformId = VER_PLATFORM_WIN32s then
    // nicht unterstützt durch Win32s Systeme :(
    Exit;

  if SystemType.dwPlatformId = VER_PLATFORM_WIN32_NT then
  begin
    // NT/2K/XP/.NET Systeme
    if StrLen(PChar(ExtractFileDrive(aFileName))) < 4 then
      Result := False; // Falls Filename z. B. nur aus C:\ besteht 
    else
      Result := MoveFileEx(PChar(aFileName), nil, MOVEFILE_REPLACE_EXISTING +
        MOVEFILE_DELAY_UNTIL_REBOOT);
  end else begin
    // 9X/ME Systeme
    GetWindowsDirectory(Dummy, MAX_PATH + 1);
    WinIni := Dummy;
    if AnsiLastChar(WinIni)^ <> '\' then
      WinIni := WinIni + '\wininit.ini'
    else
      WinIni := WinIni + 'wininit.ini';

    with TStringList.Create do
    try
      if FileExists(WinIni) then
        LoadFromFile(WinIni);
      if IndexOf('[rename]') < 0 then
        Add('[rename]');
      GetShortPathName(PChar(aFileName), ShortFileName, MAX_PATH + 1);
      Insert(Succ(IndexOf('[rename]')), 'NUL=' + ShortFileName);

      SaveToFile(WinIni);
      Result := True;
    finally
      Free;
    end;
  end;
end;

......

[edit=Chakotay1308]Fehler korrigiert. Danke an himitsu und Go2EITS. Mfg, Chakotay1308[/edit]