AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi CreateFile & DeviceIOControl Problem mit 64Bit

CreateFile & DeviceIOControl Problem mit 64Bit

Ein Thema von RWarnecke · begonnen am 26. Feb 2012 · letzter Beitrag vom 26. Feb 2012
Antwort Antwort
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.406 Beiträge
 
Delphi XE8 Enterprise
 
#1

CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 10:27
Hallo zusammen,

ich habe folgende Funktion für 32Bit-Programme bis jetzt immer erfolgreich genutzt. Wenn ich die gleiche Funktion für 64Bit kompiliere und ausführe gibt der erste DeviceIOControl-Befehl immer False zurück.
Delphi-Quellcode:
type
  SCSIPASSTHROUGH = record
    spt_Length : Word;
    spt_ScsiStatus : Byte;
    spt_PathId : Byte;
    spt_TargetId : Byte;
    spt_Lun : Byte;
    spt_CdbLength : Byte;
    spt_SenseInfoLength : Byte;
    spt_DataIn : Byte;
    spt_DataTransferLength : ULong;
    spt_TimeOutValue : ULong;
    spt_DataBufferOffset : DWord;
    spt_SenseInfoOffset : ULong;
    spt_Cdb : array[0..15] of Byte;
  end;

  SCSI_PASS_THROUGH_DIRECT_WITH_BUFFER = record
    spt : SCSI_PASS_THROUGH_DIRECT;
    Filler : ULONG;
    ucSenseBuf : array[0..32 - 1] of Byte;
  end;
  PSCSI_PASS_THROUGH_DIRECT_WITH_BUFFER = ^SCSI_PASS_THROUGH_DIRECT_WITH_BUFFER;

  SCSI_ADDRESS = record
    Length : LongInt;
    PortNumber : Byte;
    PathId : Byte;
    TargetId : Byte;
    Lun : Byte;
  end;
  PSCSI_ADDRESS = ^SCSI_ADDRESS;

const
  SCSI_IOCTL_DATA_IN = 1;
  IOCTL_SCSI_PASS_THROUGH_DIRECT = $4D014;
  IOCTL_SCSI_GET_ADDRESS = $41018;

{...}

procedure TCDDVDInfo.GetCDDVDDriveInfos;
var
  I, returned : Integer;
  FileHandle : THandle;
  buffer : array[0..1023] of AnsiChar;
  inqData : array[0..99] of AnsiChar;
  pswb : PSCSI_PASS_THROUGH_DIRECT_WITH_BUFFER;
  pscsiAddr : PSCSI_ADDRESS;
  DriveString : PAnsiChar;
  sptdwblength : Integer;
  CDDVDDrive : string;
begin
  for I := 0 to FCDDVDCount - 1 do
  begin
    setlength(FVendor, i + 1);
    setlength(FProductId, i + 1);
    setlength(FRevision, i + 1);
    setlength(FVendorSpec, i + 1);
    setlength(FModellName, i + 1);
    setlength(FHaId, i + 1);
    setlength(FTarget, i + 1);
    setlength(FLun, i + 1);
    CDDVDDrive := '\\.\' + string(FDriveLetter[i]) + ':';
    FileHandle := CreateFile(pointer(CDDVDDrive),
                     GENERIC_READ or GENERIC_WRITE,
                     FILE_SHARE_READ or FILE_SHARE_WRITE,
                     nil,
                     OPEN_EXISTING,
                     FILE_ATTRIBUTE_NORMAL,
                     0);
    if FileHandle <> INVALID_HANDLE_VALUE then
    begin
      ZeroMemory(@buffer, 1024);
      ZeroMemory(@inqData, 100);
      pswb := PSCSI_PASS_THROUGH_DIRECT_WITH_BUFFER(@buffer);
      pswb^.spt.Length := sizeof(SCSIPASSTHROUGH);
      pswb^.spt.CdbLength := 6;
      pswb^.spt.SenseInfoLength := 24;
      pswb^.spt.DataIn := SCSI_IOCTL_DATA_IN;
      pswb^.spt.DataTransferLength := 100;
      pswb^.spt.TimeOutValue := 2;
      pswb^.spt.DataBuffer := @inqData;
      pswb^.spt.SenseInfoOffset := sizeof(pswb^.spt) + sizeof(pswb^.Filler);
      pswb^.spt.Cdb[0] := $12;
      pswb^.spt.Cdb[4] := $64;
      sptdwblength := sizeof(SCSI_PASS_THROUGH_DIRECT_WITH_BUFFER);
      if DeviceIoControl(FileHandle, IOCTL_SCSI_PASS_THROUGH_DIRECT,
            pswb, sptdwblength, pswb, sptdwblength,
            Cardinal(returned), nil) then
      begin
        DriveString := @inqData[0];
        Inc(DriveString, 8);
        FVendor[i] := Copy(DriveString, 1, 8);
        FProductId[i] := Copy(DriveString, 8 + 1, 16);
        FRevision[i] := Copy(DriveString, 24 + 1, 4);
        FVendorSpec[i] := Copy(DriveString, 28 + 1, 20);
        FModellName[i] := FVendor[i] + FProductId[i] + FRevision[i];
        ZeroMemory( @buffer, 1024 );
        pscsiAddr := PSCSI_ADDRESS( @buffer );
        pscsiAddr^.Length := sizeof( SCSI_ADDRESS );
        if ( DeviceIoControl( FileHandle, IOCTL_SCSI_GET_ADDRESS, nil, 0,
          pscsiAddr, sizeof( SCSI_ADDRESS ), Cardinal( returned ),
          nil ) ) then
        begin
          FHaId[i] := pscsiAddr^.PortNumber;
          FTarget[i] := pscsiAddr^.TargetId;
          FLun[i] := pscsiAddr^.Lun;
        end;
        CloseHandle(FileHandle);
      end;
    end;
  end; // FOR-Schleife Anzahl der CD-ROM/DVD Laufwerke
end;
Ich verstehe nur nicht, warum DeviceIoControl für eine 64Bit Anwendung hier False zurückgibt. Warum passiert das und wie kann ich den Teil ändern, dass es für eine 32Bit und eine 64Bit Anwendung funktioniert ?
Rolf Warnecke
EasyNetSoft
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.616 Beiträge
 
Delphi 2006 Professional
 
#2

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 10:35
Und was sagt GetLastError?
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.406 Beiträge
 
Delphi XE8 Enterprise
 
#3

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 10:52
Das gibt GetLastError zurück:
Zitat:
ERROR_REVISION_MISMATCH
1306 (0x51A)
Rolf Warnecke
EasyNetSoft
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.616 Beiträge
 
Delphi 2006 Professional
 
#4

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 10:58
Und Klartext auf deutsch: "Dies zeigt an, dass zwei Revisionsstufen nicht kompatibel sind."
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.406 Beiträge
 
Delphi XE8 Enterprise
 
#5

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 11:04
Ja, aber wo ? Da die gleiche Funktion in einem 32Bit Programm wunderbar funktioniert. Anscheinend sehe ich den Wald vor lauter Bäumen mal wieder nicht.
Rolf Warnecke
EasyNetSoft
  Mit Zitat antworten Zitat
Benutzerbild von JamesTKirk
JamesTKirk

Registriert seit: 9. Sep 2004
Ort: Eberfing
597 Beiträge
 
FreePascal / Lazarus
 
#6

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 11:33
Laut MSDN ist spt_DataBufferOffset ein PVOID und kein DWord . Das könnte deine Unterschiede erklären.

Gruß,
Sven
Sven
[Free Pascal Entwickler]
this post is printed on 100% recycled electrons
  Mit Zitat antworten Zitat
Benutzerbild von RWarnecke
RWarnecke

Registriert seit: 31. Dez 2004
Ort: Stuttgart
4.406 Beiträge
 
Delphi XE8 Enterprise
 
#7

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 11:50
Hallo Sven,

danke für Deine Antwort und Deine schnelle Hilfe.
Laut MSDN ist spt_DataBufferOffset ein PVOID und kein DWord . Das könnte deine Unterschiede erklären.
Mit der Änderung an spt_DataBufferOffset funktioniert es jetzt einwandfrei. Ich werde in dieser Unit nochmal alle Deklarationen überprüfen. Ich glaube, ich hatte damals das als DWord deklariert, da es unter Delphi 2007 keine Deklaration für PVOID gab.
Rolf Warnecke
EasyNetSoft
  Mit Zitat antworten Zitat
Benutzerbild von JamesTKirk
JamesTKirk

Registriert seit: 9. Sep 2004
Ort: Eberfing
597 Beiträge
 
FreePascal / Lazarus
 
#8

AW: CreateFile & DeviceIOControl Problem mit 64Bit

  Alt 26. Feb 2012, 12:16
Hallo Sven,

danke für Deine Antwort und Deine schnelle Hilfe.
Laut MSDN ist spt_DataBufferOffset ein PVOID und kein DWord . Das könnte deine Unterschiede erklären.
Mit der Änderung an spt_DataBufferOffset funktioniert es jetzt einwandfrei. Ich werde in dieser Unit nochmal alle Deklarationen überprüfen. Ich glaube, ich hatte damals das als DWord deklariert, da es unter Delphi 2007 keine Deklaration für PVOID gab.
PVOID steht normalerweise über die Unit Windows zur Verfügung... ich kann ja gern morgen in der Arbeit mal schauen, da verwenden wir auch Delphi 2007.

Ansonsten ist PVOID ja nichts anderes als Pointer

Gruß,
Sven
Sven
[Free Pascal Entwickler]
this post is printed on 100% recycled electrons
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 16:01 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf