AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Clear von TList überschreiben mit Objekten

Ein Thema von Luckie · begonnen am 3. Jul 2007 · letzter Beitrag vom 4. Jul 2007
Antwort Antwort
Seite 1 von 4  1 23     Letzte » 
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#1

Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 10:18
Ich habe eine Klasse von TObject abgeleitet mit einer inneren Liste vom Typ TList. Diese fülle ich mit Objekten. Hin und wieder muss ich eine Kopie dieser Liste anfertigen. Dazu hab eich mir eine Methode Assign geschrieben:
Delphi-Quellcode:
procedure TPageCollection.Assign(Source: TPageCollection);
var
  i : Integer;
  j : Integer;
  hobj : Integer;
  hObjSource : Integer;
  Page : TImageEnVect;
begin
  // Klassenattribute kopieren
  PageParent := Source.PageParent;
  ScaleFactor := Source.ScaleFactor;
  for i := 0 to Source.Count - 1 do
  begin
    Page := TImageEnVect.Create(nil);
    // Seiteneigenschaften kopieren
    Page.Name := Source.Items[i].Name;
    Page.Parent := PageParent; //Source.Items[i].Parent;
    Page.Visible := False;
    Page.AllowOutOfBitmapMoving := False;
    Page.BorderStyle := bsNone;
    Page.ScrollBars := ssNone;
    Page.Cursor := crArrow;
    Page.DragMode := dmManual;
    Page.Width := Source.Items[i].Width;
    Page.Height := Source.Items[i].Height;
    Page.OnDragOver := Source.Items[i].OnDragOver;
    Page.OnDragDrop := Source.Items[i].OnDragDrop;
    Page.OnMouseDown := Source.Items[i].OnMouseDown;
    Page.OnObjectDblClick := Source.Items[i].OnObjectDblClick;
    Page.OnLayerNotify := Source.Items[i].OnLayerNotify;
    // Seiten-Layer kopieren. Bitmap nicht mit kopieren.
    for j := 1 to Source.Items[i].LayersCount - 1 do
    begin
      hobj := Page.LayersAdd;
      Page.Layers[hobj].Assign(Source.Items[i].Layers[j]);
    end;
    // Textobjekte
    for j := 0 to Source.Items[i].ObjectsCount - 1 do
    begin
      hobj := Page.AddNewObject;
      hObjSource := Source.Items[i].GetObjFromIndex(j);
      Page.ObjUserData[hObjSource] := Source.Items[i].ObjUserData[hObjSource];
      Page.ObjKind[hobj] := Source.Items[i].ObjKind[hObjSource];
      Page.ObjLeft[hobj] := Source.Items[i].ObjLeft[hObjSource];
      Page.ObjTop[hobj] := Source.Items[i].ObjTop[hObjSource];
      Page.ObjWidth[hobj] := Source.Items[i].ObjWidth[hObjSource];
      Page.ObjHeight[hobj] := Source.Items[i].ObjHeight[hObjSource];
      Page.ObjTextAlign[hobj] := Source.Items[i].ObjTextAlign[hObjSource];
      Page.ObjFontName[hobj] := Source.Items[i].ObjFontName[hObjSource];
      Page.ObjFontHeight[hobj] := Source.Items[i].ObjFontHeight[hObjSource];
      Page.ObjPenColor[hobj] := Source.Items[i].ObjPenColor[hObjSource];
      Page.ObjFontStyles[hobj] := Source.Items[i].ObjFontStyles[hObjSource];
      Page.ObjText[hobj] := Source.Items[i].ObjText[hObjSource];
      Page.Update;
    end;
    Add(Page);
  end;
end;
Die Instanz für die Kopie ist global (in der Klasse), damit ich aber jetzt keine Speicherlecks bekomme rufe ich die Methode Clear auf bevor ich Klasse mit der LÖiste kopiere:
Delphi-Quellcode:
procedure TPageCollection.Clear;
var
  i: Integer;
begin
  for i := FInnerList.Count - 1 downto 0 do
  begin
    TObject(FInnerList.Items[i]).Free;
  end;
// inherited;
  //FInnerList.Clear;
end;
Das sieht dann so aus:
Delphi-Quellcode:
  TempPageCollection.Clear;
  TempPageCollection.Assign(PageCollection);
Nur leider bekomme ich eine AccessViolation in der Assign-Methode, wenn ich vorher meine Clear-Methode aufrufe.

Was mache ich da falsch? Oder wie kann man sonst Speicherlecks vermeiden?
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Ghostwalker

Registriert seit: 16. Jun 2003
Ort: Schönwald
1.299 Beiträge
 
Delphi 10.3 Rio
 
#2

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 10:46
Wie ist den die Items-Eigenschaft von TPageCollection definiert ?
Uwe
e=mc² or energy = milk * coffee²
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#3

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 10:49
Delphi-Quellcode:
function TPageCollection.GetItem(Index: Integer): TImageEnVect;
begin
  Result := FInnerList.Items[Index];
end;

procedure TPageCollection.SetItem(Index: Integer; Item: TImageEnVect);
begin
  FInnerList.Items[Index] := Item;
end;
Und dann die Property dazu:
property Items[Index: Integer]: TImageEnVect read GetItem write SetItem;
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Ghostwalker

Registriert seit: 16. Jun 2003
Ort: Schönwald
1.299 Beiträge
 
Delphi 10.3 Rio
 
#4

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 10:55
hm....also das einzige was mir jetzt auffählt wäre im Clear.

Müsste das nicht

  TImageEnVect(FInnerList.Items[i]).Free; statt
  TObject(FInnerList.Items[i]).Free; Ansonsten mal mit dem Debuger rein, und guggen wo er genau im Assign semmelt.
Uwe
e=mc² or energy = milk * coffee²
  Mit Zitat antworten Zitat
kalmi01
(Gast)

n/a Beiträge
 
#5

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 10:58
ist FInnerList denn immer initialisiert ?
sonst greift Count ins Leere.
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie

Registriert seit: 29. Mai 2002
37.621 Beiträge
 
Delphi 2006 Professional
 
#6

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 11:03
Die innere Liste wird im Konstruktor erzeugt und im Destruktor wieder freigegeben. Und die TempPageCollection existiert auch. Durch die Schleife in der Clear-Methode läuft er ja auch durch, nur in der darauffolgenden Assign-Methode kracht es dann und zwar wenn der betreffende Code zum zweiten mal aufgerufen wird. Aber ich kopiere ja, also dürfte die Clear-Methode ja nichts aus der original Liste löschen oder so.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
CCRDude
(Gast)

n/a Beiträge
 
#7

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 11:08
Ohne jetzt einen konkreten Fehler zu sehen, zwei etwas allgemeinere Tips:

* FreeAndNil statt Free verwenden; dadurch sieht man beim Debuggen wenigstens sofort, daß das Objekt vorher mal freigegeben wurde, statt einen Zeiger ins Irgendwo zu haben.
* In Assign nochmal expliziter mit Self. arbeiten, für den Fall das sich da irgendwo Namen und Sichtbarkeiten überschneiden.
  Mit Zitat antworten Zitat
Ghostwalker

Registriert seit: 16. Jun 2003
Ort: Schönwald
1.299 Beiträge
 
Delphi 10.3 Rio
 
#8

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 11:09
Öhm...du solltest vielleicht auch den entsprechenden Listeneintrag beim Clear löschen, nicht nur das Objekt freigeben

Ansonsten..wie ich oben geschrieben hab.
Uwe
e=mc² or energy = milk * coffee²
  Mit Zitat antworten Zitat
hoika

Registriert seit: 5. Jul 2006
Ort: Magdeburg
8.269 Beiträge
 
Delphi 10.4 Sydney
 
#9

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 11:11
Hallo,

soll Clear die Liste leeren oder nur die Objekte freigeben,
in ersterem Fall fehlt was

Delphi-Quellcode:
procedure TPageCollection.Clear;
var
  i: Integer;
begin
  for i := FInnerList.Count - 1 downto 0 do
  begin
    TObject(FInnerList.Items[i]).Free;

// das fehlt
    FInnerList.Delete(i);

// oder ungetestet
// FInnerLIst.Remove(FInnerList.Items[i])

  end;
end;
Durch Free des Objektes wird zwar as Objekt freigegeben,
aber nicht der Listeneintrag (Pointer),
Count bliebt also immer gleich, nur der Pointer zeugt ins Nirvana.

Ich würde per {$IFDEF DEBUG} eh immer FreeAndNIL benutzen,
dann bekommt du wenigstens (hoffentlich) ne bessere Fehlermeldung.


Heiko
PS: Schon mal TObjectlist versucht ?
Heiko
  Mit Zitat antworten Zitat
Phantom1

Registriert seit: 20. Jun 2003
282 Beiträge
 
Delphi 10.4 Sydney
 
#10

Re: Clear von TList überschreiben mit Objekten

  Alt 3. Jul 2007, 11:22
@hoika: ein FInnerList.Clear reicht auch aus um alle Listeneinträge der TList zu entfernen, das hat Luckie auch gemacht (allerdings ist der code bei ihm auskommentiert).

Delphi-Quellcode:
procedure TPageCollection.Clear;
var
  i: Integer;
begin
  for i := FInnerList.Count - 1 downto 0 do
  begin
    TObject(FInnerList.Items[i]).Free;
  end;
  FInnerList.Clear;
end;
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 19:11 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz