AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Kommandozeilenprogramm ausführen und Ausgabe umleiten

Kommandozeilenprogramm ausführen und Ausgabe umleiten

Ein Thema von Shark99 · begonnen am 22. Jun 2010 · letzter Beitrag vom 2. Aug 2018
Antwort Antwort
Seite 1 von 2  1 2   
Shark99

Registriert seit: 16. Mai 2007
389 Beiträge
 
#1

Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 22. Jun 2010, 14:01
Ich habe folgenden Code in einer Batchdatei:

dc64cmd.exe -listmonitors >w:\temp\monitors.txt

Wie kann ich dc64cmd.exe mit Delphi starten und die Ausgabe in eine Datei umleiten?

Auf den ersten Blick sehe ich weder bei ShellExecute() noch bei CreateProcess() eine Möglichkeit die Ausgabe in eine Datei umzuleiten.

Danke im Voraus!
  Mit Zitat antworten Zitat
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
26.868 Beiträge
 
Delphi 10.3 Rio
 
#2

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 22. Jun 2010, 14:07
Einfach die Exe starten und die Parameter übergeben samt Dateiumleitung.
ShellExecute(0,'open','dc64cmd.exe','-listmonitors > w:\temp\monitors.txt',nil,SW_SHOW); [edit] Achso, Kommandozeilenprogramm. Du kannst es auch so versuchen:
ShellExecute(0,'open','cmd.exe','/c dc64cmd.exe -listmonitors > w:\temp\monitors.txt',nil,SW_SHOW); Ermitteln des Kommandointerpreters und Auswertung des Rückgabewertes habe ich alles weggelassen, das kannst Du ja noch implementieren [/edit]
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen

Geändert von DeddyH (22. Jun 2010 um 14:10 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.931 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#3

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 22. Jun 2010, 14:43
Das diese Umleitung via > ein Feature des CommandLine-Interpreters sein dürfte, wirst du hierfür auch diesen (z.B. die cmd.exe) ansprechen müssen.

Ansonsten könntest du über MSDN-Library durchsuchenCreateProcess in der STARTUPINFO auch einen anderen StdOutput angeben, z.B. ein FileHandle oder eine Pipe.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014

Geändert von himitsu (22. Jun 2010 um 14:46 Uhr)
  Mit Zitat antworten Zitat
Florian Hämmerle
(Gast)

n/a Beiträge
 
#4

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 22. Jun 2010, 16:46
http://www.swissdelphicenter.ch/de/showcode.php?id=990 zeigt wie du die Ausgabe der Konsole erhältst.

mfg Florian
  Mit Zitat antworten Zitat
Teekeks

Registriert seit: 19. Okt 2008
Ort: Dresden
765 Beiträge
 
FreePascal / Lazarus
 
#5

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 22. Jun 2010, 22:21
Das ist dann aber doof wenn der Zwischenpuffer voll läuft. dann wartet das ausgeführte Programm darauf das dieser geleert wird, und das ausführende Programm wartet darauf das sich das Programm beendet, damit der Puffen geleert werden kann.
Ergo: Endloßschleife.

Besser ist das hier:
Delphi-Quellcode:
   
const
   READ_BYTES = 2048;

var proc:TProcess;
   S2: TStringList;
   M: TMemoryStream;
   n: LongInt;
   BytesRead: LongInt;
begin
   M := TMemoryStream.Create;
   BytesRead := 0;
   proc:=TProcess.create;
   proc.Options:=[poUsePipes];
   Proc.CommandLine :='WasAuchImmer.echse';
   Proc.Execute;
   while Proc.Running do
   begin
     // stellt sicher daß wir Platz haben
     M.SetSize(BytesRead + READ_BYTES);

     // versuche es zu lesen
     n := Proc.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
     if n > 0
     then begin
       Inc(BytesRead, n);
     end
     else begin
       // keine Daten, warte 100 ms
       Sleep(100);
     end;
   end;
   // lese den letzten Teil
   repeat
     // stellt sicher daß wir Platz haben
     M.SetSize(BytesRead + READ_BYTES);
     // versuche es zu lesen
     n := Proc.Output.Read((M.Memory + BytesRead)^, READ_BYTES);
     if n > 0
     then begin
       Inc(BytesRead, n);
     end;
   until n <= 0;
   M.SetSize(BytesRead);

   S2 := TStringList.Create;
   S2.LoadFromStream(M);
//mache was mit dem Output...
   S2.Free;
   M.Free;
   proc.free;
end;
Peter
"Div by zero Error" oder auch: "Es geht auch ohne Signatur!".
  Mit Zitat antworten Zitat
Benutzerbild von Codehunter
Codehunter

Registriert seit: 3. Jun 2003
Ort: Thüringen
1.971 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#6

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 10. Jul 2018, 17:10
Ich fleddere mal diese Leiche und ergänze die Frage: Hat sich vielleicht in den letzten 8 Jahren, seit dieser Thread erstellt wurde, in der RTL etwas getan? So dass Delphi möglicherweise das Pipen von Konsolenausgaben von Haus aus mit wenig Code ermöglicht?
Ich mache grundsätzlich keine Screenshots. Schießen auf Bildschirme gibt nämlich hässliche Pixelfehler und schadet der Gesundheit vom Kollegen gegenüber. I und E zu vertauschen hätte den selben negativen Effekt, würde aber eher dem Betriebsklima schaden
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.931 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#7

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 10. Jul 2018, 18:04
Nicht, dass ich wüsste.

Ich glaub aber sowas wie DOSBox mal im GetIt gesehn zu haben.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014

Geändert von himitsu (10. Jul 2018 um 18:06 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
7.076 Beiträge
 
Delphi 10.3 Rio
 
#8

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 10. Jul 2018, 18:07
Ich glaub aber sowas wie DOSBox mal im GetIt gesehn zu haben.
DOSCommand
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
jziersch

Registriert seit: 9. Okt 2003
Ort: München
81 Beiträge
 
Delphi 10.3 Rio
 
#9

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 12. Jul 2018, 07:50
Ich habe diese Funktion eingesetzt um die Ausgabe von DCRaw in einen Stream umzuleiten.

Code:
function GetDosOutput(CommandLine: string; Params: string; AStream : TStream): Integer;
var
  SA: TSecurityAttributes;
  SI: TStartupInfo;
  PI: TProcessInformation;
  StdOutPipeRead, StdOutPipeWrite: THandle;
  WasOK: Boolean;
  Buffer: array[0..255] of AnsiChar;
  BytesRead: Cardinal;
  WorkDir, AParameter: string;
  Handle: Boolean;
begin
  Result := 0;
  with SA do begin
    nLength := SizeOf(SA);
    bInheritHandle := True;
    lpSecurityDescriptor := nil;
  end;
  CreatePipe(StdOutPipeRead, StdOutPipeWrite, @SA, 0);
  try
    with SI do
    begin
      FillChar(SI, SizeOf(SI), 0);
      cb := SizeOf(SI);
      dwFlags := STARTF_USESHOWWINDOW or STARTF_USESTDHANDLES;
      wShowWindow := SW_HIDE;
      hStdInput := GetStdHandle(STD_INPUT_HANDLE); // don't redirect stdin
      hStdOutput := StdOutPipeWrite;
      hStdError := StdOutPipeWrite;
    end;
    WorkDir := 'C:\';
    AParameter := Format('"%s" %s', [CommandLine, TrimRight(Params)]);

    Handle := CreateProcess(nil, PChar({'cmd.exe /C ' + }AParameter),
                            nil, nil, True, 0, nil,
                            PChar(WorkDir), SI, PI);
    CloseHandle(StdOutPipeWrite);
    if Handle then
      try
        repeat
          WasOK := ReadFile(StdOutPipeRead, Buffer, 255, BytesRead, nil);
          if BytesRead > 0 then
          begin
            AStream.Write(Buffer[0],BytesRead);
            Result := Result + BytesRead;
          end;
        until not WasOK or (BytesRead = 0);
        WaitForSingleObject(PI.hProcess, INFINITE);
      finally
        CloseHandle(PI.hThread);
        CloseHandle(PI.hProcess);
      end;
  finally
    CloseHandle(StdOutPipeRead);
  end;
end;
vgl: http://stackoverflow.com/questions/9...o-a-delphi-app

Grüsse,
Julian
WPCubed GmbH
Komponenten für Delphi:
WPTools, wPDF, WPViewPDF
  Mit Zitat antworten Zitat
Benmik

Registriert seit: 11. Apr 2009
251 Beiträge
 
Delphi 10.3 Rio
 
#10

AW: Kommandozeilenprogramm ausführen und Ausgabe umleiten

  Alt 2. Aug 2018, 21:00
Ich vermute mal, das hier ist identisch mit dem bereits Geposteten, aber es ist eine Lösung, die ich bereits erfolgreich angewendet habe.
Wundert mich, dass sich Uwe Raabe so zurückhält, hat er sich doch hier bereits engagiert.
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 05:04 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf