Funktionsbibiliothek - Objekttypunabhängig machen

[Ulf346C]

Ich möchte bestimmte, immer wiederkehrende Datenbankfunktionen in eine Bibiliothek packen.

Dummerweise habe ich drei verschiedene SQL-Objekttypen:
- tQuery
- tzQuery
- tzReadOnlyQuery

ich hatte mir das etwas so vorgestellt:

Delphi-Quellcode:

function tdbf.OpenSql(var query1: tObject; tabelle, feld: string; wert: integer): boolean;
begin
  if query1.className = 'tzQuery' then 
  with (query1 as tzQuery) do begin
    close;
    sql.text := 'select * from ' + tabelle + ' where ' + feld + ' = ' + inttostr(wert);
    open;
    result := not (eof and bof);
  end;
  if query1.className = 'tQuery' then 
  with (query1 as tQuery) do begin
    ...
  end;
  if query1.className = 'tzReadOnlyQuery' then 
  with (query1 as tzReadOnlyQuery) do begin
    ...
  end;
end;

dummerweise funktioniert das nicht (Typenfehler wird gemeldet)
woran liegts

[Bernhard Geyer]

Du mußt die gemeinsame Basisklasse von allen 3 Nehmen und die wird TDataset sein
function tdbf.OpenSql(var query1: TDataset; tabelle, feld: string; wert: integer): boolean;

[Flocke]

Classname kann ja auch anders groß-/kleingeschrieben sein.
Probier's so:

Delphi-Quellcode:

function tdbf.OpenSql(var query1: tObject; tabelle, feld: string; wert: integer): boolean;
begin
  if query1 is tzQuery then
  with tzQuery(query1) do begin
    close;
    sql.text := 'select * from ' + tabelle + ' where ' + feld + ' = ' + inttostr(wert);
    open;
    result := not (eof and bof);
  end;
  if query1 is tQuery then
  with tQuery(query1) do begin
    ...
  end;
  if query1 is tzReadOnlyQuery then
  with tzReadOnlyQuery(query1) do begin
    ...
  end;
end;

[Nachtrag]

WO WAR DER ROTE KASTEN???

TDataSet wird die Eigenschaft 'Sql' nicht haben. Gibt's vielleicht eine andere gemeinsame Basisklasse? Stammt tzReadOnlyQuery ggf. von tzQuery ab (dann kannst du dir den dritten Teil sparen)?

[Ulf346C]

tDataset als Basisklasse funktioniert durchaus, dafür ist ja
 (with query1 as tzQuery) Das funktioniert auch solange ich auf var - Parameter verzichte.
Was in diesem Fall aber keinen Sinn macht, weil ich ja hinterher eine geöffnete Datenmenge haben will.

scheinbar ist bei var-Parametern die Typprüfung besonders streng.

*kopfkratz*

[Flocke]

Du willst doch nichts an Query1 zuweisen, darum brauchst du keinen var-Parameter.

Nochwas: ich würde dir trotzdem den Test mit "Query is tzQuery" empfehlen, weil du die Routine dann auch für von tzQuery abgeleitete Klassen benutzen könntest.

[Ulf346C]

doch; query1 ist ja Platzhalter für ein beliebiges Datenbankobjekt.

lasse ich "var" weg, läuft die Funktion zwar durch aber die Tabelle ist nach dem Funktionsaufruf nicht geöffnet

[shmia]

Du musst Unterscheiden zwischen Hilfsfunktionen, die mit TDataset klarkommen und Hilfsfunktionen, die
die Eigenschaft SQL beeinflussen.

Hier ein Beispiel, für eine Funktion, die nur mit TDataset arbeitet:

Delphi-Quellcode:

{**************************************************************************
 * NAME:    CopyDataSetRecord
 * DESC:    Kopiert alle gleichnamigen Felder aus Src nach Dst.
 *          Dst.State muss in [dsEdit,dsInsert] sein, sonst wird ne
 *          Exception geschmissen.
 *          Es findet keinerlei Prüfung auf Datentypen statt!
 * PARAMS:  Src,Dst: TDataSet
 * RESULT:  None
 *************************************************************************}
procedure CopyDataSetRecord(Src,Dst: TDataSet);
var
   i: Integer;
   fSrc,fDst: TField;
begin
   for i := 0 to Src.FieldCount-1 do
   begin
      fSrc := Src.Fields[i];
      fDst := Dst.FindField(fSrc.FieldName);

      if Assigned(fDst) then
      begin
         fDst.Value := fSrc.Value;
      end;
   end;
end;

Wenn du mit SQL-Anweisungen arbeiten willst, dann schreibst du deine Funktionen am Besten so, dass nur mit TStrings gearbeitet wird.
Beispiel:

Delphi-Quellcode:

{**************************************************************************
 * NAME:    CleanSqlStrings
 * DESC:    entferne Kommentarzeilen aus TStrings
 *************************************************************************}
procedure CleanSqlStrings(SQL:TStrings);
var
   s : string;
   i : Integer;
begin
   Assert(Assigned(SQL));
   for i := SQL.Count-1 downto 0 do
   begin
      s := Copy(SQL[i],1 ,2);
      if (s = '--') or (s='//') then
         // Kommentarzeile entfernen
         SQL.Delete(i);
   end;
end;
{**************************************************************************
 * NAME:    LoadSqlStrings
 * DESC:    Lade eine SQL-Datei in TStrings und entferne Kommentarzeilen
 *************************************************************************}
procedure LoadSqlStrings(SQL:TStrings; const filename:string);
begin
   Assert(Assigned(SQL));

   // Datei laden
   SQL.LoadFromFile(filename);

   // Kommentarzeilen entfernen
   CleanSqlStrings(SQL);
end;

Später in der Anwendung stellt sich dann das Problem mit dem SQL-Property nicht mehr:
   LoadSqlString(IBQuery1.SQL, 'Summery.SQL');

[Ulf346C]

Flocke hat Recht

es geht auch ohne var Parameter
(warum das geht leuchtet mit bloß nicht ganz ein)

...bloß zwischen IDE und Laufzeit werden die class-Namen anders geschrieben

egal; so funktioniert es jetzt:

Delphi-Quellcode:

function tdbf.OpenSql(query1: tDataSet; tabelle, feld: string; wert: integer): boolean;
var t: string;
begin
  query1.close;
  t := 'select * from ' + tabelle + ' where ' + feld + ' = ' + inttostr(wert);
  if uppercase(query1.classname) = 'TZQUERY'
    then (query1 as tzQuery).sql.text := t;
  if uppercase(query1.classname) = 'TQUERY'
    then (query1 as tQuery).sql.text := t;
  if uppercase(query1.classname) = 'TZREADONLYQUERY'
    then (query1 as tzReadOnlyQuery).sql.text := t;
  query1.open;
  result := not (query1.eof and query1.bof);
end;

[Flocke]

Zitat von Ulf346C:

...bloß zwischen IDE und Laufzeit werden die class-Namen anders geschrieben

Als wenn ich das nicht geschrieben hätte
Mache den Test besser mit is und danach einfach einen festen Cast:

Delphi-Quellcode:

function tdbf.OpenSql(query1: tDataSet; tabelle, feld: string; wert: integer): boolean;
var t: string;
begin
  query1.close;
  t := 'select * from ' + tabelle + ' where ' + feld + ' = ' + inttostr(wert);
  if query1 is TZQUERY then
    tzQuery(query1).sql.text := t
  else if query1 is TQUERY then
    tQuery(query1).sql.text := t
  else if query1 is TZREADONLYQUERY then
    tzReadOnlyQuery(query1).sql.text := t;
  query1.open;
  result := not (query1.eof and query1.bof);
end;

//Edit: Semikola korrigiert