Problem mit Aufruf einer Funktion in externen dll

[schlagzu]

Hallo,

ich habe eine dll (Matrix.dll, Quellcode) die nicht von mir Stammt aber auch in Delphi geschrieben ist.
Nun möchte ich diese in meinem Prog benutzten, soweit kein Problem.

Delphi-Quellcode:

function DISPLAYDLL_Init(SizeX,SizeY : byte; s : pansichar; OK : pboolean) : pansichar; external 'matrix.dll';
function DISPLAYDLL_Done:pansichar; external 'matrix.dll';
function DISPLAYDLL_Write(s:string):pansichar; external 'matrix.dll';
function DISPLAYDLL_DefaultParameters:pansichar; external 'matrix.dll';
function DISPLAYDLL_SetPosition(x,y:byte):pansichar; external 'matrix.dll';

So habe ich sie eingebunden. Ich gleube die dll wurde mit Delphi 2007 oder kleiner geschrieben, da pchar in der dll verwendet wird, aber pansichar übergeben bzw zurückgegeben wird. Die Funktion DISPLAYDLL_DefaultParameters funktioniert, sie gibt 'COM1,9600' zurück was ja stimmt. Übergebe ich dies oder 'COM4,9600' was ich brauche der DISPLAYDLL_Init Function bekomme ich den Fehler, 'MATRIX.DLL Exception: Invalid COM port name'.
Also muss es an der Übergabe des Parameters liegen. Aber was mach ich da Falsch?

Delphi-Quellcode:

procedure TForm1.Button1Click(Sender: TObject);
var ok:pboolean;
    k:pansichar;
    s:pansichar;
    st:TStringList;
begin
   k:=pansichar('COM1,9600');
   s:=DISPLAYDLL_Init(20,4,k,ok);
   showmessage(s);
   if ok^ then
   begin
   DISPLAYDLL_SetPosition(1,1);
   DISPLAYDLL_Write('Hallo Welt');
   end
   else
   showmessage('Nö');
end;

Danke im voraus!
MfG schlagzu

PS: Die dll funktioniert in einem anderer Prog problemlos!

[jaenicke]

Du hast das stdcall vergessen.

[schlagzu]

Danke, das war der Fehler, aber jetzt kommt ein weiter Problem.
Ich glaube ich mach wieder was falsch beim Aufruf, alle Funktionen laufen, nur die schreiben nicht.

Delphi-Quellcode:

function DISPLAYDLL_Init(SizeX,SizeY : byte; s : pansichar; OK : pboolean) : pansichar; stdcall;  external 'matrix.dll';
function DISPLAYDLL_Done:pansichar; stdcall;  external 'matrix.dll';
procedure DISPLAYDLL_Write(Str : pansichar); external 'matrix.dll';
function DISPLAYDLL_DefaultParameters:pansichar; stdcall;  external 'matrix.dll';
function DISPLAYDLL_SetPosition(x,y:byte):pansichar; stdcall;  external 'matrix.dll';
procedure DISPLAYDLL_SetBrightness(Brightness : byte); stdcall; external 'matrix.dll';
procedure DISPLAYDLL_SetContrast(Contrast : byte); stdcall; external 'matrix.dll';
procedure DISPLAYDLL_SetGPO(GPO : byte; GPOOn : boolean); stdcall; external 'matrix.dll';
procedure DISPLAYDLL_SetFan(T1,T2 : byte); stdcall; external 'matrix.dll';
procedure DISPLAYDLL_SetBacklight(LightOn : boolean); stdcall; external 'matrix.dll';
procedure DISPLAYDLL_CustomChar(Chr : byte; Data : TCustomArray); stdcall; external 'matrix.dll';

Delphi-Quellcode:

procedure TForm1.Button4Click(Sender: TObject);
Var s:string;
begin
  DISPLAYDLL_SetPosition(1,1);
  s:=Edit1.Text;
  DISPLAYDLL_Write(PAnsichar(s));
end;

Bitte schaut noch einmal drüber, sicher wieder nur ne Kleinigkeit.

MfG schlagzu

[jaenicke]

Du hast s als string deklariert statt als AnsiString, deshalb kannst du (da du XE benutzt) nicht einfach auf PAnsiChar casten.

[schlagzu]

Danke für die schnelle Hilfe, es tut sich dennoch nichts.
Es handelt sich bei der dll, um Schnittstelle für ein display. Den Kontrast oder die Helligkeit kann ich verstellen, nur eben schreiben will nicht funktionieren. Die dll stammt von der Software lcd smartie, ich will einfach nur eine schlankere kleine Version für mich, darum habe ich mir gedacht das ich die dll einfach verenden kann. Aber irgendwo muss ja ein Fehler sein, denn die dll funktioniert mit der Software.

Falls jemand noch ne Idee hat bitte teilt sie mir mit.

Delphi-Quellcode:

procedure TForm1.Button4Click(Sender: TObject);
var s:AnsiString;
begin
  s:='abcdefgh';
  DISPLAYDLL_Write(pansichar(s));
end;

[schlagzu]

Fehler gefunden!

Ich muss eine reihe voll machen, bevor sie angezeigt wird!

[himitsu]

Man kann das Ganze jetzt noch etwas delphitypischer anpssen.

Delphi-Quellcode:

interface

type
  MatrixDisplay = record
    const Matrix = 'matrix.dll';
    class function  Init(SizeX, SizeY: Byte; S: AnsiString; var OK: Boolean): PAnsiChar; stdcall; static;
    class function  Done: PAnsiChar; stdcall; static;
    class procedure Write(Str: AnsiString); stdcall; static;
    class function  DefaultParameters: PAnsiChar; stdcall; static;
    class function  SetPosition(x, y: Byte): PAnsiChar; stdcall; static;
    class procedure SetBrightness(Brightness: Byte); stdcall; static;
    class procedure SetContrast(Contrast: Byte); stdcall; static;
    class procedure SetGPO(GPO: Byte; GPOOn: Boolean); stdcall; static;
    class procedure SetFan(T1, T2: Byte); stdcall; static;
    class procedure SetBacklight(LightOn: Boolean); stdcall; static;
    class procedure CustomChar(Chr: Byte; Data: TCustomArray); stdcall; static;
  end;

implementation

class function  MatrixDisplay.Init;              external MatrixDisplay.Matrix name 'DISPLAYDLL_Init';
class function  MatrixDisplay.Done;              external MatrixDisplay.Matrix name 'DISPLAYDLL_Done';
class procedure MatrixDisplay.Write;             external MatrixDisplay.Matrix name 'DISPLAYDLL_Write';
class function  MatrixDisplay.DefaultParameters; external MatrixDisplay.Matrix name 'DISPLAYDLL_DefaultParameters';
class function  MatrixDisplay.SetPosition;       external MatrixDisplay.Matrix name 'DISPLAYDLL_SetPosition';
class procedure MatrixDisplay.SetBrightness;     external MatrixDisplay.Matrix name 'DISPLAYDLL_SetBrightness';
class procedure MatrixDisplay.SetContrast;       external MatrixDisplay.Matrix name 'DISPLAYDLL_SetContrast';
class procedure MatrixDisplay.SetGPO;            external MatrixDisplay.Matrix name 'DISPLAYDLL_SetGPO';
class procedure MatrixDisplay.SetFan;            external MatrixDisplay.Matrix name 'DISPLAYDLL_SetFan';
class procedure MatrixDisplay.SetBacklight;      external MatrixDisplay.Matrix name 'DISPLAYDLL_SetBacklight';
class procedure MatrixDisplay.CustomChar;        external MatrixDisplay.Matrix name 'DISPLAYDLL_CustomChar';

Und nochmal, wegen dem immernoch defekten Delphi-Tags:

Code:

interface

type
  MatrixDisplay = record
    const Matrix = 'matrix.dll';
    class function   Init(SizeX, SizeY: Byte; S: AnsiString; var OK: Boolean): PAnsiChar; stdcall; static;
    class function   Done: PAnsiChar; stdcall; static;
    class procedure Write(Str: AnsiString); stdcall; static;
    class function   DefaultParameters: PAnsiChar; stdcall; static;
    class function   SetPosition(x, y: Byte): PAnsiChar; stdcall; static;
    class procedure SetBrightness(Brightness: Byte); stdcall; static;
    class procedure SetContrast(Contrast: Byte); stdcall; static;
    class procedure SetGPO(GPO: Byte; GPOOn: Boolean); stdcall; static;
    class procedure SetFan(T1, T2: Byte); stdcall; static;
    class procedure SetBacklight(LightOn: Boolean); stdcall; static;
    class procedure CustomChar(Chr: Byte; Data: TCustomArray); stdcall; static;
  end;

implementation

class function   MatrixDisplay.Init;               external MatrixDisplay.Matrix name 'DISPLAYDLL_Init';
class function   MatrixDisplay.Done;               external MatrixDisplay.Matrix name 'DISPLAYDLL_Done';
class procedure MatrixDisplay.Write;              external MatrixDisplay.Matrix name 'DISPLAYDLL_Write';
class function   MatrixDisplay.DefaultParameters; external MatrixDisplay.Matrix name 'DISPLAYDLL_DefaultParameters';
class function   MatrixDisplay.SetPosition;        external MatrixDisplay.Matrix name 'DISPLAYDLL_SetPosition';
class procedure MatrixDisplay.SetBrightness;      external MatrixDisplay.Matrix name 'DISPLAYDLL_SetBrightness';
class procedure MatrixDisplay.SetContrast;        external MatrixDisplay.Matrix name 'DISPLAYDLL_SetContrast';
class procedure MatrixDisplay.SetGPO;             external MatrixDisplay.Matrix name 'DISPLAYDLL_SetGPO';
class procedure MatrixDisplay.SetFan;             external MatrixDisplay.Matrix name 'DISPLAYDLL_SetFan';
class procedure MatrixDisplay.SetBacklight;       external MatrixDisplay.Matrix name 'DISPLAYDLL_SetBacklight';
class procedure MatrixDisplay.CustomChar;         external MatrixDisplay.Matrix name 'DISPLAYDLL_CustomChar';

Statt record könnte man auch class
PAnsiChar als Result wird automatisch von Delphi in einen String convertiert, wenn man es an einen String zuweisen will
und der AnsiString-Parameter wird quasi auch automatisch konvertiert, denn der String-Typ ist PChar-kompatibel aufgebaut.
PBoolean ist eine Referenz auf einen Boolean, was ein Var-Parameter ebenfalls ist.


Beim Boolean mußt du aufpassen.
Wie ist der denn im Original deklariert?

Boolean, bzw. ByteBool = 1 Byte
LongBool = 4 Byte (Integer)
und das BOOL in C++ ist ein LongBool im Delphi.


Was ist denn TCustomArray?

Delphi-Quellcode:

MatrixDisplay.Init(...);

// ********

type
  MD = MatrixDisplay;

MD.Init(...);

// ********

var
  MD: MatrixDisplay;  // ist 0 Byte groß uns läßt sich sehr schön als lokale Variable nutzen (records sind toll)

MD.Init(...);