AccessViolation bei Parameterübergabe (RecieveBuf)

[Bloodfire]

Hi!

Ist daran etwas falsch?

Delphi-Quellcode:

procedure TInvitationForm.TcpServerAccept(Sender: TObject;
  ClientSocket: TCustomIpClient);
var
  AInfo: RInvitation;
  APort: Integer;
begin
   ClientSocket.ReceiveBuf(AInfo,SizeOf(AInfo));

   AIFiles.Status:=AInfo.Status;
   AIFiles.UsePort:=AInfo.UsePort;
end;

Sofort bei
AIFiles.Status:=AInfo.Status; kommt eine Zugriffsverletzung und ich weiß ehrlich gesagt nicht, weshalb?


Hier noch die Sende-Prozedur:

Delphi-Quellcode:

procedure TInvitationForm.Send(FText: String; FPort: Integer);
var
  AInfo: RInvitation;
begin
   AInfo.Status:=FText;
   AInfo.UsePort:=FPort;

   try
    if TcpClient.Connect then
      begin
         TcpClient.SendBuf(AInfo,SizeOf(AInfo));
      end;
   finally
     TcpClient.Disconnect;
   end;
end;

Danke im Vorraus.

[GuenterS]

Vermutlich hast Du AIFiles nicht erzeugt.

Einfach an der Stelle mal einen Haltepunkt machen und schauen was davon nicht erzeugt wurde, also nil ist.

[SirThornberry]

wie ist RInvitation definiert?

[Bloodfire]

Definition lautet wie folgt:

Delphi-Quellcode:

type
RInvitation = record
    Status: String;
    UsePort: Integer;
  end;

Einen Record kann man ja nicht erzeugen, oder? (bzw. String & Integer)


Jetzt hab ich's übrigens noch ein paar mal probiert und manchmal geht's sogar!? Und manchmal eben nicht.
Das sind die unausstehlichsten Fehler ... wenn's mal funkt und dann wieder nicht - wo soll man denn da anfangen den Fehler zu suchen?

[GuenterS]

Hm stell doch mal das ganze irgendwie rein, dass mans anschaun kann. Meine Glaskugel mag heute nicht so, schließlich ist Sonntag.

[Bloodfire]

Das gesamte Projekt umfasst sicher schon -zig Seiten, also werd ich mal versuchen, wesentliches herauszunehmen:

Backgroundinfo: Es is ein Lan-Schachspiel. Es gibt ein Hauptforum, auf dem alle Spieler, die online sind, aufgelistet werden. Per PopUp in 'ner Listbox kann man dann einzelne Spieler zu einem Schachspiel herausfordern. Dazu öffnet sich eine 'Einladungsform' (Showmodal-Form), wo gefragt wird, ob man die Einladung annehmen möchte. Und hier tritt der Fehler auf.

Hier wird per PopUp-Klick der User eingeladen:

Delphi-Quellcode:

procedure TMainForm.PopUpGameClick(Sender: TObject);
var
  ARemoteHost: String;
  SendText: String;
  AInviteFiles: RInvitation;
  i: Integer;
  AOppNick: String;
begin
   if (UserList.ItemIndex<0)
     then exit;

   AOppNick:=UserList.Items[UserList.ItemIndex];

   { wenn schon Schachbrett mit dieser Person offen, dann abbrechen }
   for i:=0 to Boards.Count-1 do
     if (AOppNick = TBoardForm(Boards.Items[i]).GlobalFiles.Opponent.Nickname)
       then exit;

   { Eigenschaften des herausgeforderten Gegners setzen }
   Opponent.IP:=UserIp.Items[UserList.ItemIndex];
   Opponent.Nickname:=AOppNick;

   { Nachricht an Gegner schicken }
   SendText:='OpenChess#'+Opponent.IP+'#'+UserData.LocalIP+'#'
     +UserData.Nickname+'#'+IntToStr(UserData.Elo);
   UDPClient.Broadcast(SendText,MainPort);

   ARemoteHost:=UserIP.Items[UserList.ItemIndex];

   { Einladungsform öffnen }
   Invitation:=TInvitationForm.Create(MainForm);
   AInviteFiles:=Invitation.SetFiles('Inviter',Opponent.Nickname,Language,Paths,
     ARemoteHost, 5700, Boards);

   if (AInviteFiles.Status = 'StartGame') then
     begin
        OpenBoard(AInviteFiles.UsePort);
     end;
end;

Und hier die wichtigsten Routinen des Einladeform-Objektes:

Delphi-Quellcode:

unit u_invitation;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, ExtCtrls, u_paths, IniFiles, JPeg, Sockets, Contnrs,
  u_Board;

type
  TInvitationForm = class(TForm)
    ImgBG: TImage;
    LabelText: TLabel;
    LabelStatus: TLabel;
    BtnAccept: TImage;
    BtnRefuse: TImage;
    BtnCancel: TImage;
    TcpClient: TTcpClient;
    TcpServer: TTcpServer;
    procedure FormCreate(Sender: TObject);
    procedure FormActivate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure ImgBGMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure BtnCancelClick(Sender: TObject);
    procedure BtnAcceptClick(Sender: TObject);
    procedure BtnRefuseClick(Sender: TObject);
    procedure BtnCancelMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure BtnAcceptMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure BtnRefuseMouseMove(Sender: TObject; Shift: TShiftState; X,
      Y: Integer);
    procedure BtnCancelMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure BtnAcceptMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure BtnRefuseMouseDown(Sender: TObject; Button: TMouseButton;
      Shift: TShiftState; X, Y: Integer);
    procedure TcpServerAccept(Sender: TObject;
      ClientSocket: TCustomIpClient);
  private
    { Private-Deklarationen }
    Paths: RPaths;         { enthält alle Pfade }
    OppNick: String;       { Nickname des Gegners }
    Language: String;      { Sprache }

    ABoards: TObjectList;  { Referenz auf alle offenen Schachbretter }

    AIFiles: RInvitation;  { Statuswert (Rückgabe) }

    { Images & Index der Buttons }
    BtnCancelImgs: RImgBtn;
    BtnAcceptImgs: RImgBtn;
    BtnRefuseImgs: RImgBtn;

    procedure LoadImages;
    procedure FillImgs(var FImgs: RImgBtn; FTempPath: String);

    procedure SetForm;

    procedure SetButtons;
    procedure SetButton(var FBtn: TImage; var FBtnImgs: RImgBtn);

    procedure CenterLabels;
    procedure SetStatus(FStatus: String);

    procedure Send(FText: String; FPort: Integer);

    function SearchHighestPort(FBoards: TObjectList; FPort: Integer): Integer;

  public
    { Public-Deklarationen }
    function SetFiles(FStatus, FOppNick, FLanguage: String; FPaths: RPaths;
      FOppIP: String; FPort: Integer; FBoards: TObjectList): RInvitation;
  end;

var
  InvitationForm: TInvitationForm;

implementation

uses u_main;

{$R *.dfm}

//----Hauptroutinen-(MainForm)--------------------------------------------------

procedure TInvitationForm.FormCreate(Sender: TObject);
begin
   BorderIcons:=[];
   FirstStart:=True;

   BorderStyle:=bsNone;
   AlphaBlend:=True;
   AlphaBlendValue:=200;
end;

procedure TInvitationForm.FormClose(Sender: TObject;
  var Action: TCloseAction);
begin
   Action:=caFree;
end;
//------------------------------------------------------------------------------

//----Einrichtungs-Routinen-----------------------------------------------------

function TInvitationForm.SetFiles(FStatus, FOppNick, FLanguage: String; FPaths:
  RPaths; FOppIP: String; FPort: Integer; FBoards: TObjectList): RInvitation;
begin
   OppNick:=FOppNick;
   Language:=FLanguage;
   Paths:=FPaths;

   LoadImages;
   SetButtons;
   SetForm;

   ABoards:=FBoards;

   TcpServer.LocalPort:=IntToStr(FPort);
   TcpServer.Active:=True;
   TcpClient.RemotePort:=IntToStr(FPort);
   TcpClient.RemoteHost:=FOppIP;

   SetStatus(FStatus);

   ShowModal;
   result:=AIFiles;
end;
//------------------------------------------------------------------------------

//----on-Klick-Routinen---------------------------------------------------------

procedure TInvitationForm.BtnCancelClick(Sender: TObject);
begin
   Send('Cancel',0);
   AIFiles.Status:='Cancel';
   Close;
end;

procedure TInvitationForm.BtnAcceptClick(Sender: TObject);
var
  AHighPort: Integer;
begin
   AHighPort:=SearchHighestPort(ABoards,5800);
   inc(AHighPort);
   Send('Port',AHighPort);
end;

procedure TInvitationForm.BtnRefuseClick(Sender: TObject);
begin
   Send('Refused',0);
   AIFiles.Status:='Refused';
   Close;
end;
//------------------------------------------------------------------------------

//----Netzwerk-Routinen---------------------------------------------------------

procedure TInvitationForm.Send(FText: String; FPort: Integer);
var
  AInfo: RInvitation;
begin
   AInfo.Status:=FText;
   AInfo.UsePort:=FPort;

   try
    if TcpClient.Connect then
      begin
         TcpClient.SendBuf(AInfo,SizeOf(AInfo));
      end;
   finally
     TcpClient.Disconnect;
   end;
end;

procedure TInvitationForm.TcpServerAccept(Sender: TObject;
  ClientSocket: TCustomIpClient);
var
  AInfo: RInvitation;
  APort: Integer;
begin
   ClientSocket.ReceiveBuf(AInfo,SizeOf(AInfo));

   AIFiles.Status:=AInfo.Status;
   AIFiles.UsePort:=AInfo.UsePort;

   if (AInfo.Status='Port') then
     begin
        APort:=SearchHighestPort(ABoards,AInfo.UsePort);
        inc(APort);
        Send('StartGame',APort);
        AIFiles.Status:='StartGame';
        AIFiles.UsePort:=APort;
     end;

   Close;
   Refresh;
end;
//------------------------------------------------------------------------------

//----Such-Routinen-------------------------------------------------------------
function TInvitationForm.SearchHighestPort(FBoards: TObjectList; FPort:
  Integer): Integer;
var
  i: Integer;
  ActPort: Integer;
  APort: Integer;
begin
   APort:=FPort;

   for i:=0 to FBoards.Count-1 do
     begin
        ActPort:=TBoardForm(FBoards.Items[i]).GlobalFiles.UsedPort;
        if ActPort > APort
          then APort:=ActPort;
     end;

   result:=APort;
end;
//------------------------------------------------------------------------------


end.

Ich hoffe, es ist nicht allzu verwirrend und trägt zur Fehlerfindung (& -behebung) bei.

[Muetze1]

1. String ist nur eine Adresse - entweder du definierst dir String[200] oder ShortString in deinem Record oder du schreibst den String selber in den Socket - dann sind die Packetlängen aber variiabel.
2. Du versuchst im Accept etwas aus dem Socket zu lesen - Accept ist doch aber nur die Rückmeldung, dass der Verbindungsaufbau von der Gegenseite akzeptiert wurde und somit noch kein Hinweis, das schon Daten empfangen wurden und somit auslesbar sind.
3. Du empfängst mit ReceiveBuf() einen Record aber schaust nichtmal nach, ob er komplett empfangen wurde (Rückgabewert von ReceiveBuf()). Es kann sehr gut sein, dass
a) gar keine Daten bisher empfangen wurden.
b) nicht genügend Daten empfangen wurden (also weniger als SizeOf(DeinRecord))

[Bloodfire]

Danke für die Beiträge!

1. (String) is mir jetzt klar und hab ich schon geändert.
2. (Accept) Wo soll ich sonst auslesen?
3. (RecieveBuf) Wie überprüfe ich auf Vollständigkeit?

[Muetze1]

zu 3.) der TCustomIpClient hat als Eigenschaft BytesReceived, somit kannst du vorher nachschauen ob BytesReceived >= SizeOf(DeinRecord) ist, weil nur dann kannst du ihn komplett auslesen.

zu 2.) Auf OnReceive? Laut Hilfe gibt es ein solches Ereignis und somit würde ich dieses nutzen.