Gib deiner Threadklasse öffentliche Attribute. Dort kannst du dann beim Erzeugen die URL übergeben. Und zu Synchronize solltest du was in der Hilfe finden. Und wenn ich mich nicht irre, macht dir Delphi sogar in seinen Kommentar sogar ein Beispiel, wie man Synchronize anwendet.

Formular:

zusammenfalten · markieren

Delphi-Quellcode:

type
  TForm17 = class(TForm)
    Button1: TButton;
    Label1: TLabel;
    procedure Button1Click(Sender: TObject);
  private

  public
    procedure UpdateLabel(BytesDone: Integer);
  end;

var
  Form17: TForm17;

implementation

{$R *.dfm}

uses
  Unit18; // Thread Unit

procedure TForm17.Button1Click(Sender: TObject);
var
  HTTPThread: TIdHTTPThread;
begin
  HTTPThread := TIdHTTPThread.Create(True); // angehalten erzeugen
  HTTPThread.Url := 'http://www.xxxxxx.pdf';
  HTTPThread.Filename := 'd:\test.pdf';
  HTTPThread.FreeOnTerminate := True;
  HTTPThread.Resume; // ...und starten
end;

procedure TForm17.UpdateLabel(BytesDone: Integer);
begin
  Label1.Caption := IntToStr(BytesDone);
end;

Thread

zusammenfalten · markieren

Delphi-Quellcode:

unit Unit18;

interface

uses
  Classes, IdBaseComponent, IdComponent, IdTCPConnection, IdTCPClient, IdHTTP;

type
  TIdHTTPThread = class(TThread)
  private
    FURL: AnsiString;
    FFilename: AnsiString;
    FBytesDone: Int64;
    IdHTTP: TIdHTTP;
    procedure OnWork(ASender: TObject; AWorkMode: TWorkMode; AWorkCount: Integer);
    procedure Updatelabel;
  public
    Constructor Create(CreateSuspended: Boolean);
    Destructor Destroy; override;
    property Url: AnsiString read FURL write FUrl;
    property Filename: AnsiString read FFilename write FFilename;
  protected
    procedure Execute; override;
  end;

implementation

{ Wichtig: Methoden und Eigenschaften von Objekten in visuellen Komponenten dürfen
  nur in einer Methode namens Synchronize aufgerufen werden, z.B.

      Synchronize(UpdateCaption);

  und UpdateCaption könnte folgendermaßen aussehen:

    procedure TIdHTTPThread.UpdateCaption;
    begin
      Form1.Caption := 'Aktualisiert in einem Thread';
    end; }

{ TIdHTTPThread }

uses
  Unit17; // Formular Unit

constructor TIdHTTPThread.Create(CreateSuspended: Boolean);
begin
  inherited Create(Suspended);
  IdHTTP := TIdHTTP.Create;
  IdHTTP.OnWork := OnWork;
end;

destructor TIdHTTPThread.Destroy;
begin
  IdHTTP.Free;
  inherited;
end;

procedure TIdHTTPThread.Execute;
var
  DestStream: TFileStream;
begin
  DestStream := TFileStream.Create(Filename, fmCreate);
  try
    IdHTTP.Get(Url, DestStream);
  finally
    DestStream.Free;
  end;
end;

procedure TIdHTTPThread.OnWork(ASender: TObject; AWorkMode: TWorkMode; AWorkCount: Integer);
begin
  FBytesDone := AWorkCount;
  Synchronize(Updatelabel);
end;

procedure TIdHTTPThread.Updatelabel;
begin
  Form17.UpdateLabel(FBytesDone)
end;

end.

oh danke hab mein tool erstmal ohne threads weitergemacht
werd das entweder später noch umbauen oder aber in der nächsten
version abändern.
sollte ich also noch probleme damit haben kann das erst später kommen.

tutorials sind das eine ein funktionierender code sagt mir manchmal mehr als
nen 5 seiten tutorial, da ich damit rumtesten kann.
ist jedenfalls meine erfahrung das ich so schneller etwas verstehe.

Da man den Thread sowieso ableitet, kann man sich auch einen Constructor, mit passenden Parametern erstellen.

Ich mag Routinen mit langen Argumentenlisten nicht.

Im Prinzip sind es nur 2 Parameter, also einer mehr, als das jetzige True.

[edit]
OK, drei.

URL, Filename und das UpdateLabel, welches man vergessen und hart verlinkt hat.