AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Algorithmen, Datenstrukturen und Klassendesign Delphi Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

Ein Thema von ThorZten · begonnen am 10. Mär 2012 · letzter Beitrag vom 10. Mär 2012
Antwort Antwort
Seite 1 von 2  1 2   
ThorZten
(Gast)

n/a Beiträge
 
#1

Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 01:35
Guten Morgen!
Ich suche nach einer Lösung, wie ich am Einfachsten die folgende Datenstruktur speichern kann. Darin befinden sich ein dynamisches Array, ein statisches Array und zudem noch ein Record. Gefunden habe ich dazu Lösungen, wie man ein dynamisches und ein statisches Array separat speichert, aber nicht die Kombination aus beiden.

Meine Frage:
Wie kann ich die folgende Struktur in einer Datei speichern und wieder auslesen?
Soll ich lieber komplett auf das statische Array verzichten? Würde es das erleichtern? Ich hatte erst versucht, beide Arrays in zwei verschiedenen Dateien zu speichern, aber schöner wäre es, die Struktur nicht auseinander zu ziehen.

Code:
type
  TGewichte = record
      iDatum : TDateTime;
      iGewicht: double;
    end;

  TPerson = record
    name     : String[10];
    geschlecht: (m,w);
    groesse  : Integer;
    gewichte : array of TGewichte;   // dynamisches Array
  end;

var
  Person: array [1..4] of TPerson;   // statisches Array

Vielen Dank schon einmal für Eure Anregungen!

Beste Grüße,
Thorsten
  Mit Zitat antworten Zitat
Medium

Registriert seit: 23. Jan 2008
3.673 Beiträge
 
Delphi 2007 Enterprise
 
#2

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 01:45
Das schreit mehr nach einer Datenbank (ggf. embedded), oder zumindest XML.
"When one person suffers from a delusion, it is called insanity. When a million people suffer from a delusion, it is called religion." (Richard Dawkins)
  Mit Zitat antworten Zitat
Keldorn

Registriert seit: 6. Mär 2003
Ort: Meißen
876 Beiträge
 
Delphi 10.1 Berlin Professional
 
#3

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 08:12
Hallo,

persönlich würd ich mich für einen Stream und Twriter und Treader entscheiden
so als idee:
Delphi-Quellcode:
Var stream:Tstream;
    writer:Twriter;
    ip,ig:integer;
begin
  Stream:=TFilestream.create(Dateiname,fmcreate);
  try
    writer:=TWriter.Create(stream,4096);
    try
      Writer.WriteInteger(aktuelleVersion);
      //erstmal ne "Version reinschreiben, hier kannst du dann später beim auslesen darauf reagieren
      // (z.B. weil du ab Version5 10 statt 4 Personen hast)
      for ip:=1 to 4 do
        begin
          Writer.WriteStr(Person[ip].name);
          Writer.WriteInteger(Integer(Person[ip].Geschlecht));
          Writer.WriteInteger(Person[ip].groesse);

          //Länge des Arrays reinschreiben
          Writer.WriteInteger(length(Person[ip].gewichte));
          //und nun die einzelnen Gewichte
          for ig:=Low(Person[ip].gewichte) to High(Person[ip].gewichte) do
            begin
              Writer.WriteDate(Person[ip].gewichte[ig].iDatum);
              Writer.WriteDouble(Person[ip].gewichte[ig].iGewicht);
            end;
        end;
    finally
      writer.Free;
    end;
  finally
    Stream.free;
  end;
end;
Das kannst du dir immer noch weiter in einzelne Procs zu besseren Lesbarkeit aufteilen.
Persönlich würde ich aber auch person als dynamisches Array anlegen und statisches und dynamisches nicht mischen.

Auslesen dann genaus andersrum mit Treader und readXYZ.

Gruß Frank

Lükes Grundlage der Programmierung:
Es wird nicht funktionieren
(Murphy)
  Mit Zitat antworten Zitat
Benutzerbild von Bummi
Bummi

Registriert seit: 15. Jun 2010
Ort: Augsburg Bayern Süddeutschland
3.470 Beiträge
 
Delphi XE3 Enterprise
 
#4

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 08:35
wenn Du Dich für Stream statt Datenbank/XML entscheiden solltest, im obigen Beispiel fehlt noch die Anzahl der Personen.
Thomas Wassermann H₂♂
Das Problem steckt meistens zwischen den Ohren
DRY DRY KISS
H₂ (wenn bei meinen Snipplets nichts anderes angegeben ist Lizenz: WTFPL)
  Mit Zitat antworten Zitat
Keldorn

Registriert seit: 6. Mär 2003
Ort: Meißen
876 Beiträge
 
Delphi 10.1 Berlin Professional
 
#5

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 08:38
wenn Du Dich für Stream statt Datenbank/XML entscheiden solltest, im obigen Beispiel fehlt noch die Anzahl der Personen.
er hats ja statisch deklariert, also
for ip:=1 to 4 do

Lükes Grundlage der Programmierung:
Es wird nicht funktionieren
(Murphy)
  Mit Zitat antworten Zitat
Benutzerbild von Bummi
Bummi

Registriert seit: 15. Jun 2010
Ort: Augsburg Bayern Süddeutschland
3.470 Beiträge
 
Delphi XE3 Enterprise
 
#6

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 08:39
@Keldorn

sorry, ich war blind
Thomas Wassermann H₂♂
Das Problem steckt meistens zwischen den Ohren
DRY DRY KISS
H₂ (wenn bei meinen Snipplets nichts anderes angegeben ist Lizenz: WTFPL)
  Mit Zitat antworten Zitat
Keldorn

Registriert seit: 6. Mär 2003
Ort: Meißen
876 Beiträge
 
Delphi 10.1 Berlin Professional
 
#7

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 08:42
macht nix, ich hatte ja schon selber Panik, was ich dem BSP zur frühen Morgenstunde vergessen haben könnte

Lükes Grundlage der Programmierung:
Es wird nicht funktionieren
(Murphy)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
40.480 Beiträge
 
Delphi 11 Alexandria
 
#8

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 10:37
wenn Du Dich für Stream statt Datenbank/XML entscheiden solltest, im obigen Beispiel fehlt noch die Anzahl der Personen.
Kommt drauf an, entweder ein eine Längenangabe davor, so wie man es mit der Längenangabe des Delphi-String sieht.
Oder es als Liste markieren/umfassen, mit ListBegin und ListEnd.
Oder einfach nur mit ListEnd das Ende der Liste markieren, so wie man es mit der #0 beim PChar macht.

Bei dem Stream würde ich es also noch mit Blöcken versehn, dann braucht man halt nicht die Anzahl der Personen, da man auf das Ende des Personen-Blocks prüfen kann.

PS: Dann ist es sogar möglich die Datei ohne jegliche Kenntnis des Formats auszulesen, so wie es bei einer XML auch möglich ist.
Wenn man es also ordentlich ausbaut, dann ergibt das quasi eine Art binäre XML-Datei, nur ohne Attribute.

[DELPHI]var stream: TStream;
writer: TWriter;
ip, ig: Integer;
begin
Stream := TFilestream.create(Dateiname,fmcreate);
try
Writer := TWriter.Create(Stream, 4096);
try
Writer.WriteInteger(aktuelleVersion);
for ip := Low(Person) to High(Person) do begin
Writer.WriteString(Person[ip].name);
Writer.WriteInteger(Integer(Person[ip].Geschlecht));
Writer.WriteInteger(Person[ip].groesse);
Writer.WriteListBegin;
for ig := Low(Person[ip].gewichte) to High(Person[ip].gewichte) do begin
Writer.WriteDate(Person[ip].gewichte[ig].iDatum);
Writer.WriteDou
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list

Geändert von himitsu (10. Mär 2012 um 10:52 Uhr)
  Mit Zitat antworten Zitat
ThorZten
(Gast)

n/a Beiträge
 
#9

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 11:37
Guten Morgen noch einmal.

Erst einmal vielen Dank für die zahlreichen Antworten!
Ich muss das Geschriebene jetzt erst einmal verarbeiten. Danke!
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
40.480 Beiträge
 
Delphi 11 Alexandria
 
#10

AW: Speichern einer Kombination aus dynamischen Arrays, statischem Array und Record

  Alt 10. Mär 2012, 16:45
Hmm, irgendwie ist da was schiefgegangen.

So, daß hier hatte ich noch im Zwischenspeicher. (k.A. was ich daran noch geändert hatte)
Delphi-Quellcode:
var stream: TStream;
    writer: TWriter;
    ip, ig: Integer;
begin
  Stream := TFilestream.create(Dateiname,fmcreate);
  try
    Writer := TWriter.Create(Stream, 4096);
    try
      Writer.WriteInteger(aktuelleVersion);
      for ip := Low(Person) to High(Person) do begin
        Writer.WriteString(Person[ip].name);
        Writer.WriteInteger(Integer(Person[ip].Geschlecht));
        Writer.WriteInteger(Person[ip].groesse);
        Writer.WriteListBegin;
        for ig := Low(Person[ip].gewichte) to High(Person[ip].gewichte) do begin
          Writer.WriteDate(Person[ip].gewichte[ig].iDatum);
          Writer.WriteDouble(Person[ip].gewichte[ig].iGewicht);
        end;
        Writer.WriteListEnd;
      end;
    finally
      writer.Free;
    end;
  finally
    Stream.Free;
  end;
end;
Delphi-Quellcode:
        Writer.WriteListBegin;
        for ig := Low(Person[ip].gewichte) to High(Person[ip].gewichte) do begin
          Writer.WriteDate(Person[ip].gewichte[ig].iDatum);
          Writer.WriteDouble(Person[ip].gewichte[ig].iGewicht);
        end;
        Writer.WriteListEnd;

        Reader.ReadListBegin;
        ig := Low(Person[ip].gewichte);
        while Reader.NextValue <> vaNull do begin
          Writer.WriteDate(Person[ip].gewichte[ig].iDatum);
          Writer.WriteDouble(Person[ip].gewichte[ig].iGewicht);
          Inc(ig);
        end;
        Reader.ReadListEnd;
Und letztendlich kann man es auch noch so wie die VCL machen und die Bezeichner gleich mit Dokumentieren.
Delphi-Quellcode:
var stream: TStream;
    writer: TWriter;
    ip, ig: Integer;
begin
  Stream := TFilestream.create(Dateiname,fmcreate);
  try
    Writer := TWriter.Create(Stream, 4096);
    try
      Writer.WriteSignature
      Writer.WriteIdent('FileType');
        Writer.WriteUTF8Str('ThorZten.Personenliste');
      Writer.WriteIdent('Version');
        Writer.WriteInteger(aktuelleVersion);
      Writer.WriteIdent('Personen');
        Writer.WriteListBegin;
          for ip := Low(Person) to High(Person) do begin
            Writer.WriteListBegin;
              Writer.WriteIdent('Name');
                Writer.WriteUTF8Str(Person[ip].name);
              Writer.WriteIdent('Geschlecht');
                Writer.WriteInteger(Ord(Person[ip].geschlecht));
              Writer.WriteIdent('Größe');
                Writer.WriteInteger(Person[ip].groesse);
              Writer.WriteIdent('Gewichte');
                Writer.WriteListBegin;
                  for ig := Low(Person[ip].gewichte) to High(Person[ip].gewichte) do begin
                    Writer.WriteListBegin;
                      Writer.WriteIdent('Datum');
                        Writer.WriteDate(Person[ip].gewichte[ig].iDatum);
                      Writer.WriteIdent('Gewicht');
                        Writer.WriteDouble(Person[ip].gewichte[ig].iGewicht);
                    Writer.WriteListEnd;
                  end;
                Writer.WriteListEnd;
            Writer.WriteListEnd;
          end;
        Writer.WriteListEnd;
    finally
      writer.Free;
    end;
  finally
    Stream.Free;
  end;
end;
Und schon könnte man die Datei auch auslesen, selbst wenn man das Format nicht kennt.
Beim Einlesen kann man quasi Versionsabhänig den richtigen Wert auslesen, da sich über den Ident prüfen läßt, welcher Wert das genau ist.
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 07:35 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf