Button.Down auch für normale TButtons?

[Schaedel]

Hallo!

Ich hab in der Schule(lang ist es her) mal einen Button so erzogen das er nach dem Klick unten geblieben ist.(Quasi Button.down).
Ich würde einen Speedbutton nehmen aber ich benötige Tabstops und den hat der Speedbutton nicht.

Jemand eine Idee?
Ich benutze Delphi5 Enterprise

Die Suche hab ich bereits bemüht aber nicht wirklich was gefunden.

Danke !

[uligerhardt]

Du kannst eine Checkbox nehmen und sie wie einen normalen Button aussehen lassen.

• Quick and dirty:
  Delphi-Quellcode:

  procedure TForm2.FormCreate(Sender: TObject);
  var
    style: DWORD;
  begin
    style := GetWindowLong(CheckBox2.Handle, GWL_STYLE);
    SetWindowLong(CheckBox2.Handle, GWL_STYLE, style or BS_PUSHLIKE);
  end;

• Etwas sauberer: Leite eine Komponente von TCheckbox ab und jubele ihr das BS_PUSHLIKE im CreateParams unter.

HTH, Uli.

[Bernhard Geyer]

Oder such dir eine Komponentensammlung die entsprechende Button-Komponenten bereitstellt (wie z.B. das ElPack)

[Tyrael Y.]

Moin,

da hast du eine "Komponente"
...ich habe die mal vor paar Monaten eher spasseshalber gemacht
...ist von TPanel abgeleitet

Delphi-Quellcode:

unit CustomPanelButton;

interface

uses
  SysUtils, Classes, Controls, ExtCtrls, Messages, ActnList;

type TButtonType =(btNone, btButton, btRadio);

type
  TCustomPanelButton = class(TPanel)
  private
    { Private declarations }
    FClicked: Boolean;
    FButtonType: TButtonType;

    procedure SetClicked(const Value: Boolean);
    procedure SetButtonType(const Value: TButtonType);
  protected
    { Protected declarations }
    procedure Click(); override;
    procedure MouseUp(Button: TMouseButton; Shift: TShiftState;
      X, Y: Integer); override;
    procedure MouseDown(Button: TMouseButton; Shift: TShiftState;
      X, Y: Integer); override;
  public
    { Public declarations }
    constructor Create(AOwner: TComponent); override;
    destructor Destroy(); override;
  published
    { Published declarations }
    property Clicked: Boolean read FClicked write SetClicked;
    property ButtonType: TButtonType read FButtonType write SetButtonType;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Standard', [TCustomPanelButton]);
end;

{ TCustomPanelButton }

constructor TCustomPanelButton.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FButtonType := btNone;
  FClicked := False;

  self.Width := 75;
  self.Height := 25;
  self.Caption := 'Button';
end;

destructor TCustomPanelButton.Destroy;
begin
  inherited;
end;

procedure TCustomPanelButton.Click;
begin
  if FButtonType = btRadio then
  begin
    FClicked := BevelOuter = bvLowered;
    if FClicked then
      BevelOuter := bvRaised
    else
      BevelOuter := bvLowered;
  end;
end;

procedure TCustomPanelButton.MouseDown(Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  inherited;
  if FButtonType = btButton then
    BevelOuter := bvLowered;
end;

procedure TCustomPanelButton.MouseUp(Button: TMouseButton;
  Shift: TShiftState; X, Y: Integer);
begin
  inherited;
  if FButtonType = btButton then
    BevelOuter := bvRaised;
end;

procedure TCustomPanelButton.SetButtonType(const Value: TButtonType);
begin
  FButtonType := Value;
  if FButtonType = btButton then
    BevelOuter := bvRaised;
end;

procedure TCustomPanelButton.SetClicked(const Value: Boolean);
begin
  FClicked := Value;
  if FClicked and (FButtonType = btRadio) then
    BevelOuter := bvLowered
  else
    BevelOuter := bvRaised;
end;



end.

[Schaedel]

Erstmal danke für die Antworten...
aber das ist alles mehr oder weniger von hinten durch die Brust ins Auge

Ich versuchs mal mit den Handeln anders hinzubekommen ...

[Luckie]

Nein, ist es nicht. Unter Windows sind Schaltflächen, Checkboxen und Optionsfelder alles Schaltflächen - nur mit unterschiedlichen Stilen.

[sakura]

Zitat von Schaedel:

Erstmal danke für die Antworten...
aber das ist alles mehr oder weniger von hinten durch die Brust ins Auge

Nun ja, für die Checkbox ist es eine Standardfunktionalität der WinAPI, welche lediglich nie von der VCL direkt angeboten wurde.

......

[Schaedel]

ok ok .. Schande über mein Haupt

Und nochmals Danke