AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Projekte Google Maps über COM (Component Object Model)

Google Maps über COM (Component Object Model)

Ein Thema von Thom · begonnen am 23. Dez 2010 · letzter Beitrag vom 22. Mai 2022
Antwort Antwort
Seite 23 von 55   « Erste     13212223 242533     Letzte » 
Thom
Registriert seit: 19. Mai 2006
screenshot_panoramio.jpg

Use Google Maps API inside your Delphi application. Free, easy to use and much more powerful than a component.

Der Kern besteht aus einer Delphi-To-JavaScript-Bridge, mit deren Hilfe Delphi-Programme über das COM-Interface des Internet Explorers auf JavaScript-Objekte und -Funktionen zugreifen können. Die Kommunikation ist dabei bidirektional: Das bedeutet, daß Objekt- und anonyme Methoden aus JavaScript heraus aufgerufen werden können - zum Beispiel als Callback-Funktion, Event-Handler oder "injizierter" Code.

In diesem Framework wurde mit Hilfe dieser Delphi-To-JavaScript-Bridge das komplette Google Maps API abgebildet. Damit ist es möglich, alle Funktionen und Objekte dieses API's anzusprechen, ohne eine einzige Zeile JavaScript schreiben zu müssen.

Nun gibt es schon eine Reihe von Lösungsvorschlägen und Komponenten für Delphi, die das Google Maps API kapseln (ohne Anspruch auf Vollständigkeit):
Weshalb dann noch dieses Framework?
Ganz klar zwei Gründe:
  1. Der Preis. Für Freeware oder OpenSource, die nach den Lizenzbedingungen von Google keine Premier Lizenz benötigt, sind diese Preise indiskutabel. Eine kostenlose Version, die das komplette API bedient, ist mir nicht bekannt.
  2. Die Flexibilität. Eine Komponente kann prinzipiell kein API ersetzen. Sie macht zwar die Arbeit des Programmierers bedeutend leichter und spart viel Zeit bei der Einarbeitung und Umsetzung des Projektes (bei kommerziellen Projekten ist Zeit gleich Geld, daher auch die hohen Preise für diese Komponenten) - schränkt aber mehr oder weniger stark ein.
    Eine JavaScript-ähnliche Programmierung ist nicht möglich.

Mit diesem Framework können JavaScript-Beispiele ohne Probleme nach Delphi umgesetzt werden - mit den Vorteilen einer Code-Vervollständigung und komfortablen Debugging-Möglichkeiten.

Ein kleines Beispiel:
Code:
[...]
<script type="text/javascript">
  function CreateMap() {
    var Options = {zoom: 13,
                   center: new google.maps.LatLng(47.651743,-122.349243),
                   mapTypeId: google.maps.MapTypeId.SATELLITE};
    new google.maps.Map(document.getElementById("div_map"),Options);
  };
</script>
</head>
<body onload="CreateMap()">
[...]
Delphi-Quellcode:
procedure TForm1.FormShow(Sender: TObject);
begin
  if Script=nil then
    with TScript.Create(WebBrowser1) do
      LoadAPIAsync(InitMap);
end;

procedure TForm1.InitMap(Sender: TObject);
var
  Options: TMapOptions;
begin
  with TScript(Sender) do
  begin
    Options:=TMapOptions.Create;
    with Options do
    begin
      Zoom:=13;
      Center:=New(Google.Maps.LatLng(47.651743,-122.349243));
      MapTypeID:=Google.Maps.MapTypeID.Satellite;
    end;
    New(Google.Maps.Map(Options));
  end;
end;
In der aktuellen Version 2.0 besteht das Framework aus rund 30000 Quelltextzeilen, 10000 Zeilen Dokumentation im XML-Format und rund 10000 Zeilen in reichlich 80 Demos.

Systemvoraussetzungen
  • Delphi ab Version 5 (empfohlen Delphi 2009 oder neuer zur Nutzung von Unicode und anonymen Methoden)
  • Internet Explorer ActiveX (zum Beispiel TWebBrowser (1) oder TEmbeddedWB)
  • bei einigen Demos installierte Indy-Komponenten
  • bei einer Demo eine installierte TChart-Komponente

Das Framework wurde bisher mit folgenden Delphi-Versionen getestet:
  • Delphi 5
  • Delphi 7 (vielen Dank an angos!) (2)
  • Delphi 2005
  • Delphi 2007
  • Delphi 2010
  • Delphi XE
  • Delphi XE2 32/64 Bit
  • Delphi XE3 32/64 Bit (vielen Dank an Stefan für die angepaßte inc-Datei und für's Testen!)
  • Delphi XE4 32/64 Bit
  • Delphi XE5 32/64 Bit

Bekannte Probleme

In Zusammenhang mit dem Internet Explorer 6 (sollte eigentlich keiner mehr benutzen):
  • Darstellungsfehler bei Schatteneffekten
  • langsamer Schatten- und Bildaufbau
  • keine Überblendeffekte
  • keine Base64/Data-Unterstützung
  • Probleme bei der Nutzung von Icons (die Demos Icon Simple und Icon Complex bleiben hängen)
  • keine Animation von Markern
  • das StreetView-Symbol verschwindet sporadisch
Allgemein:
  • werden vor Delphi 2007 TGIFImage und vor Delphi 2009 TPNGImage verwendet (bis dahin nicht Bestandteil von Delphi), können die entsprechenden Compilerschalter in der Datei gmConfig.inc aktiviert werden
  • die integrierte XML-Hilfe funktioniert noch nicht richtig und ist noch nicht vollständig
  • unter den verstärkten Sicherheitseinstellungen für den Internet Explorer in einem Server-System konnte bisher kein Zugriff auf die Funktionen der JavaScript-Engine hergestellt werden
  • die Demo Places Autocomplete führt unter IE9 64 Bit zu einem Absturz des Programmes, wenn das Edit-Feld benutzt wird

Installation, Migration bestehender Projekte

Da es sich um ein Framework handelt, muß nichts in der IDE installiert werden - es müssen lediglich die Pfade zur gmConfig.inc sowie den Verzeichnissen API und JScript eingetragen werden (global oder in den Projekt-Optionen).

Die Umstellung von bestehenden Projekten unter Verwendung der Versionen 1.x auf die Version 2.0 sollte sich in der Regel auf die Anpassung der Unit-Namen beschränken. Um eine bessere Übereinstimmung zur Google Maps API-Dokumentation zu erzielen, wurden einige Units umbenannt. Auf die Einführung eines Namespace wurde mit Rücksicht auf ältere Delphi-Versionen (noch) verzichtet.
Es wird empfohlen, die Initialisierung der Karte in eine separaten Methode auszulagern, um den Refresh-Mechanismus (Taste F5) des Frameworks nutzen zu können.

Lizenz

(Möglichst) kurz und schmerzlos:
Ich mag keine seitenlangen Texte, die meist nur verunsichern (siehe aktuelle Problematik mit einer speziellen Datenbank) und die sowieso kaum jemand liest. Noch weniger mag ich Quelltexte, die am Anfang einen Hinweis enthalten, der länger ist als der eigentliche Code. Auch bin ich aus dem Alter heraus, in dem ich nach jeweils drei Zeilen mein Copyright hinterlassen muß, als hätte ich die genialste Erfindung aller Zeiten gemacht und müßte wie ein Hund mein Revier markieren. Wer das nötig hat, soll das machen - ich jedenfalls nicht.
Deshalb nur folgende Regeln:
  1. Die Nutzungsbedingungen von Google sind zu beachten.
  2. Die Verwendung des Frameworks ist kostenfrei, wenn die Anwendung, die damit erstellt wurde, kostenlos und frei für alle zur Verfügung steht (siehe Lizenzbestimmungen von Google: Das schließt zum Beispiel die Kopplung an kostenpflichtige Hard- oder Software und eine innerbetriebliche Nutzung aus!!!). Das veröffentlichte Programm muß keinesfalls OpenSource sein.
  3. Keine Leistung - keine Verpflichtung. Wird das Framework in der kostenlosen Community-Edition verwendet, gibt es keinen Anspruch auf Bugfixes, Updates oder Hilfe. Das bedeutet natürlich nicht, daß ich hier im Forum nicht mehr auf Fragen antworte.
  4. Für jegliche andere Nutzung (kommerziell, innerbetrieblich, geschlossene Benutzergruppe) ist eine Lizenzierung bei Google und mir notwendig. Bei Nachfrage bitte per PM oder Email melden. Von meiner Seite sind dann Bugfixes, Updates und Support für ein Jahr garantiert.
  5. Wem das Framework gefällt und wer die Weiterentwicklung unterstützen möchte, kann das in Form eine Spende tun. Ab einer Spendenhöhe von gegenwärtig 25 € erhält der/die Spender/in als Dankeschön zusätzliche Units, Komponenten und Demos (siehe Abschnitt Erweiterungen) sowie alle weiteren Bonus-Komponenten, die in der Version 2.x veröffentlicht werden. Falls jemand kein PayPal-Konto besitzt, kann er mich auch für eine direkte Überweisung (innerhalb Deutschlands) kontaktieren. Für einen Betrag von mindestens 100 € wird der Spender namentlich genannt (falls er nicht anonym bleiben möchte). (3)

Erweiterungen
  1. Panoramio API
    - Wrapper-Unit
    - Demo
  2. KeyDragZoom Library
    - Wrapper-Unit
    - sechs Demos
  3. MarkerClustererPlus Library
    - Wrapper-Unit
    - fünf Demos
  4. RichMarker Library
    - Wrapper-Unit
    - zwei Demos

Viel Spaß!

(1) Wer für die Starter Editionen (XE bzw. XE2) keine TWebBrowser-Komponente besitzt, kann diese hier nachrüsten.
(2) siehe Beitrag
(3) Spenden über PayPal (Bitte Name und Email-Adresse angeben, damit ich die Bonus-Units versenden kann.)
Angehängte Dateien
Dateityp: zip GoogleMaps_1.1_Source&Demos.zip (587,1 KB, 1224x aufgerufen)
Dateityp: zip GoogleMaps_2.0_Source&Demos.zip (458,2 KB, 1743x aufgerufen)
Dateityp: zip gmConfig.inc_XE5.zip (1,9 KB, 416x aufgerufen)

Geändert von Thom (17. Sep 2013 um 14:03 Uhr) Grund: gmConfig.inc für Delphi XE5
 
DelphiFan2008

 
Delphi XE2 Starter
 
#221
  Alt 15. Apr 2012, 18:18
Hallo Thom,

mit deinem Tip komme ich jetzt an die detaillierten Datenpunkte mit folgendem Code

Delphi-Quellcode:
var i,k,l : Integer;
     f1,f2 : Double;
     MyRoute : TDirectionsRoute;
     TP : TTrackPoint;
     s : String;
begin
  LB.Clear;
  TD.Clear;
  f1 := 0.0;

  with Script do
  begin
    MyRoute := DirectionsRenderer[0].Directions.Routes[0];

    for i := 0 to MyRoute.Legs.Count-1 do
    begin
      s := MyRoute.Legs[i].StartAddress+' nach '+MyRoute.Legs[i].EndAddress;
      LB.Items.Add( Format( '[%d] %s',[i+1,s] ));
      LB.Items.Add( '' );

      for k := 0 to MyRoute.Legs[i].Steps.Count-1 do
      begin
        // BEGIN Anweisungen für diesen Schritt in Form einer Zeichenfolge
        s := MyRoute.Legs[i].Steps[k].Instructions;
        f2 := MyRoute.Legs[i].Steps[k].Distance.Value / 1000;
        f1 := f1 + f2;
        LB.Items.Add( Format( '[%d] %s %1.2fkm',[k+1,s,f2] ));
        // END Anweisungen für diesen Schritt in Form einer Zeichenfolge

        for l := 0 to MyRoute.Legs[i].Steps[k].Path.Count-1 do
        begin
          // BEGIN Speicher für TrackPoint reservieren und Daten erfassen
          TP := TTrackPoint.Create;

          TP.LatitudeDegrees := MyRoute.Legs[i].Steps[k].Path[l].Lat;
          TP.LongitudeDegrees := MyRoute.Legs[i].Steps[k].Path[l].Lng;

          TD.TrackPointList.Add( TP );
          // END Speicher für TrackPoint reservieren und Daten erfassen
        end;
      end;
      LB.Items.Add( '' );
      LB.Items.Add( Format( 'Streckenlänge : %1.2fkm',[f1] ));
    end;
  end;

  TD.Export...
jetzt wird es noch spannend die entsprechenden Höhewerte mittels "PathElevationRequest" bzw. "LocationElevationRequest" zu ermitteln. Bei meiner Demo-Route entstehen für den Track ca. 5100 Wertepaare LAT/LNG auf ca. 130km. Du hattest mir schon mal bei der Ermittlung geholfen. Damals war bei ca. 1000 Anfragen eine Pause von ca. 8 Sekunden notwendig. Werde mal verschiedene Ansätze versuchen. Der BikeRoutToaster scheint keine Pause zu verwenden, das Höhenprofil wird parallel erzeugt. Mir fehlen schon die Grundkenntnisse in JavaScript um an den Quelltext zu gelangen bzw. den zu lesen

Danke und Gruß DelphiFan2008
  Mit Zitat antworten Zitat
Thom

 
Delphi XE3 Professional
 
#222
  Alt 15. Apr 2012, 20:10
Hmmm... Auf meinem PC brauchen die aber auch eine ganze Weile, um das Höhenprofil zu ermitteln. Wie genau muß das Profil sein?
Bei einer PathElevationRequest-Anfrage kannst Du ja bis zu 1024 Höhenwerte ermitteln lassen. Das macht auf 130 km etwa einen Wert pro 130 m. Reicht Dir das? Das sollte dann ohne gelbe Karte von Google und Wartezeit gehen...
Thomas Nitzschke
  Mit Zitat antworten Zitat
DelphiFan2008

 
Delphi XE2 Starter
 
#223
  Alt 15. Apr 2012, 20:40
Hi Thom,

du hast recht, beim spielen mit dem Programm fällt auf, dass die Abfragen auch ne Weile dauern. Da GoogleMap eine schöne feine Auflösung liefert - zuerst war es mir zu grob, wie gesagt nun ca. 5100 Wertepaare auf 130km - müssen diese falls notwendig auf kleiner 1024 reduziert werden -> PathElevationRequest. Ich habe die letzten zwei Stunden mit dem Douglas-Peucker Algorithmus experimentiert um die Punktezahl zu reduzieren, Quelle1 und Quelle2. Werde mich noch ein wenig beschäftigen. Mein Outdoor-Navi, für welches ich dies alles mache wird sich auch über die geringere Datenmenge freuen.

Frage noch in die andere Richtung - kann GoogleMap evntl. per API schon analog zu Douglas-Peucker optimieren?

Gruß DelphiFan2008
  Mit Zitat antworten Zitat
Thom

 
Delphi XE3 Professional
 
#224
  Alt 15. Apr 2012, 22:32
Nicht, daß ich wüßte...
Ich bilde mir aber ein (nicht getestet), daß der Pfad keine Begrenzung der Punktanzahl vorschreibt. Theoretisch sollte es möglich sein, den kompletten Pfad zu übergeben (also nicht jeden Punkt einzeln kopieren) und dann einfach die gewünschte Anzahl (max. 1024) Höherwerte ermitteln zu lassen (eventuell in Abhängigkeit von der Pfadlänge). Google interpoliert dann einfach zwischen den Stützpunkten, die den Pfad darstellen.
Thomas Nitzschke

Geändert von Thom (17. Apr 2012 um 00:38 Uhr)
  Mit Zitat antworten Zitat
manfred_h

 
Delphi XE2 Enterprise
 
#225
  Alt 16. Apr 2012, 17:11
Hallo Thom

Bin gerade weiter dabei die Karte in meine Anwendung zu integrieren.
Was mir nicht ganz klar ist wie kann ich das InfoWindow einem Marker zuordnen?
Beim Marker erscheint immer das erste InfoWindow, was eigentlich auch klar ist
da ich ja dies aufrufe Infowindows[0].Open(Maps[0],Marker); .
Stecke hier ein wenig fest....

mit folgendem code werden die Marker gesetzt:
Delphi-Quellcode:
procedure Tfrm_map.btn_Encode_batchClick(Sender: TObject);
var
  LatLng: TLatLng;
  Lat, Lng, InfoWindow_String: String;
  InfoWindow: TInfoWindow;
  Marker: TMarker;
  MarkerOptions: TMarkerOptions;
begin
  with Script do
  begin
    Marker:=nil; //falls keine Daten in der Tabelle vorliegen
    DM_map.Map.First;
    while not DM_map.Map.Eof do
    begin
      if DM_map.Map.FieldByName('POS_LAT').Text = 'then
        DM_map.Map.Next
      else
      Lat:=DM_map.Map.FieldByName('POS_LAT').Text;
      Lng:=DM_map.Map.FieldByName('POS_LNG').Text;
      InfoWindow_String:=(
      //
        DM_map.Map.FieldByName('AREA').AsString + '<br>'+
        DM_map.Map.FieldByName('NAME').AsString + '<br>'+
        DM_map.Map.FieldByName('STR').AsString + '<br>'+
        DM_map.Map.FieldByName('PLZ').AsString + '-'+
        DM_map.Map.FieldByName('CITY').AsString + '<br>'+'TEL:' +
        DM_map.Map.FieldByName('TEL').AsString + '<br>'+'______________________ <br>'+'Camp ' + '- '+
        DM_map.Map.FieldByName('C_NO').AsString);
      //
      LatLng:=New(Google.Maps.LatLng(StrToFloatDef(Lat,0,'.'),
                                   StrToFloatDef(Lng,0,'.')));
      InfoWindow:=New(Google.Maps.InfoWindow);
      InfoWindow.Content:=InfoWindow_String;
      MarkerOptions:=TMarkerOptions.Create;
      with MarkerOptions do
      begin
        Map:=Maps[0];
        Position:=LatLng;
        MarkerOptions.Title:= DM_map.Map.FieldByName('NAME').AsString;
      end;
      Marker:=New(Google.Maps.Marker(MarkerOptions));
      Marker.OnClick:=MarkerClick;
      MarkerOptions.Free; //momentan noch etwas auf den Speicher achten
                          //-> in der neuen Version stelle ich auf Interfaces um,
                          //so daß die Freigabe automatisch erfolgt
      LatLng.Free; //gleicher Grund
      DM_map.Map.Next;
    end;
    if assigned(Marker)
      then Maps[0].SetCenter(Marker.GetPosition); //nur den letzten Marker zentrieren
  end;
end;
Delphi-Quellcode:
procedure Tfrm_map.MarkerClick(Sender: TObject; Event: TEvent);
var
  Marker: TMarker;
  Text: String;
begin
  with Script do
  begin
    Marker:=TMarker(Sender);
// Text:=Marker.Properties['PlaceName'];
// Infowindows[0].SetContent(Text);
    Infowindows[0].Open(Maps[0],Marker);
  end;
end;
  Mit Zitat antworten Zitat
Thom

 
Delphi XE3 Professional
 
#226
  Alt 16. Apr 2012, 18:29
Du müßtest das Info-Fenster an den Marker "binden". Ab Delphi 2009 geht das sehr komfortabel über anonyme Methoden. Ansonsten könntest Du die Data-Eigenschaft des Markers nutzen und dort das InfoWindow-Objekt ablegen (vergleichbar mit TListItem.Data):
Delphi-Quellcode:
  Marker.Data:=InfoWindow;
  [...]
Die Anzeige im MarkerClick-Ereignis ist dann einfach:
Delphi-Quellcode:
 [...]
var
  Marker: TMarker;
  InfoWindow: TInfoWindow;
begin
  Marker:=Sender as TMarker;
  InfoWindow:=(Marker.Data) as TInfoWindow;
  if assigned(InfoWindow)
    then InfoWindow.Open(Marker.GetMap,Marker);
end;
Wobei ich bei diesem Tip etwas Bauchschmerzen habe, da ich noch nicht 100%ig weiß, ob das Data-Property noch in der kostenlosen Personal-Edition der nächsten Version vorkommen wird. Eigentlich sollen dort nur Objekte, Eigenschaften und Methoden enthalten sein, die auch im Google Maps API dokumentiert sind. Delphi "Komfort"-Funktionen (wozu auch die Data- und die Tag- Eigenschaft gehören) sollen eigentlich der Professional- und Enterprise-Edition vorbehalten sein. Da muß ich noch etwas darüber schlafen...

Ansonsten könntest Du natürlich auch ein Array mit allen Marker-InfoWindow-Paaren aufbauen und darüber die Zuordnung realisieren:
Delphi-Quellcode:
type
  TMarkerData = record
    Marker: TMarker;
    InfoWindow: TInfoWindow;
  end;

var
  MarkerData: array[0..x] of TMarkerData;
Desweiteren würde ich empfehlen, als Cast nur den as -Operator zu verwenden, da zukünftig Interfaces genutzt werden und damit die Umstellung schneller geht (IMarker(Sender) geht dann nämlich schief):
Delphi-Quellcode:
//bisher:
procedure TForm1.MarkerClick(Sender: TObject; Event: TEvent);
begin
  with Sender as TMarker do
  begin
  end;
end;

//zukünftig:
procedure TForm1.MarkerClick(Sender: IObject; Event: IEvent);
begin
  with Sender as IMarker do
  begin
  end;
end;
Thomas Nitzschke
  Mit Zitat antworten Zitat
manfred_h

 
Delphi XE2 Enterprise
 
#227
  Alt 17. Apr 2012, 16:04
Hallo Thom

Bei der Variante mit Marker.Data:=InfoWindow erhalte ich eine EAccessViolation
ohne nähere angaben. Habe schon versucht das Info-Window nur einzeilg zu halten brachte aber keinen Unterschied.

Du müßtest das Info-Fenster an den Marker "binden". Ab Delphi 2009 geht das sehr komfortabel über anonyme Methoden. Ansonsten könntest Du die Data-Eigenschaft des Markers nutzen und dort das InfoWindow-Objekt ablegen (vergleichbar mit TListItem.Data):
Delphi-Quellcode:
  Marker.Data:=InfoWindow;
  [...]
Die Anzeige im MarkerClick-Ereignis ist dann einfach:
Delphi-Quellcode:
 [...]
var
  Marker: TMarker;
  InfoWindow: TInfoWindow;
begin
  Marker:=Sender as TMarker;
  InfoWindow:=(Marker.Data) as TInfoWindow;
  if assigned(InfoWindow)
    then InfoWindow.Open(Marker.GetMap,Marker);
end;
[/DELPHI]
Mit dem Array bin ich noch nicht ganz klar gekommen, werde mich als nächstes daran versuchen.
Das ganze sieht aber schon wirklich super aus.
Manfred
  Mit Zitat antworten Zitat
Thom

 
Delphi XE3 Professional
 
#228
  Alt 17. Apr 2012, 19:52
Ich habe gerade mal folgende Variante getestet (Framework Version 2.0 mit Delphi XE):
Delphi-Quellcode:
procedure TForm1.InitMap(Sender: TObject);
var
  Map: TMap;
  MapOptions: TMapOptions;
begin
  with Sender as TScript do
  begin
    MapOptions:=TMapOptions.Create;
    with MapOptions do
    begin
      Zoom:=10;
      Center:=New(Google.Maps.LatLng(47.651743,-122.349243));
      MapTypeID:=Google.Maps.MapTypeID.Roadmap;
    end;
    Map:=New(Google.Maps.Map(MapOptions));
    Map.OnClick:=
      procedure(Sender: TObject; Event: TMouseEvent)
      var
        Marker: TMarker;
        InfoWindow: TInfoWindow;
      begin
        Marker:=New(Google.Maps.Marker);
        Marker.Position:=Event.LatLng;
        Marker.Map:=Map; //<- hier wird das Map-Objekt aus der InitMap-Methode genommen
        InfoWindow:=New(Google.Maps.InfoWindow);
        InfoWindow.SetContent(Event.LatLng.ToUrlValue(4));
        Marker.OnClick:=
          procedure(Sender: TObject; Event: HTMLObjects.TEvent)
          begin
            InfoWindow.Open(Map,Marker); //<- hier wird das Map-Objekt aus der InitMap-Methode
                                         //sowie das Marker- und das InfoWindow-Objekt
                                         //aus der Map.OnClick-Methode verwendet
          end;
      end;
  end;
end;
Das demonstriert recht schön die Datenbindung mit Hilfe von anonymen Methoden. Schon alleine das wäre ein Grund, sich mal eine aktuelle Delphi-Version zuzulegen...

Aber auch die Variante mit Marker.Data:=InfoWindow; funktioniert bei mir ohne Probleme. Allerdings muß noch Marker.OwnsData:=false; gesetzt werden, damit es bei Löschen eines Markers beziehungsweise beim Aufräumen am Programmende zu keinen Problemen kommt.

Sollte es dann immer noch Probleme in Deinem Projekt geben, poste mal bitte den betreffenden Quelltext.

Zusatz:
Im Folgenden noch ein kleines Beispiel, wie durch anonyme Methoden gebundene Objekte in der neuen Frameworkversion verwendet und freigegen werden können. Dazu wurde das neue Event OnWrapperDestroy eingeführt:
Delphi-Quellcode:
procedure TForm1.InitMap(Sender: IObject);
var
  Map: IMap;
  MapOptions: IMapOptions;
begin
  with Sender as IScript do
  begin
    MapOptions:=New(Google.Maps.MapOptions);
    with MapOptions do
    begin
      Zoom:=10;
      Center:=New(Google.Maps.LatLng(47.651743,-122.349243));
      MapTypeID:=Google.Maps.MapTypeID.Roadmap;
    end;
    Map:=New(Google.Maps.Map(MapOptions));
    Map.OnClick:=
      procedure(Sender: IObject; Event: IMouseEvent)
      var
        Marker: IMarker;
        InfoWindow: IInfoWindow;
      begin
        InfoWindow:=New(Google.Maps.InfoWindow);
        InfoWindow.SetContent(Event.LatLng.ToUrlValue(4));
        Marker:=New(Google.Maps.Marker);
        Marker.Map:=Map;
        Marker.Position:=Event.LatLng;
        Marker.PopupMenu:=MarkerPopupMenu;
        Marker.OnClick:=
          procedure(Sender: IObject; Event: IMouseEvent)
          begin
            InfoWindow.Open(Map,Marker);
          end;
        Marker.OnContextPopup:=
          procedure(Sender: IObject; MousePos: TPoint; var Handled: Boolean)
          begin
            FActiveMarker:=Marker;
          end;
        Marker.OnWrapperDestroy:=
          procedure(Sender: IObject)
          begin
            if assigned(InfoWindow)
              then InfoWindow.Free;
          end;
      end;
  end;
end;

procedure TForm1.DeleteMarkerClick(Sender: TObject);
begin
  if assigned(FActiveMarker)
    then FActiveMarker.Free;
end;
Hier wird eine einfache Karte erstellt, bei einem Klick darauf ein neuer Marker gesetzt und mit einem Info-Fenster verbunden, das die Koordinaten des Markers anzeigt und beim Klick auf den Marker eingeblendet wird. Jedem Marker wird das selbe Popup-Menu zugeordnet, das auf den Befehl Delete den angeklickten Marker löscht und das zugeordnete Info-Fenster freigibt.

Interessant ist dabei die Freigabe eines Objektes über ein Interface (InfoWindow.Free und FActiveMarker.Free). Die Variable FActiveMarker enthält nach der Ausführung der Anweisung FActiveMarker.Free den Wert nil - Objekt- bzw. Interface-Referenzen werden also automatisch gelöscht. Ebenso wird die in den anonymen Methoden gebundene Variable InfoWindow automatisch auf nil gesetzt, falls durch die Refresh-Taste F5 oder beim Beenden des Programmes das InfoWindow-Objekt vor dem Marker freigegeben werden sollte (daher auch der notwendige Test mit assigned(), um Zugriffsverletzungen zu verhindern).
Thomas Nitzschke

Geändert von Thom (18. Apr 2012 um 01:25 Uhr) Grund: Erweitertes Beispiel
  Mit Zitat antworten Zitat
manfred_h

 
Delphi XE2 Enterprise
 
#229
  Alt 18. Apr 2012, 11:38
Hallo Thom

Danke für Deine Antwort.
Es geht jetzt. Habe bemerkt dass
Delphi-Quellcode:
      Marker.OwnsData:=false;
      Marker.Data:=InfoWindow;
erst nach MarkerOptions aufgerufen werden darf.

Delphi-Quellcode:
procedure Tfrm_map.btn_Encode_batchClick(Sender: TObject);
var
  LatLng: TLatLng;
  Lat, Lng, InfoWindow_String: String;
  InfoWindow: TInfoWindow;
  Marker: TMarker;
  MarkerData: array of TMarkerData;
  MarkerOptions: TMarkerOptions;
  MyImage, MyShadow: TMarkerImage;
  sql_count: Integer;
begin
  with Script do
  begin
    Marker:=nil; //falls keine Daten in der Tabelle vorliegen
    DM_map.Map.First;
    while not DM_map.Map.Eof do
    begin
      if DM_map.Map.FieldByName('POS_LAT').Text = 'then
        DM_map.Map.Next
      else
      Lat:=DM_map.Map.FieldByName('POS_LAT').Text;
      Lng:=DM_map.Map.FieldByName('POS_LNG').Text;
      LatLng:=New(Google.Maps.LatLng(StrToFloatDef(Lat,0,'.'),
                                   StrToFloatDef(Lng,0,'.')));
      //
      InfoWindow_String:=(
        DM_map.Map.FieldByName('AREA').AsString + '<br>'+
        DM_map.Map.FieldByName('NAME').AsString + '<br>'+
        DM_map.Map.FieldByName('STR').AsString + '<br>'+
        DM_map.Map.FieldByName('PLZ').AsString + '-'+
        DM_map.Map.FieldByName('CITY').AsString + '<br>'+'TEL:' +
        DM_map.Map.FieldByName('TEL').AsString + '<br>'+'______________________ <br>'+'Camp ' + '- '+
        DM_map.Map.FieldByName('C_NO').AsString);
      //
      InfoWindow:=New(Google.Maps.InfoWindow);
      InfoWindow.Content:=InfoWindow_String;
      // Imagesettings for this Marker
      MyImage:=New(Google.Maps.MarkerImage(MarkerURL+table_name+'.png',
        //This marker is 28 pixels wide by 35 pixels tall.
        New(Google.Maps.Size(28,35)),
        //The origin for this image is 0,0.
        New(Google.Maps.Point(0,0)),
        //The anchor for this image is the base of the flagpole at 6,20.
        New(Google.Maps.Point(6,20))));
      //
// Marker.OwnsData:=false;
// Marker.Data:=InfoWindow;
      MarkerOptions:=TMarkerOptions.Create;
      with MarkerOptions do
      begin
        Map:=Maps[0];
        Position:=LatLng;
        MarkerOptions.Title:= DM_map.Map.FieldByName('NAME').AsString;
        IconImage:=MyImage;
      end;
      Marker:=New(Google.Maps.Marker(MarkerOptions));
      Marker.OnClick:=MarkerClick;
      MarkerOptions.Free; //momentan noch etwas auf den Speicher achten
                          //-> in der neuen Version stelle ich auf Interfaces um,
                          //so daß die Freigabe automatisch erfolgt
      LatLng.Free; //gleicher Grund
      Marker.OwnsData:=false;
      Marker.Data:=InfoWindow;
      DM_map.Map.Next;
    end;
    if assigned(Marker)
      then Maps[0].SetCenter(Marker.GetPosition); //nur den letzten Marker zentrieren
  end;
end;
Besten Dank
  Mit Zitat antworten Zitat
Thom

 
Delphi XE3 Professional
 
#230
  Alt 18. Apr 2012, 12:19
Schön, daß es funktioniert!
Aber was meinst Du mit "nach MarkerOptions"? Ich würde sagen, daß die Zuweisung nach der Erstellung des Marker-Objektes mit Marker:=New(Google.Maps.Marker(MarkerOptions)); erfolgen kann, da an dieser Stelle der Marker erstellt wird und damit für Zugriffe zur Verfügung steht. Um diesen Sachverhalt etwas deutlicher zu machen, hatte ich in der Version 2 die New-Funktionen eingeführt (analog dem new-Operator in JavaScript). Sonst ist nicht sofort ersichtlich, daß mit Google.Maps.Marker(...); ein neues Objekt angelegt wird. Delphi-Programmierer sind ja eher den Syntax TMyObject.Create(...); gewohnt. Die Erstellung eines Objektes über eine Funktion entspricht eher der Logik der "Fabrikmethoden".
War die Verwendung der New-Funktionen bisher optional (sie reichen einfach den Parameter an den Result-Wert weiter), wird deren Anwendung zukünftig obligatorisch, da die "Fabrikmethoden" nicht mehr das reine Objekt, sondern nur noch einen Zwischenwert liefern, der durch die New-Methode "entpackt" wird. Der Sinn des Ganzen: Den Quelltext lesbarer zu gestalten.
Thomas Nitzschke
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

(?)

LinkBack to this Thread

Erstellt von For Type Datum
DELPHI | (google maps) This thread Refback 11. Nov 2011 10:07
Twebbrowser HTML tag to UniHTMLFrame1 - uniGUI Discussion Forums This thread Refback 4. Nov 2011 07:52
DoraDev1975: google maps This thread Refback 23. Sep 2011 09:18
delphi osm - Google Search Post #0 Refback 19. Sep 2011 10:02
DoraDev1975: ?&#3636;????? 2011 This thread Refback 11. Sep 2011 17:39
DoraDev1975 This thread Refback 30. Aug 2011 11:13
Untitled document This thread Refback 25. Jun 2011 20:57
Interact with Google Maps in a TWebBrowser from Delphi | Ramblings This thread Refback 26. Jan 2011 06:12
google maps mit delphi link - Google Search This thread Refback 24. Jan 2011 15:24
google maps mit delphi - Google Search This thread Refback 24. Jan 2011 15:20
Untitled document This thread Refback 19. Jan 2011 22:49

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 22:18 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz