Integer --> null vor zahl?

[marabu]

Hallo Leute,

Zitat von Daniel G:

Format ist das, was du suchst...

warum drum herum zeigen? Kann denn keiner den format string fs angeben, der im folgenden Beispiel "001" ausgibt?

Delphi-Quellcode:

var
  fs: string;
begin
  fs := '"%d"';  // hier korrigieren
  ShowMessage(Format(fs, [1]));
end;

Grüße vom marabu

[Flocke]

Delphi-Quellcode:

var
  fs: string;
begin
  fs := '"%3.3d"';  // hier korrigieren
  ShowMessage(Format(fs, [1]));
end;

[marabu]

Danke Volker,

um wieviel wertvoller wird doch ein thread, wenn nicht einfach nur auf die Online-Hilfe verwiesen wird...

In meiner Code Library benötige ich Funktionen, die allgemein verwendbar sind:

Delphi-Quellcode:

function ZeroPad(s: string; size: word): string;
begin
  if Length(s) < size
    then Result := StringOfChar('0', size - Length(s)) + s
    else Result := s;
end;

Wenn ich meiner Funktion aus TP Zeiten die angepasste Version mit Format() gegenüberstelle, dann liefern 1 Mio Durchläufe das Verhältnis ZeroPad : ZeroFmt = 10 : 14. Nur zur Information.

Delphi-Quellcode:

function ZeroFmt(n: cardinal; size: word): string;
begin
  Result := Format(Format('%%%d.%dd', [size, size]), [n]);
end;

Freundliche Grüße vom marabu

[LoRd-MuldeR]

Ich würde mir für diesen Zweck ne kleine Hilfs-Funktion basteln:

Delphi-Quellcode:

function MyIntToStr(Value:Integer; Digits:Integer):String;
begin
  Result := IntToStr(Value);
  while Length(Result) < Digits do
    Result := '0' + Result;
end;

MyIntToStr(1, 4) = '0001';

[Daniel G]

Zitat von marabu:

Kann denn keiner den format string fs angeben, der im folgenden Beispiel "001" ausgibt?
Grüße vom marabu

Doch, kann ich, tue ich aber nicht. Schließlich steht alles in der Hilfe. Ich will damit lediglich Eigeninitiative fördern...

[Kroko1999]

ich benutzte für diesen Fall folgende Proc:

Delphi-Quellcode:

type
{== Range-Type ==}
  TBaseRange = 2..36;
  TDigitRange = 0..31;
  TGroupRange = 0..15;

function ZifferToChar (Z: TZiffern): Char;
begin
  case Z of
    0..9:   Result := Chr($30+Z);
    10..36: Result := Chr($41-10+Z);
  else Result := '*';
  end;
end;

function IntegerFormat (Value: Int64;                // zu formatierende Int64-Wert
                        ASign: Boolean;              // soll die Zahl ein Vorzeichen besitzen
                        ABasis: TBaseRange;          // Zahlenbasis bis 2..36
                        ADigits: TDigitRange;        // wieviel Stellen soll das Ergebnis haben
                        ATPGroup: TGroupRange;       // wieviel Teile sollen Gruppen haben (zBsp.Tausenderpunkt)
                        ATPChar: Char): String;      // wie sollen Gruppen getrennt werden
var
  C: String[1];
  OldMax,
  HMax,
  Max: Int64;
begin
  Result := '';
  if Value<0 then C := '-'
  else
    begin
      if ASign then C := '+'
               else C := '';
    end;
  Value := Abs(Value);
  if Value<2 then Result := ZifferToChar(Value)
  else
    begin
      Max := 1;
      OldMax := Max;
      while Max<=Value do
      begin
        OldMax := Max;
        Max := Max*ABasis;
      end;
      Max := OldMax;
      if Max=0 then Result := Result+'0'
      else
        repeat
          HMax := Value div Max;
          Result := Result+ZifferToChar(HMax);
          Dec (Value,HMax*Max);
          Max := Max div ABasis;
        until Max=0;
    end;
  if ADigits>0 then
    while Length(Result)<ADigits do Result := '0'+Result;
  if (ATPChar>#0) and (ATPGroup>0) then
    begin
      HMax := ATPGroup-1;
      while HMax<Length(Result) do
      begin
        Insert (ATPChar,Result,Length(Result)-HMax);
        Inc (HMax,ATPGroup+1);
      end;
     if Result>'' then
       if Result[1]=ATPChar then Delete (Result,1,1);
    end;
  Result := C+Result;
end;

[Jelly]

Zitat von Daniel G:

Doch, kann ich, tue ich aber nicht. Schließlich steht alles in der Hilfe. Ich will damit lediglich Eigeninitiative fördern...

Dann kannst Du Dir deine so *konstruktiven* Beiträge auch sparen...

Mit der Format Funktion geht da jedenfalls so:
S := Format ('%.3d',[DeineZahl]) ; liefert dir einen String S mit 3 Stellen, mit führenden Nullen.

[tigerman33]

Zitat:

Dann kannst Du Dir deine so *konstruktiven* Beiträge auch sparen...

Sinn der Sache hier ist ja nicht, die Lösung auf dem silbernen Tablett serviert zu bekommen, sondern Denkanstöße zu erhalten. Das lässt sich übrigens schon aus dem Verhaltenskodex rauslesen.

[Jelly]

Ach, Du meinst wie in der Schule
Also mal ehrlich. Es war ne klare, simple Frage, warum muss denn da um den Brei rumgeschwafelt werden, statt einfach eine Zeile Code zu posten. So steht das in keinem Kodex, sorry. Denn sonst darfst Du gar keinen Code mehr posten, sondern verweisst nur noch auf OH und andere Quellen. Ich geb Dir recht, wenn einer kommt, der keinen Bock hat was selbst zu machen, und hier im Forum ne Antwort sucht. Aber in diesem Fall war das nicht etwa eine "keine Bock Frage", sondern ein einzelnes, konkretes und kleines Problemchen.

[DGL-luke]

kleine Anmerkung: In der D2005-Hilfe sind solche Sachen nicht drin. Zumindest nicht bei der PE.