AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein XML Delphi Problem bei XML-Erstellung / Schemenangabe

Problem bei XML-Erstellung / Schemenangabe

Ein Thema von Keldorn · begonnen am 26. Okt 2004 · letzter Beitrag vom 27. Okt 2004
Antwort Antwort
Keldorn

Registriert seit: 6. Mär 2003
Ort: Meißen
876 Beiträge
 
Delphi 10.1 Berlin Professional
 
#1

Problem bei XML-Erstellung / Schemenangabe

  Alt 26. Okt 2004, 19:52
Hallo

Ich gebs auf … ich habe schon mehrere verschiedene Sachen ausprobiert und komme einfach nicht auf einen grünen Zweig. Und da ich mich das erste Mal mit XML beschäftige, weiß ich nicht so recht weiter.
Eine von uns genutzte Anwendung erwartet als Importfunktion eine XML-Datei. Diese sieht ungefähr so aus:
Code:
  <?xml version="1.0" encoding="windows-1252" ?>
- <OpenShipments xmlns="x-schema:.\OpenShipments.xdr">
- <OpenShipment ProcessStatus="">
- <Receiver>
        … unterknoten mit den Daten
  </Receiver>
- <Shipment>
        … unterknoten mit den Daten
  </Shipment>
  </OpenShipment>
  </OpenShipments>
Mit folgendem code
Delphi-Quellcode:
  xmlDoc := CoDOMDocument30.Create;
  xmlDoc.validateOnParse := false;
  xmlDoc.resolveExternals := false;

  XMLdoc.loadXML('<?xml version="1.0" encoding="windows-1252" ?>'+
                 '<OpenShipments xmlns="x-schema:.\Openshipments.xdr">'+
                 '<OpenShipment ProcessStatus="">'+
                 '</OpenShipment>'+
                 '</OpenShipments>');

  root:=XMLdoc.selectSingleNode('OpenShipments/OpenShipment');

  Empfaenger := xmlDoc.createElement('Receiver');
  if Empfaenger<>Nil then
    begin
       ….
      root.appendChild(Empfaenger);
    end;

  xmlDoc.save(blabla);
entsteht aber:
Code:
  <?xml version="1.0" encoding="windows-1252" ?>
- <OpenShipments xmlns="x-schema:.\Openshipments.xdr">
- <OpenShipment ProcessStatus="">
  <Receiver xmlns="" />
  </OpenShipment>
  </OpenShipments>
Da steht aber nun ein xmlns=““ hinter Receiver, was nicht hingehört. Der Fremdanwendung scheint es auch nicht zu gefallen und es kommt zu einem Fehler, dass receiver nicht gefunden wurde. Editiere ich die Datei und lösche das xmlns=““ geht’s zumindestens einen Schritt beim importieren weiter.
Nehme ich CoDOMDocument40.Create; ist root immer nil, verstehe ich auch nicht.

Versuche ich es mit:
Delphi-Quellcode:
  XMLdoc.loadXML('<?xml version="1.0" encoding="windows-1252" ?>'+
                 '<OpenShipments>'+
                 '<OpenShipment>'+
                 '</OpenShipment>'+
                 '</OpenShipments>');
Gibt es in der Fremdanwendung auch wieder einen Fehler, das das Schema nicht angegeben wurde … dafür steht hinter receiver auch kein xmlns=““ mehr.

Fragen:
Woher stammt das xmlns=““ ? was hat das überhaupt zu sagen ?
Wie bekommt man diese Schemenangabe (xmlns="x-schema:.\OpenShipments.xdr ) ohne loadxml mit rein oder wie kann man die nachträglich setzen? (wenn ich bei loadxml diese Angaben weglasse, erscheint auch nicht dieses xmlns=““ hinter receiver, also genau das, was ich will).

Danke im Voraus

Frank

edit: Schreibfehler in Überschrift ausgebessert

Lükes Grundlage der Programmierung:
Es wird nicht funktionieren
(Murphy)
  Mit Zitat antworten Zitat
MathiasSimmack
(Gast)

n/a Beiträge
 
#2

Re: Problem bei XML-Erstellung / Schemenangabe

  Alt 27. Okt 2004, 07:28
Hallo.

"xmlns" steht für XML Namespace (behaupte ich jetzt einfach mal ). In deinem Fall benutzt die komplette Datei den gleichen Namespace. Und daran liegt es auch, dass "selectSingleNode" nichst findet. Hast du die MS-XML-Doku in der Nähe? Dann schau mal rein, da steht das auch drin.

Also, dein Anfang war schon mal okay. Ich nehme jetzt mal XML 4, aber mit Version 3 sollte es auch so funktionieren:
Delphi-Quellcode:
const
  strNS = 'x-schema:.\Openshipments.xdr';
  strNamespace = 'xmlns="' + strNS + '"';
var
  xmldoc : DomDocument40;
  root,
  node : IXMLDomNode;
begin
  xmldoc := CoDomDocument40.Create;
  if(xmldoc <> nil) then
  try
    xmldoc.async := true;
    xmldoc.validateOnParse := false;
    xmldoc.resolveExternals := false;

    // XML-Grundcode
    xmldoc.loadXML('<?xml version="1.0" encoding="windows-1252"?>' + #13#10 +
      '<OpenShipments ' + strNamespace + '>' + #13#10 +
      ' <OpenShipment ProcessStatus=""/>' + #13#10 +
      '</OpenShipments>');
So, damit der XML-Parser jetzt auch den Knoten findet, musst du selbst noch mal den Namespace deklarieren. Das Problem ist, dass der Namespace kein Suffix/Präfix hat. Also musst du dir selbst einen ausdenken, sonst kannst du mit XPath nicht richtig suchen. Ich nehme einfach mal deinen Nick als Suffix:
Delphi-Quellcode:
const
  strSelNS = 'xmlns:keldorn="' + strNS + '"';
begin
  { ... }

    // Namespace setzen, allerdings mit eigenem Präfix, wg.
    // "selectSingleNode" und Co.
    xmldoc.setProperty('SelectionNamespaces',strSelNS);
Das ist jetzt nur für den Parser von Interesse, weil du den Suffix nun als Präfix beim Suchen verwendest:
Delphi-Quellcode:
    root := xmldoc.selectSingleNode('/keldorn:OpenShipments/' +
      'keldorn:OpenShipment');
Jetzt sollte der Knoten gefunden werden, und du kannst den neuen anlegen. Nimm hier aber nicht "createElement", denn das geht offenbar davon aus, dass der zu erzeugende Knoten einen anderen Namespace (in dem Fall: keinen) hat. Deswegen auch das leere
<Receiver xmlns=""/> Nimm stattdessen "createNode", denn hier kannst du den Namespace selbst angeben. Aber diesmal eben nur den Teil in den Anführungszeichen:
Delphi-Quellcode:
    if(root <> nil) then
    begin
      // neuen Knoten erzeugen und Namespace direkt angeben
      node := xmldoc.createNode(NODE_ELEMENT,'Receiver',strNS);
      root.appendChild(node);
    end;
Der Parser ist clever genug und merkt, dass das der Haupt-Namespace der Datei ist. Deswegen lässt er die Angabe im Code später weg, obwohl der Namespace faktisch natürlich da ist. Und damit sollte deine Datei eigentlich so aussehen, wie es gefordert wird:
Delphi-Quellcode:
    // XML-Code anzeigen, & speichern
    ShowMessage(xmldoc.xml);
    xmldoc.save(ExtractFilePath(paramstr(0)) + 'test.xml');

    // end of log :o)
  finally
    xmldoc := nil;
  end;
end;
Ich hoffe, das hilft dir weiter.
  Mit Zitat antworten Zitat
Keldorn

Registriert seit: 6. Mär 2003
Ort: Meißen
876 Beiträge
 
Delphi 10.1 Berlin Professional
 
#3

Re: Problem bei XML-Erstellung / Schemenangabe

  Alt 27. Okt 2004, 18:51
Zitat von MathiasSimmack:
Ich hoffe, das hilft dir weiter.
Tut es , Habs erstmal als Beispiel probiert und werds morgen dann umsetzen. Vielen Dank!!!!

Mfg Frank

Lükes Grundlage der Programmierung:
Es wird nicht funktionieren
(Murphy)
  Mit Zitat antworten Zitat
MathiasSimmack
(Gast)

n/a Beiträge
 
#4

Re: Problem bei XML-Erstellung / Schemenangabe

  Alt 27. Okt 2004, 20:27
Gern geschehen. Ich muss mich nämlich auch mal mit diesem Schema-Zeug befassen.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 06:46 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz