COM Collections durchsuchen

[sakura]

Hi,

ich habe das Gleiche jetzt mal mit dem MS XML DOM von Microsoft gemacht. alle Infos solltest Du im durchkommentierten Code finden, wenn noch Fragen offen sind, dann weißt Du ja, wie die Delphi-PRAXiS funktioniert

Delphi-Quellcode:

// Dein Problem habe ich hier mal mit Hilfe des MS XML DOM 4.0 nachgestellt.
procedure TForm1.Button1Click(Sender: TObject);
var
  // MSXML typische Interfaces

  // Das Basis Dokument
  Doc: IXMLDOMDocument2;
  // Die COM Collection
  Nodes: IXMLDOMNodeList;
  // Das COM Collection Objekt
  Node: IXMLDOMNode;

  // das Interface zum Collection-Container
  Enum: IEnumVariant;
  // Anzahl der zurückgelieferten Elemente
  Fetched: Cardinal;
  // Der Empfänger des Collection-Objektes
  ResultItem: OleVariant;
begin
  // okay, einfach mal den XML DOM initialisieren
  Doc := CoDOMDocument40.Create;
  // XML file laden
  Doc.load('C:\Temp\hallo.xml');

  // und eine Liste von aller (x) Nodes erzeugen
  Nodes := Doc.selectNodes('.//*');
  // die Collection zurückgeben lassen
  Enum := Nodes._newEnum as IEnumVariant;

  // die Collection reseten (ist theoretisch beim ersten Durchlauf nicht nötig
  // sollte imho aber gemacht werden
  Enum.Reset;
  // das erste Element ermitteln
  //   der erste Parameter gibt an, wie viele Objekte zurückgeliefert werden
  //     sollen
  //   der zweite Parameter nimmt das Zielobjekt auf
  //     für diesen kann auch ein SafeArray von OleVariants übergeben werden
  //   der dritte Parameter gibt an, wieviele Objekte zurückgeliefert wurden
  //
  // die Übergabe von "1" für den ersten Parameter entspricht dem VB Konstrukt
  //   for each Item in Collection
  Enum.Next(1, ResultItem, Fetched);
  // Fetched muß also "1" sein, solange ein Element gefunden wird
  while Fetched = 1 do
  begin
    // jetzt auf das gewünschte Interface casten - dazu als erstes das IDispatch
    //   Interface ermitteln und dann das Ziel-Interface
    Node := IDispatch(ResultItem) as IXMLDOMNode;

    // und nun wie gewohnt arbeiten...
    ListBox1.Items.Add(Node.nodeName);

    // das nächste Element ermitteln und weiter im Job...
    Enum.Next(1, ResultItem, Fetched);
  end;
  // jetzt noch die Collection freigeben - oder einfach weglassen, dann tut
  //   Delphi dieses spätestens beim Verlassen der Prozedur
  Enum := nil;
end;

......