FormularArray den richtigen Create aufrufen! Wie?

[Bummi]

Delphi-Quellcode:

uses unit4,unit5;
{$R *.dfm}


type
  TShowForm = Reference to Function(Owner : TComponent):TForm;
const
  FC: Array [1..2] of TFormClass=(Tform4,Tform5);
var
  F : Array [1..2] of TShowForm;




procedure TForm3.Button1Click(Sender: TObject);
var
 s:TShowForm;
begin
    s := F[2];
    s(self).Show;
end;

procedure TForm3.FormCreate(Sender: TObject);
begin
F[1] :=    Function(Owner:TComponent):TForm
              begin
              Result := FC[1].Create(Owner);
              end;
F[2] :=    Function(Owner:TComponent):TForm
              begin
              Result := FC[2].Create(Owner);
              end

end;

[Sir Rufo]

@Jumpy

Warum nicht RegisterClass bzw. RegisterClassAlias und FindClass?

[Jumpy]

Zitat von Sir Rufo:

@Jumpy
Warum nicht RegisterClass bzw. RegisterClassAlias und FindClass?

Was man nicht kennt, kann man nicht benutzen

Und weil es bei einem Problem meist schnell gehen muss, nimmt man die erst beste Idee, die man zur Lösung finden kann, auch wenn's bei weiterer Suche oder mehr Erfahrung vllt. einfacheres oder schöneres gegeben hätte.

Hab die Hilfe dazu grad nur mal überflogen und gesehen, dass es das in D6 ja auch schon gibt, muss mir das aber auch nochmal in Ruhe angucken, genau wie das Beispiel in #11, wo mir noch nicht ganz klar ist, was das macht. Sieht aber auf jeden Fall interessant aus.

Zu RegisterClass und FindClass:
Verstehe ich das so, dass ich damit die Konstruktion mit dem Record und dem Array nicht brauchen würde? Aber wo/wie benutzt man dann RegisterClass? Sprich, das muss doch wahrscheinlich für jede Klasse einmal aufgerufen werden, oder? Im Constructor der Factory?

[Sir Rufo]

Zitat von Jumpy:

Zu RegisterClass und FindClass:
Verstehe ich das so, dass ich damit die Konstruktion mit dem Record und dem Array nicht brauchen würde? Aber wo/wie benutzt man dann RegisterClass? Sprich, das muss doch wahrscheinlich für jede Klasse einmal aufgerufen werden, oder? Im Constructor der Factory?

Das RegisterClass kommt am Besten in den initialization Abschnitt, wo diese Klasse auch definiert wurde.

Das FindClass kann dann irgendwo aufgerufen werden.

Dadurch kann man z.B. der MainForm Zugriff auf alle vorhandenen Formular-Klassen ermöglichen ohne die ganzen Formular-Units dort einzubinden.

Ich baue mal ein kleines Beispiel zusammen ... stay tuned

[Jumpy]

Zitat von Sir Rufo:

Dadurch kann man z.B. der MainForm Zugriff auf alle vorhandenen Formular-Klassen ermöglichen ohne die ganzen Formular-Units dort einzubinden.

Irgendwas entgeht mir hier, denn wenn ich die nicht irgendwo einbinde, wird doch initialization nie durchlaufen?

Zitat von Sir Rufo:

Ich baue mal ein kleines Beispiel zusammen ... stay tuned

Da hab ich heut Abend ja einen Grund nochmal hier reinzugucken.

[Sir Rufo]

Zitat von Jumpy:

Zitat von Sir Rufo:

Dadurch kann man z.B. der MainForm Zugriff auf alle vorhandenen Formular-Klassen ermöglichen ohne die ganzen Formular-Units dort einzubinden.

Irgendwas entgeht mir hier, denn wenn ich die nicht irgendwo einbinde, wird doch initialization nie durchlaufen?

Formulare müssen eh irgendwo im Projekt (.dpr ) eingebunden sein, aber wenn die Klassen registriert sind, dann brauchen diese Units nirgendwo anders mit eingebunden werden.

Zitat von Jumpy:

Zitat von Sir Rufo:

Ich baue mal ein kleines Beispiel zusammen ... stay tuned

Da hab ich heut Abend ja einen Grund nochmal hier reinzugucken.

Jo, fertig ...

Hier der Code der MainForm

Delphi-Quellcode:

unit FormMain;

interface

uses
  Windows, Messages,
  SysUtils, Variants, Classes,
  Graphics, Controls, Forms, Dialogs, ExtCtrls, StdCtrls;

type
  TMainForm = class( TForm )
    FormNames_ListBox : TListBox;
    Form_Panel : TPanel;
    procedure FormNames_ListBoxClick( Sender : TObject );
  private
    FForm : TForm;
    procedure CreateFormFromName( const FormName : string; Parent : TWinControl );
  public
    { Public-Deklarationen }
  end;

var
  MainForm : TMainForm;

implementation

{$R *.dfm}

procedure TMainForm.CreateFormFromName( const FormName : string; Parent : TWinControl );
var
  LClass : TPersistentClass;
begin
  if Assigned( FForm ) then
  begin
    FForm.Release;
    FForm := nil;
  end;

  // Wirft eine Exception, wenn die Klasse nicht gefunden wird
  // LClass := FindClass( FormName );

  // Liefert einfach nur nil, wenn die Klasse nicht gefunden wird
  LClass := GetClass( FormName );
  if Assigned( LClass ) and LClass.InheritsFrom( TForm ) then
  begin
    // Form-Instanz erzeugen
    FForm := TFormClass( LClass ).Create( Self );
    // Ein bisschen Zucker drüber
    FForm.Parent := Parent;
    FForm.BorderStyle := bsNone;
    FForm.Align := alClient;
    // fertig
    FForm.Show;
  end;
end;

procedure TMainForm.FormNames_ListBoxClick( Sender : TObject );
begin
  CreateFormFromName( ( Sender as TListBox ).Items[( Sender as TListBox ).ItemIndex], Form_Panel );
end;

initialization

// In der Regel eigentlich nicht, aber hier ist es lustig :o)
RegisterClass( TMainForm );

end.

[himitsu]

Zitat von Sir Rufo:

Formulare müssen eh irgendwo im Projekt (.dpr ) eingebunden sein, aber wenn die Klassen registriert sind, dann brauchen diese Units nirgendwo anders mit eingebunden werden.

Da sind wir auch schon drauf reingefallen.

Eine Unit war in der DPR für eine BPL eingebunden, aber da diese Unit sonst in keiner anderen Unit aufgerufen wurde und auch nichts "direkt" aus der Unit verwendet wurde...
Es sollte da auch nur etwas registriert werden.
- In einer EXE einkompilert funktioniert es.
- In einer BPL einkompiliert wurde diese Unit nicht initialisiert. Das passerte erst, nachdem die Unit explizit in einer anderen Unit eingebunden wurde.

[Jumpy]

Danke.

Kriegs in D6 kompiliert und gestartet, muss aber in den initialization Abschnitten jeweils eines der RegisterClassAlias auskommentieren sonst bekomme ich einen Laufzeitfehler. Siehe Bild. Woran könnte das liegen?

Da ich auch ReportMemoryLeaksOnShutdown := True; auskommentieren musste:
Wenn ich X mal hintereinander so das MainForm erzeuge und dann das vorderste wieder wechsele, werden dann die restlichen alle gelöscht (owner ist ja jeweils angegeben)?

[Medium]

Kann man Konstruktoren nicht ggf. virtuell deklarieren? Das wäre ja quasi ein Paradebeispiel. (Oder sind sie es eventuell sogar schon? Kann's grad nicht selber prüfen.)

Edit: Ansonsten halt über eine virtuelle Init-Methode, die jede Form-Klasse selbst implementiert.

[Sir Rufo]

Zitat von Medium:

Kann man Konstruktoren nicht ggf. virtuell deklarieren? Das wäre ja quasi ein Paradebeispiel. (Oder sind sie es eventuell sogar schon? Kann's grad nicht selber prüfen.)

Ab TComponent ist der auf jeden Fall virtual