Wörter in Zeichenstring fett schreiben

[t0mmy]

Hallo:

Ich hab folgendes Problem... und zwar möchte ich in einer Zeichenkette gewisse Wörter fettschreiben.... und diesen String dann als ganzes in ein RichEdit - Element reinschreiben.

Beispiel:

meinstring:
Höhe: 70cm, Breite: 106cm, Tiefe: 40cm

Ausgabe in RichEdit:
Höhe:70cm, Breite:106cm, Tiefe: 40cm

Ich habs jetzt schon eine zeitlang probiert... aber ohne Erfolg :(

[DeddyH]

Schau Dir mal das Delphi-Beispiel zu TCustomRichEdit.FindText an, da hast Du schon die halbe Miete und musst quasi nur noch die SelAttributes setzen.

[t0mmy]

Danke für die Seite.. jedoch habe ich hier was gefunden http://www.delphipraxis.net/65927-ri...-findtext.html, aber ich verstehe die ganzen funktionalitäten von: SelStart, SelLength, SelText

SelAttributes is mir noch klar... aber ich weiss nicht ob ich mit dem obigen code was anfangen soll -.-


bzw... wenn ich den TCustomRichEdit.FindText code hernehmen würde, dann müsste ich doch bei

Delphi-Quellcode:

FindDialog1.Position := 
    Point(RichEdit1.Left + RichEdit1.Width, RichEdit1.Top);
  FindDialog1.Execute;

anstatt RichtEdit1.Left + RichEdit1.Widht, RichEdit1.Top eintragen odeR?

mfg

[DeddyH]

Der Code des Buttons ist doch für Dich vollkommen irrelevant, es geht schließlich um das Suchen eines Textes und anschließendes Markieren (für das Setzen der SelAttributes) in einem RichEdit. Und dafür genügt der Code in FindDialog1Find, der muss nur noch marginal angepasst/erweitert werden.

[Bjoerk]

Jo, is ne Sch..arbeit. Hat mich auch mal ein paar Tage gekostet.

Delphi-Quellcode:

procedure DoColorWork (ARichEdit: TRichEdit; const ARow: integer; const S: string; const fAlle: boolean);
var
  I, X, L, X1, X2: integer;
  F: boolean;
begin
  X1:= 0;
  X2:= 0;
  for I := 0 to ARichEdit.Lines.Count - 1 do
  begin
    if I < ARow then
      X1:= X1+Length(ARichEdit.Lines[I])+2;
    if I <= ARow then
      X2:= X2+Length(ARichEdit.Lines[I])+2;
    if I = ARow then
      break;
  end;
  ARichEdit.Lines.BeginUpDate;
  L:= Length(S);
  X:= X1+1;
  F:= true;
  while F do
  begin
    X:= PosEx(S, ARichEdit.Text, X);
    if ((X <> 0) and (X <= X2)) then
    begin
      with ARichEdit do
      begin
        SelStart:= X-1;
        SelLength:= L;
        SelAttributes.Color:= clNavy;
        SelAttributes.Style:= [fsBold];
        SelAttributes.Name:= Font.Name;
        SelAttributes.Size:= Font.Size;
      end;
      Inc(X, L);
      F:= fAlle;
    end
    else
      F:= false;
  end;
  ARichEdit.SelLength:= 0;
  ARichEdit.Lines.EndUpDate;
end;

Delphi-Quellcode:

  DoColorWork (RichEdit1, 27, 'Höhe:', false);  // Zeilen beginnen mit Null

[DeddyH]

Sry, aber ich verstehe Deinen Code nicht, zumal der mir recht umständlich aussieht. Alleine schon, was die Zeilennummer damit zu tun hat/haben soll, erschließt sich mir nicht :gruebel:. Was passiert denn bei automatischen Zeilenumbruch? Muss ich dann selbst ermitteln, wo ich anfangen will?

[Bjoerk]

Ich habe TE so verstanden, daß er in einer bestimmten Zeile etwas ändern will, nicht im ganzen Text. Dafür ist die Zeilennummer o.ä. erforderlich. Hast Du eine bessere Idee? Dann poste sie. Der Code setzt RichEdit.WordWrap:= false voraus, da hast du recht.

[DeddyH]

Zitat:

Zitat von t0mmy (Beitrag 1111543)

Hallo:

Ich hab folgendes Problem... und zwar möchte ich in einer Zeichenkette gewisse Wörter fettschreiben.... und diesen String dann als ganzes in ein RichEdit - Element reinschreiben.

Beispiel:

meinstring:
Höhe: 70cm, Breite: 106cm, Tiefe: 40cm

Ausgabe in RichEdit:
Höhe:70cm, Breite:106cm, Tiefe: 40cm

Ich habs jetzt schon eine zeitlang probiert... aber ohne Erfolg :(

Ich habe ausnahmsweise mal einen FullQuote gemacht, damit Du mir die Stelle mit der Zeile zeigen kannst.

[t0mmy]

Hallo!

Danke DeddyH... jedoch kapier ich die prozedur FindDialog1Find nicht so ganz -.-
Die Prozedur von Bjoerk (DoColorWork) ist mir um einiges verständlicher... jedoch weiss ich nicht warum er PosEx nimmt...??? wenn der Compiler schreit Undeklarierter bezeichner -.-

Jedoch möcht ich nicht nur ein Wort das in einer Zeile vorkommt ändern, sonder dieses Wort kommt öfters im Text vor, da is mir die FindText methode sympathischer, wenn ich sie verstehen würde.

[DeddyH]

Was verstehst Du denn nicht? Der Code ist doch sogar kommentiert.

[t0mmy]

Okay.. mittlerweile.. check ichs ein bisschen... jedoch schreit der compiler beim kompilieren:

2mal Inkompatible Typen: 'TSearchType' und 'TRichSearchType'
&1mal: Inkompatible Typen: 'TRichSearchTypes' und 'TSearchTypes'

Ich muss mich ausbessern ich verwende kein TRichEdit Steuerelement sondern ein TJvRichEdit.. da es möglich is in diesem Bilder einzufügen.
Aber ich glaube das macht kein unterschied beim TFindDialog - Element

[t0mmy]

Warum kann mir keiner Helfen??? -.-

[DeddyH]

Nun schrei hier mal nicht rum. Zum Einen brauchst Du ja keinen FindDialog, zum Anderen musst Du halt mal schauen, wie die Typen beim JvRichEdit deklariert sind und das dann entsprechend umdeklarieren.

[Bjoerk]

uses
StrUtils;

[Bjoerk]

Alle Wörter im Text?
Dann wird's noch einfacher. Dann lauft x ab 1. ggf. TRichEdit in der Übergabe ändern.

DeddyH, was daran jetzt kompliziert? :shock:

Delphi-Quellcode:

procedure DoColorWork (ARichEdit: TRichEdit; const S: string);
var
  I, X, L: integer;
  F: boolean;
begin
  ARichEdit.Lines.BeginUpDate;
  L:= Length(S);
  X:= 1;
  F:= true;
  while F do
  begin
    X:= PosEx(S, ARichEdit.Text, X);
    if X <> 0 then
    begin
      with ARichEdit do
      begin
        SelStart:= X-1;
        SelLength:= L;
        SelAttributes.Color:= clNavy;
        SelAttributes.Style:= [fsBold];
        SelAttributes.Name:= Font.Name;
        SelAttributes.Size:= Font.Size;
      end;
      Inc(X, L);
    end
    else
      F:= false;
  end;
  ARichEdit.SelLength:= 0;
  ARichEdit.Lines.EndUpDate;
end;

[t0mmy]

Hallo Bjoerk!

Beim kompilieren von:

Delphi-Quellcode:

 DoColorWork (RichEdit1, 'Höhe:');

Hab den Fehler gefunden RichEdit1 --> JvRichEdit1 -.-

[t0mmy]

Das Programm lässt sich ausführen, jedoch schreibt er was anderes fett -.-


Mit

Delphi-Quellcode:

zeichenkette1 := StringReplace(zeichenkette1, 'Höhe:', 'HÖHE:', [rfIgnoreCase]);

kann ich die Höhe: --> groß schreiben.. wie geht das mit fett schreiben???

[DeddyH]

Hat sich eigentlich einer von Euch beiden mal FindText angeschaut, speziell die Optionen, die da geboten werden? Falls ja, wieso friemelt Ihr dann mit PosEx herum? Ich kann mein Auto auch schieben, dann bewegt es sich auch, nur ist das zum Einen im Allgemeinen langsamer als wenn ich fahren würde, zum Anderen ist das Fahren doch unbestreitbar bequemer. Aber es ist ja nicht mein Programm. Übrigens:

Zitat:

Use FindText rather than programmatically searching through the text of the control, to keep from being thrown off by the encoding of rich text characteristics.

[edit] Fett schreiben: gefunden Text markieren (SelStart, SelLength) und SelAttributes setzen.

Delphi-Quellcode:

DeinRichEdit.SelAttributes.Style := DeinRichEdit.SelAttributes.Style + [fsBold];

[/edit]

[t0mmy]

Ich schau mir diesen Befehle (FindText) eine Zeit lang an.. aber ich hab mittlerweile überhaupst keine Ahnung wie ich ihm angeben soll das wenn er Höhe im TJvRichEdit findet es fettt schreiben soll.. jaa okay...

Delphi-Quellcode:

JvRichEdit1.FindText('Höhe:', 1, ???????

Weiss nicht mal was ich da eintragen soll

und dass was ich noch weiss ist das mit JvRichEdit1.SelAttributes.Style := [fsBold]

sonnst hab ich keine Ahnung und ich weiss nicht mehr was ich tun soll.. probier nur die ganze Zeit herrum -.-

[DeddyH]

Probieren ist schlecht, kapieren wäre besser. Wirf doch einfach mal einen Blick in die Hilfe, da werden sowohl FindText als auch TSerachTypes doch recht genau beschrieben. Bei dem Jedi-Dingen wird es doch recht ähnlich sein, auch wenn da wohl eigene Typen verwendet werden.

[Bjoerk]

Zitat:

Zitat von t0mmy (Beitrag 1111698)

Das Programm lässt sich ausführen, jedoch schreibt er was anderes fett -.-
kann ich die Höhe: --> groß schreiben.. wie geht das mit fett schreiben???

Oh mann, weil der Text HÖHE nicht enthält (PosEx ist CaseSensitive).

Eventuell so:

Delphi-Quellcode:

  RE: string;
begin
  RE:= AnsiLowercase(ARichEdit.Text);

  ..
  
  X:= PosEx(AnsiLowercase(S), RE, X);

[t0mmy]

@Bojerk

Es wird immer das Falsche fett markiert -.-

[Bjoerk]

Nochmal zum mitschreiben:

Delphi-Quellcode:

procedure DoColorWork (ARichEdit: TWasAuchImmerFuerEinRichEdit; const S: string);
var
  I, X, L: integer;
  F: boolean;
  RE: string;
begin
  RE:= AnsiLowerCase(ARichEdit.Tex); // !!
  ARichEdit.Lines.BeginUpDate;
  L:= Length(S);
  X:= 1;
  F:= true;
  while F do
  begin
    X:= PosEx(AnsiLowerCase(S), RE, X); / !!
    if X <> 0 then
    begin
      with ARichEdit do // !!
      begin
        SelStart:= X-1;
        SelLength:= L;
        SelAttributes.Color:= clNavy;
        SelAttributes.Style:= [fsBold];
        SelAttributes.Name:= Font.Name;
        SelAttributes.Size:= Font.Size;
      end;
      Inc(X, L);
    end
    else
      F:= false;
  end;
  ARichEdit.SelLength:= 0;
  ARichEdit.Lines.EndUpDate;
end;

// Aufruf:

DoColorWork (WasAuchImmerFuerEinRichEdit, 'HÖHE:');

[Bjoerk]

Alternative:

Delphi-Quellcode:

procedure DoColorWork (ARichEdit: TWasAuchImmerFuerEinRichEdit; const S: string);
var
  I, X, L: integer;
  F: boolean;
begin
  ARichEdit.Text:= StringReplace(AnsiLowerCase(ARichEdit.Text), AnsiLowerCase(S), S, [rfReplaceAll]);
  ARichEdit.Lines.BeginUpDate;
  L:= Length(S);
  X:= 1;
  F:= true;
  while F do
  begin
    X:= PosEx(S, ARichEdit.Text, X);
    if X <> 0 then
    begin
      with ARichEdit do
      begin
        SelStart:= X-1;
        SelLength:= L;
        SelAttributes.Color:= clNavy;
        SelAttributes.Style:= [fsBold];
        SelAttributes.Name:= Font.Name;
        SelAttributes.Size:= Font.Size;
      end;
      Inc(X, L);
    end
    else
      F:= false;
  end;
  ARichEdit.SelLength:= 0;
  ARichEdit.Lines.EndUpDate;
end;

// Aufruf:

DoColorWork (WasAuchImmerFuerEinRichEdit, 'HÖHE:');

[DeddyH]

Siehe Anhang.

[t0mmy]

Ich glaub man versteht mich hier nicht.. ja der Code funktioniert Bjoerk, jedoch wenn ich einen Text hab und dazwischen Bilder.. dann findet er nichts -.-
DeddyH's Methode ist da einsichtiger... jedoch hab ich noch immer keinen Plan wie ich FindText anwenden soll :( Ja die Funktion kenn ich und auch die Parameter aber bei meinem Problem check ichs nicht.

[DeddyH]

Versuch mal, ob es hiermit geht:

Delphi-Quellcode:

procedure {TfrmDemo.}MarkKeyword(RE: TRichEdit; const s: string;
  CaseSensitive: Boolean);
var
  FoundAt: LongInt;
  StartPos, ToEnd: Integer;
  SearchTypes: TSearchTypes;
begin
  Assert(Assigned(RE));
  if CaseSensitive then
    SearchTypes := [stMatchCase]
  else
    SearchTypes := [];
  StartPos := 0;
  ToEnd := Length(RE.Text);
  FoundAt := RE.FindText(s, StartPos, ToEnd, SearchTypes);
  while FoundAt > -1 do
    begin
      RE.SelStart := FoundAt;
      RE.SelLength := Length(s);
      RE.SelAttributes.Style := RE.SelAttributes.Style + [fsBold];
      RE.SelLength := 0;
      StartPos := FoundAt + Length(s);
      ToEnd := Length(RE.Text) - StartPos;
      FoundAt := RE.FindText(s, StartPos, ToEnd, SearchTypes);
    end;
end;

Aufruf (Button1):

Delphi-Quellcode:

procedure TfrmDemo.Button1Click(Sender: TObject);
begin
  RichEdit1.Lines.BeginUpdate;
  try
    MarkKeyword(RichEdit1, 'Höhe:', CheckBox1.Checked);
    MarkKeyword(RichEdit1, 'Breite:', CheckBox1.Checked);
    MarkKeyword(RichEdit1, 'Tiefe:', CheckBox1.Checked);
  finally
    RichEdit1.Lines.EndUpdate;
  end;
end;

Ggf. musst Du eben die Typen noch anpassen, ich habe die JVCL nicht installiert und kann daher nicht nachsehen, wie das da heißen muss.

[t0mmy]

@DeddyH

Ich habs jetzt auf TJvRichEdit abgeändert.. und bin den Code auf nem Blatt papier durchgegangen... jetzt verstehe ich... was die ganzen Funktionen auf sich haben....
Es funktioniert :))

Danke DeddyH... ich wär viel Glücklicher wenn ichs selber Rausgefunden hätte -.- aber trotzdem danke (Prof. ;) ) DeddyH

[DeddyH]

Na siehste :zwinker:

[t0mmy]

Hallo

Ich hätte da noch eine kleine Frage.. wie kann ich die markierten wörter zudem auch noch Groß schreiben... ?_?

[DeddyH]

Wenn ich keinen Denkfehler mache, nach dem Markieren

Delphi-Quellcode:

RichEdit.SelText := AnsiUpperCase(RichEdit.SelText);

[p80286]

Ja.

Was Du Suchst ist SelText und UpCase bzw UpperCase
Gruß
K-H

[t0mmy]

Hallo!

Ich habs jetzt in der Prozedur MarkKeyword ganz zum schluss eingefügt, jedoch ändert sich nichts -.-

Habs schon gefunden... denkfehler -.-