AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Versuche Objektorientierung zu lernen

Ein Thema von foerster7892 · begonnen am 18. Feb 2012 · letzter Beitrag vom 19. Feb 2012
Antwort Antwort
Seite 2 von 3     12 3   
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.967 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#11

AW: Versuche Objektorientierung zu lernen

  Alt 18. Feb 2012, 21:47
Free heißt immer Free.

In Lazarus kann der Destructor und der Constructor auch anders heißen.
Und schon hast du ein Problem, mit dem Verwenden von Destroy.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#12

AW: Versuche Objektorientierung zu lernen

  Alt 18. Feb 2012, 21:49
"Btw. "free" würde ich in Ruhe lassen. Überschreibe lieber Destroy." habe ich in anderen Foren gefunden?
Dann hast du da was falsch verstanden.

Eine Instanz wird mit
Delphi-Quellcode:
Foo := TFoo.Create;
// something with Foo
Foo.Free;
ins Nirwana befördert.

Will man bei der Zerstörung der Klasse etwas spezielles ausführen, dann wir der Destructor überschrieben und der heißt nun mal Destroy .

Also man benutzt Free und überschreibt Destroy !
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#13

AW: Versuche Objektorientierung zu lernen

  Alt 18. Feb 2012, 22:03
Außerdem würde ich mich freuen wenn mir jemand nocheinmal mit eigenen Worten den Sinn von inhirated und die genaue Funktionsweise des constructors erklären könnte. (Den constructor braucht man irgendwie um Speicher für die klasse zu reservieren und sie zu erstellen, was bedeutet dies genau? Und inherited ka wird halt manchmal auch hingeschrieben und manchmal nicht...)
Jedes Objekt (TObject) hat von Haus aus einen constructor .
Dieser reserviert automatisch den Speicher.

Wenn du keine weiteren Anforderungen an dein Objekt hast, dann brauchst du auch keinen speziellen constructor .

Delphi-Quellcode:
type
  TFoo = class
    public
      procedure DoSomething;
  end;

...

procedure TFoo.DoSomething;
begin
  // some code
end;
Allerdings musst du alles, was du in der Typ-Deklaration angibst auch ausformulieren (Ausnahme bei virtual abstract )

inherited bedeutet, dass hier der Code aus der Ableitung ausgeführt werden soll.
Delphi-Quellcode:
type
  TFoo = class
    public
      InFooObject : TObject;
      constructor Create;
      destructor Destroy; override; // ist in TObject als virtual deklariert, darum override
  end;

...

constructor TFoo.Create;
begin
  inherited; // den Code der Vorgänger-Klasse - hier TObject.Create - ausführen
  
  InFooObject := TObject.Create;
end;

destructor TFoo.Destroy;
begin
  InFooObject.Free;

  inherited; // den Code aus der Vorgänger-Klasse - hier TObject.Destroy - ausführen
end;
Hier mal deine Unit2 korrekt formuliert:
Delphi-Quellcode:
unit Unit2;

{$mode objfpc}{$H+}

interface

uses
  Classes, SysUtils;

type
  TRechnen = class( TObject )
    public
      // virtual - weil diese Methode in der Regel überschrieben werden soll
      // abstract - weil es keine Basis-Implementierung gibt, eben halt abstrakt :o)
      function CalcIt( a, b : real ) : real; virtual; abstract;
  end;

  TAddition = class( TRechnen )
    public
      function CalcIt( a, b : real ) : real; override;
  end;

  TSubtraktion = class( TRechnen )
    public
      function CalcIt( a, b : real ) : real; override;
  end;

implementation

function TAddition.CalcIt( a, b : real ) : real;
  begin
    result := a + b;
  end;

function TSubtraktion.CalcIt( a, b : real ) : real;
  begin
    result := a - b;
  end;

end.
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)

Geändert von Sir Rufo (18. Feb 2012 um 22:10 Uhr)
  Mit Zitat antworten Zitat
foerster7892

Registriert seit: 10. Okt 2007
Ort: Brieskow-Finkenheerd
181 Beiträge
 
#14

AW: Versuche Objektorientierung zu lernen

  Alt 18. Feb 2012, 22:41
Wenn du keine weiteren Anforderungen an dein Objekt hast, dann brauchst du auch keinen speziellen constructor . // bedeutet? was sind "weitere Anforderungen?"

Ich zitier mich kurz mal selber, dass hatte ich vorhin noch hinzu editiert weil ich mir mit meinem Verständnis nicht sicher bin!

Zitat:
Nur nochmal zum Verständnis:
Wenn ich inherited benutze dann greife ich auf die Funktion der Mutterklasse zu also:

constructor TAddtion.create;
begin
inherited;
end;

jetzt würde ich also wenn ich:

Rechnen:=TAddition.create;
Rechnen.calcit(a,b);

und dies würde bei mir dann in der Mutterklasse landen und somit würde nichts passieren da diese ja in meinem Bsp. leer ist.

Achso und danke jetzt funzts. Aber warum trat bei constructor create Eintrag nen Fehler auf?

(sry dass ich euch gerade mit Fragen über Fragen bombardiere aber ich will dass bis Mitternacht durch haben soweit^^)
mfg
foerster7892
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#15

AW: Versuche Objektorientierung zu lernen

  Alt 18. Feb 2012, 22:57
Wenn du keine weiteren Anforderungen an dein Objekt hast, dann brauchst du auch keinen speziellen constructor . // bedeutet? was sind "weitere Anforderungen?"
Wenn du in der Klasse noch einige Voreinstellungen vornehmen möchtest.
Delphi-Quellcode:
type
  TFoo = class
  private
    FData : integer;
  public
    constructor Create;
    property Data : integer read FData write FData;
  end;

...

constructor TFoo.Create;
begin
  inherited;

  // wir benötigen diesen constructor nur, weil wir FData mit dem Wert 10 initialisieren wollen
  FData := 10;
end;
Ich zitier mich kurz mal selber, dass hatte ich vorhin noch hinzu editiert weil ich mir mit meinem Verständnis nicht sicher bin!

Zitat:
Nur nochmal zum Verständnis:
Wenn ich inherited benutze dann greife ich auf die Funktion der Mutterklasse zu also:

constructor TAddtion.create;
begin
inherited;
end;

jetzt würde ich also wenn ich:

Rechnen:=TAddition.create;
Rechnen.calcit(a,b);

und dies würde bei mir dann in der Mutterklasse landen und somit würde nichts passieren da diese ja in meinem Bsp. leer ist.
Ja, und weil in dem constructor ja nichts passieren soll, dann kann man den auch gleich weglassen

Achso und danke jetzt funzts. Aber warum trat bei constructor create Eintrag nen Fehler auf?
Weil du in der Typ-Deklaration den constructor angegeben hattest, aber diesen nicht ausformuliert hast.
Delphi-Quellcode:
type
  TFoo = class
  public
    constructor Create;
    procedure DoSomething;
  end;

...

// Das hier fehlte bei dir !!!
constructor TFoo.Create;
begin
  inherited;

end;

procedure TFoo.DoSomething;
begin
  // some code
end;
Das meinte ich mit "Alles was du in der Typ-Deklaration angibst, musst du auch ausformulieren ...

(sry dass ich euch gerade mit Fragen über Fragen bombardiere aber ich will dass bis Mitternacht durch haben soweit^^)
Hast ja noch eine gute Stunde
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Popov
(Gast)

n/a Beiträge
 
#16

AW: Versuche Objektorientierung zu lernen

  Alt 19. Feb 2012, 00:23
Noch was zu constructor und inherited usw. Wenn du zum constructor nichts beizutragen hast, dann laß ihn weg, denn jede Klasse leitet sich von der Basisklasse TObject und erbt schon mal den constructor. Den hast du also schon. Dein

Delphi-Quellcode:
constructor TFoo.Create;
begin
  inherited;
end;
schadet zwar nicht, bringt aber auch nichts. Nötig wird es erst wenn du etwas dazu schreibst.

Nun zum inherited. So manches Mal stellt man sich die Frage ob er nötig ist, denn es gibt oft keinen Unterschied wenn man den wegläßt. Jetzt nicht hauen wenn es nicht stimmt, ist schon lange her wo ich es nach geguckt habe, aber bei Klassen auf der untersten Ebene ist nichts da was inherited aufrufen könnte. Deshalb könnte man sich die Frage stellen wozu der nötig ist. Nötig ist es spätestens da wenn man seine Klasse von einer anderen ableitet und die schon etwas in Create stehen hat. Dann, ohne inherited, wird der Part übergangen und die Klasse funktioniert nicht. Also am besten immer nutzen, ob nötig oder nicht. Dann geht es einem ins Blut über und man vergisst es nicht.
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.967 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#17

AW: Versuche Objektorientierung zu lernen

  Alt 19. Feb 2012, 00:30
Nicht Schaden?
Das inherited hat einen ganz bestimmten Grund, denn damit wird gesagt "führe die Methode des Vorfahren aus".

Wenn man etwas überschreibt, dann hat das meistens einen Grund.
Oftmals möchte man zusäztliche Dinge machen, wobei das "zusätzlich" bedeutet, daß man das Alte auch haben will.
Im Falle des Constructors, möchte man natürlich, daß die Teile der Vorfahren ebenfalls ordentlich initialisiert werden.

PS: Es kann nicht schaden, wenn man das Inherited schreibt, auch wenn es keinen Vorfahren gibt ... dann läßt es der Compiler einfach weg.
Es schadet aber oftmals, wenn man es vergißt, wenn es nötig wäre.

Tipp: leite dir mal ein TMemo ab, überschreib den Constructor und vergiß das Inherited.
Jetzt will ich mal sehn, wie du dich fragst "Wo ist mein Memo, ich seh ja garnichts?" und beim ersten Zugriff auf .Lines hoff' ich, du freust dich über die Exception.

Ja, bei TObject fällt es nicht auf, da dort aktuell nur ein leerer Constructor vorhanden ist, aber wer weiß, ob da in Zukunft nicht doch mal irgendwas darin ist.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014

Geändert von himitsu (19. Feb 2012 um 00:34 Uhr)
  Mit Zitat antworten Zitat
Popov
(Gast)

n/a Beiträge
 
#18

AW: Versuche Objektorientierung zu lernen

  Alt 19. Feb 2012, 02:25
Mir ist gerade ein nettes Beispiel eingefallen, ich hoffe es ist gut.

Es zeigt, wie ich hoffe, gut wozu der constructor, aber vor allem inherited gut ist. Ich habe eine Klasse von TStringList abgeleitet und im constructor Create mit Wochentagen gefüllt. Wenn ich nun in der Prozedur Button1Click das Objekt erstelle und gleich mit ShowMessage anzeigen lasse, ist die Liste bereits mit Daten gefüllt.

Ansonsten ist das eine normale StringList, ich kann also den Inhalt löschen oder bearbeiten. Aber als Unterschied zu StringList hatte sie am Anfang Daten drin.

Nun mal ein kleines Experiment: mal in TWochenTageListe.Create inherited auskommentieren.

Was sehen wir? Eigentlich keinen Unterschied(²). In beiden Fällen wird beim Klick auf Button1 eine Liste ausgegeben.

Ok, inherited wieder einsetzten und zum zweiten Beispiel unten gehen.

Delphi-Quellcode:
// --------- Eine Liste mit Wochentagen für Deutschland ----------------
// ----------------- Abgeleitet von TStringList ------------------------
type
  TWochenTageListe = class(TStringList)
    constructor Create;
  end;

constructor TWochenTageListe.Create;
begin
  inherited; // teste die Klasse mit inherited und ohne
  Add('Montag');
  Add('Dienstag');
  Add('Mittwoch');
  Add('Donnerstag');
  Add('Freitag');
  Add('Samstag');
  Add('Sonntag');
end;

procedure TForm1.Button1Click(Sender: TObject);
var
  slWochenTage: TWochenTageListe;
begin
  slWochenTage := TWochenTageListe.Create;
  try
    ShowMessage(slWochenTage.Text);
  finally
    slWochenTage.Free;
  end;
end;
Das oben war eine Liste für Deutschland. In Bayern sagt man aber nicht Samstag, sondern Sonnabend. Wir erstellen nun eine extra Klasse für die Bayern, aber keine neue Liste, sondern leiten die WochenTageListe für Bayern aus der WochenTageListe für Deutschland ab und ändern lediglich den Samstag in Sonnabend. Da wir die Klasse ableiten, erben wir die Liste, allerdings nur wenn wir inherited aufrufen.

Wieder ein kleines Experiment: mal in TBayernWochenTageListe.Create inherited auskommentieren.

Was sehen wir? Nichts! Wenn wir auf Button2 klicken, ist die Liste leer. Nicht mal Sonnabend steht drin. Mit inherited wird die Wochentage Liste geerbt, ohne nicht.

Delphi-Quellcode:
// ----------- Eine Liste mit Wochentagen für Bayern -------------------
// --------------- Abgeleitet von TWochenTageListe----------------------
type
  TBayernWochenTageListe = class(TWochenTageListe)
    constructor Create;
  end;

constructor TBayernWochenTageListe.Create;
var
  i: Integer;
begin
  inherited; // teste die Klasse mit inherited und ohne
  for i := 0 to Count - 1 do
    if Self[i] = 'Samstagthen Self[i] := 'Sonnabend';
end;

procedure TForm1.Button2Click(Sender: TObject);
var
  slWochenTage: TBayernWochenTageListe;
begin
  slWochenTage := TBayernWochenTageListe.Create;
  try
    ShowMessage(slWochenTage.Text);
  finally
    slWochenTage.Free;
  end;
end;
Und noch ein letztes Experiment: wir setzen inherited nicht wie es soll am Anfang des constructors, sondern am Ende der Prozedur.

Was sehen wir? Eine Liste, aber kein Sonnabend, sondern Samstag. Als in der Schleife nach Samstag gesucht wurde, war die Liste noch nicht da.

Delphi-Quellcode:
constructor TBayernWochenTageListe.Create;
var
  i: Integer;
begin
  //inherited; //Auskommentiert
  for i := 0 to Count - 1 do
    if Self[i] = 'Samstagthen Self[i] := 'Sonnabend';

  inherited; // inherited am Ende
end;

² - Damit meine ich keinen sichtbaren Unterschied in Bezug auf das Experiment.

Geändert von Popov (19. Feb 2012 um 02:42 Uhr)
  Mit Zitat antworten Zitat
foerster7892

Registriert seit: 10. Okt 2007
Ort: Brieskow-Finkenheerd
181 Beiträge
 
#19

AW: Versuche Objektorientierung zu lernen

  Alt 19. Feb 2012, 14:51
Vielen Dank an alle hat mir unglaublich geholfen.



PS.: Das Beispiel war super!

mfg
foerster7892
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
34.967 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#20

AW: Versuche Objektorientierung zu lernen

  Alt 19. Feb 2012, 16:17
Wobei man noch froh sein kann, daß beim Zugriff auf "Count" keine Exception auftrat, denn schließlich war zu diesem Zeitpunkt die Stingliste noch nicht initialisiert.
Daß keine Exception auftrat, liegt am Inneren der Count-Funktion, wo glücklicher Weise auf nichts "Schlimmes"/Kompliziertes zugegriffen wird.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
Delphi-Tage 2005-2014

Geändert von himitsu (19. Feb 2012 um 16:19 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 22:30 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf