AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

CreateProcessAsUser

Ein Thema von toyoman · begonnen am 16. Nov 2004 · letzter Beitrag vom 19. Nov 2004
Antwort Antwort
Seite 1 von 2  1 2   
toyoman

Registriert seit: 2. Jun 2003
323 Beiträge
 
Delphi 2010 Enterprise
 
#1

CreateProcessAsUser

  Alt 16. Nov 2004, 08:21
hallo jungs

hab gesehen dass einige Beiträge schon über den API Aufruf CREATEPROCESSASUSER zu finden sind. Leider find ich kein lauffähiges Beispiel.

Meins sieht im Moment so aus, kriege aber immer nur Fehlermeldungen, sprich kann nicht mal notepad.exe starten..:

Code:
if not LogonUser
       (pchar(adminuser),pchar(admindomain),pchar(passwort),LOGON32_LOGON_INTERACTIVE, LOGON32_PROVIDER_DEFAULT,hToken) then
       begin
            logfileschreiben('LOGON FAILURE (Logon32_Interactive): Errorcode: '+inttostr(getlasterror));
       end else
       begin
            logfileschreiben('Interactive Logon successful!');
       end;
       if not ImpersonateLoggedOnUser(hToken) then
       begin
            logfileschreiben('LOGON FAILURE (ImpersonateLoggedonUser): Errorcode: '+inttostr(getlasterror));
       end else
       begin
            logfileschreiben('Impersonate Logon successful!');
       end;
       with sinfo do
       begin
            cb:=sizeof(sinfo);
            lpreserved:=nil;
            lpdesktop:=nil;
            lptitle:=nil;
            dwFlags:=0;
            cbReserved2:=0;
            lpReserved2:=nil;
            dwysize:=0;
       end;
       if not createprocessasuser(htoken,nil,pchar(command.text),nil,nil,true,0,nil,nil,sinfo,pinfo) then
       begin
            logfileschreiben('ERROR: CANNOT CreateProcessAsUser, CreateProcess Error: '+inttostr(getlasterror));
       end else
       begin
          repeat
              sleep(500);
              application.ProcessMessages;
              GetExitCodeProcess(pinfo.hProcess,ergebnis2);
          until ergebnis2<>STILL_ACTIVE;
       end;
       closehandle(htoken);
Hat jemand ein lauffähiges Beispiel oder eine Idee warum bei mir folgende Errorcodes erscheinen:

16.11.2004,08:01:48:Installing: notepad.exe
16.11.2004,08:01:48:Install-Type, Installation per: ADMIN
16.11.2004,08:01:48:Installation per USER or ADMIN selected.
16.11.2004,08:01:48:Installation per ADMIN Account running...
16.11.2004,08:01:48:Using Admin-Account: Domain\User
16.11.2004,08:01:48:Admin-Account password seems to be correct, try to install...
16.11.2004,08:01:48:Interactive Logon successful!
16.11.2004,08:01:48:Impersonate Logon successful!
16.11.2004,08:01:48:ERROR: CANNOT CreateProcessAsUser, CreateProcess Error: 2
16.11.2004,08:01:48:...Installed Setup removed from INI-File.
16.11.2004,08:01:48:Next Setup
16.11.2004,08:01:48:Awaiting possible reboot...
16.11.2004,08:01:50:..:: Closing Application ::..
16.11.2004,08:01:50:Awaiting termination - Installing

die ERROR Nummer ändert sich irgendwie immer.. war auch schon bei 5 oder bei 1314
  Mit Zitat antworten Zitat
toyoman

Registriert seit: 2. Jun 2003
323 Beiträge
 
Delphi 2010 Enterprise
 
#2

Re: CreateProcessAsUser

  Alt 17. Nov 2004, 08:10
hat noch niemand diesen Befehl erfolgreich genutzt??????
  Mit Zitat antworten Zitat
Benutzerbild von Marcel Gascoyne
Marcel Gascoyne

Registriert seit: 18. Nov 2003
Ort: Uetersen
271 Beiträge
 
Delphi 2005 Architect
 
#3

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 07:27
Bei mir läuft es tadellos, hier der Quellcode für ein Consolen-Programm (es werden die WinAPI Units benötigt):

Delphi-Quellcode:
program runadmin;

{$APPTYPE CONSOLE}

uses
  System, SysUtils, JwaWinBase;

var
  si: STARTUPINFOW;
  pif: PROCESS_INFORMATION;
  res: Boolean;
  s: string;
  cmd: PWideChar;
begin
  if Length(ParamStr(1)) = 0 then
    WriteLn(
      'RunAdmin - Kommando unter Administrator-Konto ausführen' + #13#10 +
      'Usage: runadmin <command>')
  else
  try
    si.cb := SizeOf(startupinfow);
    si.dwFlags := STARTF_USESHOWWINDOW;
    si.wShowWindow := 1;
    si.lpReserved := nil;
    si.lpDesktop := nil;
    si.lpTitle := 'Konsole';
    getmem(cmd,Length(ParamStr(1))*2);
    cmd := StringToWideChar(ParamStr(1),cmd,Length(ParamStr(1))*2);
    res := CreateProcessWithLogonW('Administrator', '', 'password', LOGON_WITH_PROFILE,
      nil,cmd,CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
    if booltostr(res) = '0then
    begin
      str(GetLastError, s);
      WriteLn('Beim Ausfuehren des Befehls "' + ParamStr(1) + '"');
      WriteLn('ist der Fehler ' + s + ' aufgetreten.');
      Halt(1);
    end;
  except
    on E: Exception do
    begin
      WriteLn('Beim Ausfuehren des Befehls "' + ParamStr(1) + '"');
      WriteLn('ist der Fehler ' + E.Message + ' aufgetreten.');
      Halt(1);
    end;
  end;

end.
Gruß,
Marcel
Marcel Gascoyne
Der Fehler sitzt immer vor der Tastatur
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#4

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 08:42
Ich habe den Code etwas umgebaut und sieht jetzt so aus:
Delphi-Quellcode:
uses MpuWinNT;

function CreateProcessAsLogon(const User, PW, Application: string):
  Boolean;
var
  s : string;
  si : TStartupInfoW;
  pif : TProcessInformation;
  wUser : PWideChar;
  wPW : PWideChar;
  wApp : PWideChar;
begin
  si.cb := SizeOf(TStartupInfoW);
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := 1;
  si.lpReserved := nil;
  si.lpDesktop := nil;
  si.lpTitle := nil;

  wAPP := GetMemory(length(Application) * 2);
  wApp := StringToWideChar(Application, wApp, length(Application) * 2);
  wUser := GetMemory(length(User) * 2);
  wUser := StringToWideChar(User, wUser, length(User) * 2);
  wPW := GetMemory(length(PW) * 2);
  wPW := StringToWideChar(PW, wPW, length(PW) * 2);
  result := CreateProcessWithLogonW(wUser, '', wPW, LOGON_WITH_PROFILE,
    nil, wApp, CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
  FreeMem(wUser);
  FreeMem(wPW);
  FreeMem(wApp);
end;
Das witzige ist: So bald ich die Stringvariable s auskommentiere, wird der Prozess nicht mehr gestartet und ich bekomme den Fehler: "Falscher Parameter". Das passiert sowohl mit GetMemory, AllocMem und als auch mit GetMem. Lasse ich es drinne, läuft alles prima. Das gleiche passiert, wenn ich die Speicherreservierung und -freigabe in einem try-finally-Block kapsele. irgendwas bringt da meinen Speicher mächtig durcheinander.
Ächtz. Jetzt habe ich es in einen try-finally-Block gekapselt, s auskommentiert und es kommt der Fehler, wenn ich Return drücke, wenn der Button den Fokus hat. Klicke ich mit der Maus, klappt es.

Die Unit MpuWinNT befindet sich im Anhang.
Angehängte Dateien
Dateityp: pas mpuwinnt.pas (9,5 KB, 198x aufgerufen)
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
toyoman

Registriert seit: 2. Jun 2003
323 Beiträge
 
Delphi 2010 Enterprise
 
#5

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 10:52
Ich habs nun endlich, nach ein paar Tagen Testen Testen und nochmals testen.
Wir können jetzt den SAP Mobile client damit installieren, DOS Befehle absetzen, VBS Skripte ausführen, EXE und MSI's.
Der springende Punkt war die richtige Übergabe de lpApplicationname und lpCommandline.
Wird die Commandline mit Parametern in einer Zeile übergeben muss der lpApplicationName blank sein ('').

Delphi-Quellcode:
var
   kommando:string;
   cCmd: array [0..1023] of char;
   serviceok:integer;
   s:textfile;
   ersteszeichen:string;
   ergebnis2:dword;
   si: STARTUPINFOW;
   pif: PROCESS_INFORMATION;
   res: Bool;
   ss: string;



procedure....
      //erstmal die StartUpInfoW setzen
      //set StartUpInfoW first
      si.cb := SizeOf(startupinfow);
      si.dwFlags := STARTF_USESHOWWINDOW;
      si.wShowWindow := SW_SHOWDEFAULT;
      si.lpReserved := nil;
      si.lpDesktop := nil;
      si.lpTitle := 'HILTI Installer - RUNAS';
      // dann CreateProcessWithLogonW ausführen...
      // run CreateProcessWithLogonW...
      logfileschreiben('Converting to absolute paths: '+command.text);
      command.text:=replaceStr(command.text,'.\',getpath);
      res := CreateProcessWithLogonW(StringToOleStr(adminuser), StringToOleStr(admindomain), StringToOleStr(passwort), LOGON_WITH_PROFILE,
      StringToOLEstr(''), StringToOLEstr(command.text)
      , CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
      logfileschreiben('Created: '+StringToOLEstr(command.text));
      logfileschreiben('Waiting for process and checking for errors...');
          repeat
              sleep(500);
              application.ProcessMessages;
              GetExitCodeProcess(pif.hProcess,ergebnis2);
          until ergebnis2<>STILL_ACTIVE;
      if booltostr(res) = '0then
      begin
          //wenn ein Fehler auftritt, soll der Fehlercode ausgegeben werden
          //über 'net helpmsg ' in der Kommandoeingabeaufforderung
          //kann dieser entziffert werden

          //if an error occures, show the error-code
         //this code can be 'translated' with 'net helpmsg ' on command-prompt
        str(GetLastError, ss);
        logfileschreiben('ERROR: CreateProcessWithLogonResult: ' + booltostr(res) +
          ' --> GetLastError: ' + ss);
      end;
      //closehandle(pif.hProcess);
end;
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#6

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 10:58
Für mich ist damit mein Problem aber immer noch nicht geklärt.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#7

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 11:58
So geht es:
Delphi-Quellcode:
uses MpuWinNT;

function CreateProcessAsLogon(const User, PW, Application: WideString):
  Boolean;
var
  si : TStartupInfoW;
  pif : TProcessInformation;
begin
  si.cb := SizeOf(TStartupInfoW);
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := 1;
  si.lpReserved := nil;
  si.lpDesktop := nil;
  si.lpTitle := nil;
  Result := CreateProcessWithLogonW(PWideChar(User), nil, PWideChar(PW),
    LOGON_WITH_PROFILE, nil, PWideChar(Application),
    CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  if not CreateProcessAsLogon('Administrator', 'gina', 'Notepad.exe') then
    RaiseLastOSError;
end;
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
toyoman

Registriert seit: 2. Jun 2003
323 Beiträge
 
Delphi 2010 Enterprise
 
#8

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 12:29
Zitat von Luckie:
So geht es:
Delphi-Quellcode:
uses MpuWinNT;

function CreateProcessAsLogon(const User, PW, Application: WideString):
  Boolean;
var
  si : TStartupInfoW;
  pif : TProcessInformation;
begin
  si.cb := SizeOf(TStartupInfoW);
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := 1;
  si.lpReserved := nil;
  si.lpDesktop := nil;
  si.lpTitle := nil;
  Result := CreateProcessWithLogonW(PWideChar(User), nil, PWideChar(PW),
    LOGON_WITH_PROFILE, nil, PWideChar(Application),
    CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  if not CreateProcessAsLogon('Administrator', 'gina', 'Notepad.exe') then
    RaiseLastOSError;
end;
Probier hier mal mit Parametern ein Setup Programm aufzurufen oder gar ein Batchfile.. dann siehts wieder anders aus, bzw dann siehst du was ich für Probleme hatte... Ein EXE allein aufzurufen geht relativ schnell mal
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#9

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 12:34
Geht prima:
Delphi-Quellcode:
uses MpuWinNT;

function CreateProcessAsLogon(const User, PW, Application, CmdLine: WideString):
  Boolean;
var
  si : TStartupInfoW;
  pif : TProcessInformation;
begin
  si.cb := SizeOf(TStartupInfoW);
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := 1;
  si.lpReserved := nil;
  si.lpDesktop := nil;
  si.lpTitle := nil;
  Result := CreateProcessWithLogonW(PWideChar(User), nil, PWideChar(PW),
    LOGON_WITH_PROFILE, nil, PWideChar(Application +' '+CmdLine),
    CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  if not CreateProcessAsLogon('Administrator', 'passwort', 'Notepad.exe', 'c:\boot.ini') then
    RaiseLastOSError;
end;
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
toyoman

Registriert seit: 2. Jun 2003
323 Beiträge
 
Delphi 2010 Enterprise
 
#10

Re: CreateProcessAsUser

  Alt 18. Nov 2004, 12:49
Zitat von Luckie:
Geht prima:
Delphi-Quellcode:
uses MpuWinNT;

function CreateProcessAsLogon(const User, PW, Application, CmdLine: WideString):
  Boolean;
var
  si : TStartupInfoW;
  pif : TProcessInformation;
begin
  si.cb := SizeOf(TStartupInfoW);
  si.dwFlags := STARTF_USESHOWWINDOW;
  si.wShowWindow := 1;
  si.lpReserved := nil;
  si.lpDesktop := nil;
  si.lpTitle := nil;
  Result := CreateProcessWithLogonW(PWideChar(User), nil, PWideChar(PW),
    LOGON_WITH_PROFILE, nil, PWideChar(Application +' '+CmdLine),
    CREATE_DEFAULT_ERROR_MODE, nil, nil, si, pif);
end;


procedure TForm1.Button1Click(Sender: TObject);
begin
  if not CreateProcessAsLogon('Administrator', 'passwort', 'Notepad.exe', 'c:\boot.ini') then
    RaiseLastOSError;
end;

Was ist das für eine Unit MPUWinnt?
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 01:13 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz