shutdown, reboot usw.

[Sprint]

Zitat von Delphi Star:

Ich habe fast alles gefunden, jetzt muss ich nur nocn den Befehl für den Standbymodus wissen.

Das folgende Beispiel habe ich am 06. August 2002 geschrieben und noch nicht unter XP getestet...

Zitat:

Wie kann ich Windows in den StandBy Modus setzen?

Um Windows schlafen zu legen, reicht der Aufruf der Win32 API Funktion SetSystemPowerState. Nach Angaben des Platform SDK, wird die Funktion von allen Windows Versionen unterstützt. Unter Windows NT muss zusätzlich das SE_SHUTDOWN_NAME Privileg gesetzt werden.

Delphi-Quellcode:

unit StandbyWindows_Unit;

interface

uses
  Windows;

function StandbyWindows: Boolean;

implementation

const
  SE_SHUTDOWN_NAME = 'SeShutdownPrivilege';

// -----------------------------------------------------------------------------

function StandbyWindows: Boolean;
var
  OSVersionInfo: TOSVersionInfo;
  hToken: THandle;
  hProcess: THandle;
  TokenPriv: TTokenPrivileges;
  ReturnLength: DWORD;
begin

  Result := False;
  OSVersionInfo.dwOSVersionInfoSize := SizeOf(OSVersionInfo);

  if not GetVersionEx(OSVersionInfo) then
    Exit;

  case OSVersionInfo.dwPlatformId of
    VER_PLATFORM_WIN32_NT:
      begin
        hProcess := GetCurrentProcess;

        if not OpenProcessToken(hProcess, TOKEN_ADJUST_PRIVILEGES, hToken) then
          Exit;

        if not LookupPrivilegeValue(nil, SE_SHUTDOWN_NAME,
          TokenPriv.Privileges[0].Luid) then Exit;

        TokenPriv.PrivilegeCount := 1;
        TokenPriv.Privileges[0].Attributes := SE_PRIVILEGE_ENABLED;

        if not AdjustTokenPrivileges(hToken, False, TokenPriv, 0,
          PTokenPrivileges(nil)^, ReturnLength) then Exit;

        CloseHandle(hToken);
      end; {end VER_PLATFORM_WIN32_NT}
  end; {end case}

  Result := SetSystemPowerState(True, False);

end; {end function}

// -----------------------------------------------------------------------------

end.