Items.Text übergabe

[newuser01]

Hallo

Ich habe folgendes Problem Wenn ich einer ListBox die Einträge einer StringList über "items.text" übergeben will klappt das nicht so recht

Delphi-Quellcode:

//so funktioniert die übergabe 
for i := 0 to slTemp.Count -1 do
begin
lbAusgabe.Items.Add(slTemp.Strings[i]);
end;

Delphi-Quellcode:

// und so leider nicht es wird in lbAusgabe nichts angezeigt warum auch immer 
lbAusgabe.Items.Text := slTemp.Text;

vielleicht hilft euch das noch weiter "lbAusgabe ist eine (JVCL Komponente TJvListBox)"

[mkinzler]

Versuch mal :
lbAusgabe.Items.DelimitedText := slTemp.DelimitedText;

[newuser01]

funktioniert leider auch nicht

[inherited]

Warum willst du es auch mit dem Text machen?

Eine andere Alternative wäre noch

Delphi-Quellcode:

lbAusgabe.Items.Clear;
lbAusgabe.Items.AddStrings(slTemp);

[newuser01]

Zitat:

Warum willst du es auch mit dem Text machen?

Wenn sehr viele Einträge vorhanden sind denk ich das es mit items.text schneller geht

Delphi-Quellcode:

//funktioniert
lbAusgabe.Items.AddStrings(slTemp); //auch besser wie schleife ?

aber warum items.text nicht

[inherited]

Delphi-Quellcode:

procedure TStrings.AddStrings(Strings: TStrings);
var
  I: Integer;
begin
  BeginUpdate;
  try
    for I := 0 to Strings.Count - 1 do
      AddObject(Strings[I], Strings.Objects[I]);
  finally
    EndUpdate;
  end;
end;

Kurz: Nein, auch mit schleife. Wobei ich nicht denke, dass das mit schleife sehr viel langsamer ist

[marabu]

Guten Morgen,

so geht es:

Delphi-Quellcode:

 
// Inhalt von ListBox ersetzen
lbAusgabe.Items.Assign(slTemp); 

// Inhalt von ListBox ergänzen
lbAusgabe.Items.AddStrings(slTemp);

Die Zuweisung über die property Text ist ungünstig, da beim Lesen von Text erst der String aus den einzelnen Items zusammengebaut werden muss, beim Schreiben von Text umgekehrt.

Grüße vom marabu

[inherited]

Delphi-Quellcode:

procedure TStrings.Assign(Source: TPersistent);
begin
  if Source is TStrings then
  begin
    BeginUpdate;
    try
      Clear;
      FDefined := TStrings(Source).FDefined;
      FNameValueSeparator := TStrings(Source).FNameValueSeparator;
      FQuoteChar := TStrings(Source).FQuoteChar;
      FDelimiter := TStrings(Source).FDelimiter;
      AddStrings(TStrings(Source));
    finally
      EndUpdate;
    end;
    Exit;
  end;
  inherited Assign(Source);
end;

ergo->auch Assign arbeitet mit Schleife. Kommt also mehr oder weniger aufs gleiche hinaus

[newuser01]

OK Danke für eure Hilfe !