TFileStream.Write / .Read

[StanY]

Ich habe das Problem, dass ich per TFileStream eine Integervariable hineinschreibe, sie jedoch falsch ausglesen wird.

Write:

Delphi-Quellcode:

  try
    F := TFileStream.Create(FName,fmCreate); //ja, FName ist gesetzt
  finally
    Size := Length(Connection);
    WriteLn(Size); //LIEFERT 1 ZURÜCK
    F.Write(Size,SizeOf(Size));

    F.Free;
  end;

Read:

Delphi-Quellcode:

  try
    F := TFileStream.Create(FName,fmOpenRead); //ja, FName ist gesetzt
  finally
    Size := F.Read(Size,SizeOf(Size));
    WriteLn(IntToStr(Size)); //GIBT 4 AUS
    
    F.Free;
  end;

Was mache ich falsch?

edit: ui, hundertste Beitrag - er, Frage ^^

[Dax]

So geht es:

Delphi-Quellcode:

  try
    F := TFileStream.Create(FName,fmOpenRead); //ja, FName ist gesetzt
  finally
    F.Read(Size,SizeOf(Size));
    WriteLn(IntToStr(Size)); //GIBT 4 AUS
   
    F.Free;
  end;

Die Methode TStream.Read gibt als Rückgabewert die Zahl der ausgelesenen Bytes

[StanY]

Danke (:.

[Luckie]

Was sind das für seltsame Ressourcenschutzblöcke?

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var
  fs: TFileStream;
  i: Integer;
begin
  fs := TFileStream.Create('d:\test.txt', fmCreate);
  try
    i := 36;
    fs.WriteBuffer(i, sizeof(Integer));
  finally
    FreeAndNil(fs);
  end;
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  fs: TFileStream;
  i: Integer;
begin
  fs := TFileStream.Create('d:\test.txt', fmOpenRead);
  try
    fs.ReadBuffer(i, sizeof(Integer));
    ShowMessage(IntToStr(i));
  finally
    FreeAndNil(fs);
  end;
end;

so wie ihr die da habt bringen sie absolut nichts.

[StanY]

Naja, SizeOf(Size) und SizeOf(Integer) sind ja, da Size eine Integervariable ist, deckungsggliech?

[Luckie]

Jupp. Hat aber nichts damit zu tun, dass dein Ressourcenschutzblock für den Popo ist und somit eigentlich keiner ist. Was wenn es beim Schreiben kracht? Dann fliegst du aus dem finally Abschnitt raus und wie geht es dann weiter?

Der finally Abschnittt ist dazu da, dass Code noch abgearbeitet wird, wenn im vorangegangenem try Abschnitt eine Exception aufgetreten ist.

[jim_raynor]

Zitat von StanY:

Naja, SizeOf(Size) und SizeOf(Integer) sind ja, da Size eine Integervariable ist, deckungsggliech?

Naja, ihm ging es aber mehr darum, was du vor und was du nach dem finally schreibst.

[StanY]

Achso, okay. Danke (:.