AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Textbreite innerhalb der Titelleiste

Textbreite innerhalb der Titelleiste

Ein Thema von kub · begonnen am 17. Jun 2010 · letzter Beitrag vom 19. Jun 2010
Antwort Antwort
Seite 1 von 2  1 2   
kub

Registriert seit: 13. Nov 2008
41 Beiträge
 
#1

Textbreite innerhalb der Titelleiste

  Alt 17. Jun 2010, 17:56
Hallo zusammen,

Ich will mir ein Meldungsfenster, ähnlich wie bei MessageBox erstellen, dem ich u.a. eine Meldung und eine Caption übergeben kann. Mein Problem liegt in der automatischen Anpassung der Fensterbreite an die Caption.

Bei der Anpassung an die Breite des Meldungslabels kann ich einfach Label.Canvas.Textwidth verwenden, wie kann ich aber die erforderliche Breite für die Caption des Fensters ermitteln?

Wahrscheinlich wurde die Frage schon oft gestellt und beantwortet, aber ich finde die Antwort so nicht.

Gruß
Thomas
  Mit Zitat antworten Zitat
Tobinator

Registriert seit: 18. Mai 2008
Ort: Cottbus
53 Beiträge
 
#2

AW: Textbreite innerhalb der Titelleiste

  Alt 17. Jun 2010, 18:51
Wenn du in deinem Canvas die Font-Einstellungen umstellst, so wie in der Titelleiste (also Canvas.Font.Name='Schriftart der Titelleiste'; usw...) dann könntest du wieder mit Canvas.TextWidth die breite des Textes in der Titelleiste ermitteln. Dann musst du nur noch den Platz für das X und den Rand usw. mit dazu addieren und dann müsste das passen.
Also so würde ich das machen.

Tobi.
Tobias
  Mit Zitat antworten Zitat
Benutzerbild von negaH
negaH

Registriert seit: 25. Jun 2003
Ort: Thüringen
2.950 Beiträge
 
#3

AW: Textbreite innerhalb der Titelleiste

  Alt 17. Jun 2010, 19:49
Die API Funktion SystemParametersInfo() müsste dir alles liefern um diese Schriftbreite ausrechnen zu können.

Gruß Hagen
  Mit Zitat antworten Zitat
kub

Registriert seit: 13. Nov 2008
41 Beiträge
 
#4

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 11:34
Danke für Eure Tipps. Mit folgender Funktion kann ich die Textbreite ermitteln.

Delphi-Quellcode:
function TForm1.GetCaptionWidth: integer;
var
  MyStruct: TNonClientMetrics;
begin
  MyStruct.cbSize:=SizeOf(TNonClientMetrics);
  SystemParametersInfo(
    SPI_GETNONCLIENTMETRICS,
    SizeOf(TNonClientMetrics),
    @MyStruct,
    0);
  Self.Canvas.Font.Handle := CreateFontIndirect (MyStruct.lfCaptionFont);
  Result:= Self.Canvas.TextExtent (Self.Caption).cx;
end;
Ich bin mir jetzt nur nicht sicher, ob ich mit CreateFontIndirect ein Memoryleak erzeuge. Wenn ja, wie kann ich den erzeugten Font freigeben, ohne den Font meines Forms zu zerstören?
  Mit Zitat antworten Zitat
Benutzerbild von negaH
negaH

Registriert seit: 25. Jun 2003
Ort: Thüringen
2.950 Beiträge
 
#5

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 13:52
Das sollte über den TFont vom TCanvas erschlagen sein. Du weist ja das .Handle zu und die VCL kümmert sich dann darum, ergo schon richtig wie du das gemacht hast. Ich finde keinen Fehler in deinem Source, mal abgesehen davon das du das explizite Self weglassen könntest. Und eben den Punkt das alle Zeichenroutinen die später auf TForm.Canvas aufsetzen nun mit dem Font der Titelzeile arbeiten.

Gruß Hagen

Delphi-Quellcode:
function TForm1.GetCaptionWidth: integer;
var
  Metrics: TNonClientMetrics;
begin
  Metrics.cbSize := SizeOf(Metrics);
  SystemParametersInfo(SPI_GETNONCLIENTMETRICS, SizeOf(Metrics), @Metrics, 0);
  Canvas.Font.Handle := CreateFontIndirect(Metrics.lfCaptionFont);
  Result := Canvas.TextExtent(Caption).cx;
  Canvas.Font.Assign(Font); // originalen Font aus TForm.Font restaurieren
end;

Geändert von negaH (18. Jun 2010 um 13:57 Uhr)
  Mit Zitat antworten Zitat
David Martens

Registriert seit: 29. Sep 2003
205 Beiträge
 
Delphi XE Enterprise
 
#6

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 17:42
Also ich hole mir die Textbreite immer so:

Delphi-Quellcode:
function GetTextWidth(Text: string; Font: TFont): integer;
var
  WMF : TMetafile; // virtuelle WMF bzw. EMF Datei (enthält das Image)
  WMFCanvas : TMetafileCanvas; // virtuelle Oberfläche des Metafiles
begin
  WMF := TMetafile.Create;
  WMFCanvas := TMetafileCanvas.Create(WMF, 0);

  WMFCanvas.Brush.Style := bsClear;
  WMFCanvas.Font := Font;

  Result := WMFCanvas.TextWidth(Text);

  WMFCanvas.Free;
  WMF.Free;
end;
  Mit Zitat antworten Zitat
Benutzerbild von negaH
negaH

Registriert seit: 25. Jun 2003
Ort: Thüringen
2.950 Beiträge
 
#7

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 18:53
Das gibt dir aber nicht die Textbreite mit der Schriftart in der Titelzeile = Non Client Area eines Fensters zurück. Davon abgesehen wäre es dann sinnvoller über einen TBitmap.Canvas zu gehen statt über die langsammen WMF/EMFs. Der einzige Nachteil über TForm.Canvas zu gehen ist der das das TForm.Handle vorher alloziert sein muß. Unter Umständen, wenn man mit kubs Methode arbeitet, und das TForm noch ohne Handle=hWnd ist, zb. beim Laden aus dem DFM, wird intern über .HandleNeeded das TForm.Handle zu frühzeitig erzeugt. Das kann dann einige unerwünschte Nebenwirkungen mit sich bringen.

Gruß Hagen
  Mit Zitat antworten Zitat
David Martens

Registriert seit: 29. Sep 2003
205 Beiträge
 
Delphi XE Enterprise
 
#8

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 20:17
Also ich hab mal beide Varianten gegenüber gestellt.

Angepasst an meine Combobox mit 7.000.000 Zellen (7 mal 1.000.000).

einmal:
Delphi-Quellcode:
var
  WMF : TMetafile; // virtuelle WMF bzw. EMF Datei (enthält das Image)
  WMFCanvas : TMetafileCanvas; // virtuelle Oberfläche des Metafiles
  i, j, iWidthTest : integer;

begin
  WMF := TMetafile.Create;
  WMFCanvas := TMetafileCanvas.Create(WMF, 0);

  WMFCanvas.Brush.Style := bsClear;

  WMFCanvas.Font := Self.Font;

  for i := 0 to FGrid.RowCount - 1 do
  begin
    for j := 1 to FGrid.ColCount - 1 do
    begin
      if FGrid.ColWidths[j] < WMFCanvas.TextWidth(FGrid.Cells[j, i]) + 9 then
        if WMFCanvas.TextWidth(FGrid.Cells[j, i]) + 5 < FMaxColWidth then
        begin
          FGrid.ColWidths[j] := WMFCanvas.TextWidth(FGrid.Cells[j, i]) + 9;
        end
        else
        begin
          FGrid.ColWidths[j] := FMaxColWidth;
        end;
    end;
  end;

  WMFCanvas.Free;
  WMF.Free;
  ...
und dann:
Delphi-Quellcode:
var
  i, j, iWidthTest : integer;
  Metrics : TNonClientMetrics;
begin
  Metrics.cbSize := SizeOf(Metrics);
  SystemParametersInfo(SPI_GETNONCLIENTMETRICS, SizeOf(Metrics), @Metrics, 0);
  Canvas.Font := Font;

  for i := 0 to FGrid.RowCount - 1 do
  begin
    for j := 1 to FGrid.ColCount - 1 do
    begin
      if FGrid.ColWidths[j] < Canvas.TextExtent(FGrid.Cells[j, i]).cx + 9 then
        if Canvas.TextExtent(FGrid.Cells[j, i]).cx + 5 < FMaxColWidth then
        begin
          FGrid.ColWidths[j] := Canvas.TextExtent(FGrid.Cells[j, i]).cx + 9;
        end
        else
        begin
          FGrid.ColWidths[j] := FMaxColWidth;
        end;
    end;
  end;
  ...
mit meinem WMF bin ich NICHT signifikant schneller. Meine Variante braucht 4,1.. e-5 und die Metrics braucht 4,2.. e-5.
  Mit Zitat antworten Zitat
Benutzerbild von negaH
negaH

Registriert seit: 25. Jun 2003
Ort: Thüringen
2.950 Beiträge
 
#9

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 21:33
@David:

erstmal gehts nicht um schneller oder langsammer sondern um die Frage: ist die so ermitteltete Breite eines Textes identisch zur Breite wenn man sie in der Schriftart in der Titelzeile eines Fenster zeichnen würde. Und die Antwort ist, nein. Du weist dem WMF Canvas nur den Font deklariert im TForm zu und nicht den den das Windows OS zum Zeichnen der Titelzeile verwendet. (quasi Thema verfehlt)

Es gibt nur eine Methode das zu machen:
1.) mit SystemParamatersInfo() den Font als Struktur vom Betriebssystem holen
2.) diese Struktur und ein GDI Font Handle mit CreateFontIndirekt() umwandlen
3.) diese Handle einen Canvas.Font.Handle zuweisen oder direkt über das Windows GDI API das Gleiche ohne Umwege über den TCanvas.Font machen.

Nun streiche mal all diese Funktinen aus Kubs Funktion heraus und schau was im Vergleich zu deinem Vorschlag übrig bleibt. Ich sage es nur ungern so deutlich, es bleibt ne Menge heiße Luft die keinerlei Vorteile bringt, eher Nachteile.

Angenommen man möchte die Breite eines Textes im Font des TForms ermitteln, dann geht das am einfachsten so:

Delphi-Quellcode:
funcntion TForm1.GetTextWidth(const Text: String): Integer;
begin
  Result := Canvas.TextWidth(Text);
end;
Also ein Einzeiler der exakt das gleiche Resultat bringt wie dein Source !

Gruß Hagen

PS: verzeih mir bitte die eventuell harten Worten, aber es ist nunmal nicht anders.
  Mit Zitat antworten Zitat
kub

Registriert seit: 13. Nov 2008
41 Beiträge
 
#10

AW: Textbreite innerhalb der Titelleiste

  Alt 18. Jun 2010, 22:35
Hi,
vielen Dank für eure Hilfe!

Ich werde bei der von Hagen verbesserten Funktion bleiben. Trotzdem danke für alle Vorschläge.

Gruß
Thomas
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 11:23 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf