AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Code-Bibliothek Library: Dateien / Laufwerke Delphi Dateiversionsinformationen auslesen

Dateiversionsinformationen auslesen

Ein Thema von sakura · begonnen am 22. Mai 2003 · letzter Beitrag vom 11. Sep 2005
Antwort Antwort
Benutzerbild von sakura
sakura

Registriert seit: 10. Jun 2002
Ort: München
11.586 Beiträge
 
Delphi 10.4 Sydney
 
#1

Dateiversionsinformationen auslesen

  Alt 22. Mai 2003, 12:54
Ich habs gerade gebraucht und alten Code von mir hier gefunden. Jetzt kommt der zur Abwechslung auch einmal in die Code Library

Delphi-Quellcode:
function GetFileInfo(
  var aInternalName, aFileVersion: String; FileName: AnsiString
): Boolean;
var
  VersionInfoSize, VerInfoSize, GetInfoSizeJunk: DWORD;
  VersionInfo, Translation, InfoPointer: Pointer;
  VersionValue: AnsiString;
begin
  Result := False;
  VerInfoSize := GetFileVersionInfoSize(PChar(FileName), GetInfoSizeJunk);
  if VerInfoSize > 0 then
  begin
    GetMem(VersionInfo, VerInfoSize);
    try
      GetFileVersionInfo(PChar(FileName), 0, VerInfoSize, VersionInfo);
      VerQueryValue(
        VersionInfo, '\\VarFileInfo\\Translation', Translation, VerInfoSize
      );
      VersionValue :=
        '\\StringFileInfo\\' + IntToHex(LoWord(LongInt(Translation^)), 4) +
        IntToHex(HiWord(LongInt(Translation^)), 4) + '\\';
      VersionInfoSize := 0;

      VerQueryValue(
        VersionInfo, PChar(VersionValue + 'InternalName'), InfoPointer,
        VersionInfoSize
      );
      aInternalName := AnsiString(PChar(InfoPointer));

      VerQueryValue(
        VersionInfo, PChar(VersionValue + 'FileVersion'), InfoPointer,
        VersionInfoSize
      );
      aFileVersion := AnsiString(PChar(InfoPointer));

    finally
      FreeMem(VersionInfo);
    end;
    aInternalName := Trim(aInternalName);
    aFileVersion := Trim(aFileVersion);
    Result := (aInternalName <> '') and (aFileVersion <> '');
  end;
end;
Daniel W.
Ich bin nicht zurück, ich tue nur so
  Mit Zitat antworten Zitat
Benutzerbild von sakura
sakura

Registriert seit: 10. Jun 2002
Ort: München
11.586 Beiträge
 
Delphi 10.4 Sydney
 
#2
  Alt 22. Mai 2003, 13:00
Nachtrag, wer andere Werte auslesen will, kann die folgenden Codezeilen entsprechend anpassen.
Delphi-Quellcode:
      VerQueryValue(
        VersionInfo, PChar(VersionValue + 'InternalName'), InfoPointer,
        VersionInfoSize
      );
      aInternalName := AnsiString(PChar(InfoPointer));
......
Daniel W.
Ich bin nicht zurück, ich tue nur so
  Mit Zitat antworten Zitat
CalganX

Registriert seit: 21. Jul 2002
Ort: Bonn
5.403 Beiträge
 
Turbo Delphi für Win32
 
#3

Re: Dateiversionsinformationen auslesen

  Alt 11. Sep 2005, 12:56
Ein Nachtrag von himitsu:

So, hier sind noch einige Werte, welche bestimmt interessant sein könnten.

Links ist der Wert, welcher verwendet werden muß und Rechts gibt's den Namen, welchen man im deutschen Delphi findet (natürlich in den Projektoptionen unter Versionsinfo).
Code:
CompanyName       Firmenname
FileDescription   Beschreibung
FileVersion       Dateiversion
InternalName      Interner Name
LegalCopyright    Copyright
LegalTrademarks   Warenzeichen
OriginalFilename  Originaldateiname
ProductName       Produktname
ProductVersion    Produktversion
Comments          Kommentare

Und zum Schluß sei noch erwähnt, dass man sich die Werte auch als WideString besorgen kann.
In diesem Fall muß man halt nur statt String/AnsiString das WideString verwenden.
Für Char/AnsiChar wird ebenfalls WideChar eingesetzt und natürlich braucht man dann noch die passenden UnicodeVersionen:

Code:
// die AnsiVarianten
GetFileVersionInfoSize
GetFileVersionInfo
VerQueryValue

GetFileVersionInfoSize[b]A[/b]
GetFileVersionInfo[b]A[/b]
VerQueryValue[b]A[/b]

// die WideVarianten
GetFileVersionInfoSize[b]W[/b]
GetFileVersionInfo[b]W[/b]
VerQueryValue[b]W[/b]

Sakura's Beispiel wird dann also zu:
Delphi-Quellcode:
Function GetFileInfo(Var aInternalName, aFileVersion: WideString; FileName: WideString): Boolean;
  Var VersionInfoSize, VerInfoSize, GetInfoSizeJunk: LongWord;
    VersionInfo, Translation, InfoPointer: Pointer;
    VersionValue: WideString;

  Begin
    Result := False;
    VerInfoSize := GetFileVersionInfoSize(PChar(FileName), GetInfoSizeJunk);
    If VerInfoSize > 0 Then Begin
      GetMem(VersionInfo, VerInfoSize);
      Try
        GetFileVersionInfo(PWideChar(FileName), 0, VerInfoSize, VersionInfo);

        VerQueryValue(VersionInfo, '\\VarFileInfo\\Translation', Translation, VerInfoSize);
        VersionValue := '\\StringFileInfo\\' + IntToHex((PLongInt(Translation)^ shl 16)
          or (PLongInt(Translation)^ shr 16), 8) + '\\';
        VersionInfoSize := 0;

        VerQueryValue(VersionInfo, PWideChar(VersionValue + 'InternalName'), InfoPointer, VersionInfoSize);
        aInternalName := Trim(PWideChar(InfoPointer));

        VerQueryValue(VersionInfo, PWideChar(VersionValue + 'FileVersion'), InfoPointer, VersionInfoSize);
        aFileVersion := Trim(PWideChar(InfoPointer));

      Finally
        FreeMem(VersionInfo);
      End;
      Result := (aInternalName <> '') and (aFileVersion <> '');
    End;
  End;
Wenn allerdings jemand zwar die Werte als WideString erhalten, aber dennoch den Dateinamen per Ansi übergeben will, der wird vermutlich zufrieden sein, wenn er/sie zwei kleine Zeilen durch folgende ersetzt.
Delphi-Quellcode:
Function GetFileInfo(Var aInternalName, aFileVersion: WideString; FileName: AnsiString): Boolean;
GetFileVersionInfo(PAnsiChar(FileName), 0, VerInfoSize, VersionInfo);
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 14:47 Uhr.
Powered by vBulletin® Copyright ©2000 - 2023, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf