[RTTI] an Klassennamen der TCollectionItems herankommen

[_frank_]

ich brauche den Klassennamen der Items einer von TCollection abgeleiteten Klasse
die untenstehende Funktion funktioniert soweit, dass ich den Namen der TCollection-Klasse habe (TStatusPanels), und mir ein Object dessen erzeugt, leider ist dessen property ItemClass=nil somit kome ich nicht an den namen ran...

Jemand eine Idee?

Beispiel für untenstehende Funktion:
classname ist z.B. TStatusbar
propname ist Panels

Delphi-Quellcode:

function getCollectionClass(classname,propname:string):string;
var ti:pTypeinfo;
    td:pTypeData;
    pi:pPropInfo;
    classe:TClass;
    col:TCollection;
begin
  ti:=FindTypeInfo(classname); //funktion von Hagen ähnlich Typeinfo() nur mit strings
  pi:=GetPropInfo(ti,propname);
  if pi.PropType^.kind=tkClass then
  begin
    ti:=FindTypeInfo(pi.PropType^.Name);
    td:=GetTypeData(ti);
    classe:=td.ClassType;
    if assigned(classe) and (classe.InheritsFrom(TCollection)) then
    begin
      //showmessage(pi.PropType^.Name); //TStatusPanels wird angezeigt
      //hier muss ich irgendwie and den Namen der CollectionItems (TStatusPanel) herankommen
      col:=TCollection(classe.create);
      showmessage(col.ItemClass.ClassName);
      col.Free;
    end;
  end;
end;

Gruß Frank

[Hawkeye219]

Hallo Frank,

der folgende Code könnte funktionieren:

Delphi-Quellcode:

function getCollectionClass(classname,propname:string):string;
var ti:pTypeinfo;
    td:pTypeData;
    Comp:TComponent;
    Coll:TCollection;
begin
  ti:=FindTypeInfo(classname);
  td:=GetTypeData(ti);
  Comp:=TComponentClass(TD.ClassType).Create(nil);
  Coll:=TCollection(GetOrdProp(Comp, propname));
  Result:=Coll.ItemClass.ClassName;
  Comp.Free;
end;

Im Unterschied zu deinem Code wird hier das Control selbst (z.B. TStatusBar) temporär erzeugt. Ich habe leider keine andere Möglichkeit gefunden, die abzufragende Eigenschaft (Panels.ItemClass) zu initialisieren. Für den produktiven Einsatz solltest du natürlich noch die üblichen Sicherheitsabfragen einbauen.

Gruß Hawkeye

[_frank_]

Hi,
hätte ich auch selber drauf kommen können, danke.
Musste nur noch eine Änderung machen...

Delphi-Quellcode:

var ...
    pi:pPropInfo;
begin
...
  pi:=GetPropInfo(ti,propname);
  Coll:=TCollection(GetOrdProp(Comp, pi));
...
end;

warum itemclass nil ist ist mir jett auch klar...(es wird der consturctor von TObject aufgerufen, nicht von der klasse selbst)
die prüfungen mache ich auch noch rein...(assigned,try/except/finally)

Gruß Frank