AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein XML Delphi Free von XML-Komponente führt zu EInvalidPointer exception

Free von XML-Komponente führt zu EInvalidPointer exception

Offene Frage von "himitsu"
Ein Thema von michele_tedesco · begonnen am 31. Mär 2014 · letzter Beitrag vom 31. Mär 2014
Antwort Antwort
michele_tedesco

Registriert seit: 19. Mär 2014
50 Beiträge
 
#1

Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 11:45
Hallo

Ich habe aus einem Form:
Delphi-Quellcode:
unit ViewXML;

interfaces
...

  TfrmXML = class(TForm)
...

var
  frmXML: TfrmXML;

implementation
....

procedure TfrmXML.Button2Click(Sender: TObject);
var
  XMLData: TXMLData;
begin
  if odXMLFile.Execute then
    frmXML.Caption := odXMLFile.FileName;
  try
    XMLData := TXMLData.Create;
    XMLData.XMLToTree(tvXML, odXMLFile.FileName);
  finally
    XMLData.Free;
  end;
end;
...
eine Komponente instantiiert und erhalte eine EInvalidPointer beim Free des Objekts.
Hier die Komponente:
Delphi-Quellcode:
unit ServiceXMLData;

interface
....

  TXMLData = class
  private
    FList: TList<string>;
    FDOC: IXMLDocument;
    FRootNode: IXMLNode;
    Procedure TreeToXML(const Tree: TTreeView);
    procedure IterateXMLNodes(xn: IXMLNode; ParentNode: TTreeNode; var Tree: TTreeView);
    procedure IterateTreeNodes(N: TTreeNode; var ParentXN: IXMLNode);
  public
    Constructor Create;
    Destructor Destroy; override;
    procedure Config;
    Procedure SaveToFile(const fn: String; const Tree: TTreeView);
    procedure XMLToTree(var Tree: TTreeView; const FileName: String);
  end;

implementation
uses
  System.Classes;

{ TXMLData }

procedure TXMLData.Config;
begin
//
end;

constructor TXMLData.Create;
begin
//
  FList := TList<string>.Create;
end;

destructor TXMLData.Destroy;
begin
  FList.Free;
  inherited;
end;


procedure TXMLData.IterateXMLNodes(xn: IXMLNode; ParentNode: TTreeNode; var Tree: TTreeView);
var
  i, j: Integer;
  ChildTreeNode, ChildAttributeTreeNode, ChildTextTreeNode: TTreeNode;
  XMLAttribute: TXMLAttribute;
begin
  For i := 0 to xn.ChildNodes.Count - 1 do
  begin
    if xn.ChildNodes[i].NodeType = TNodeType.ntElement then
    begin
      try
        { XML Node }
        ChildTreeNode := Tree.Items.AddChild(ParentNode, xn.ChildNodes[i].NodeName);
        { XML Node attributes }
        for j := 0 to xn.ChildNodes[i].AttributeNodes.Count -1 do
        begin
          { XML Node attribute key }
          ChildAttributeTreeNode := Tree.Items.AddChild(ChildTreeNode, xn.ChildNodes[i].AttributeNodes[j].NodeName);
          XMLAttribute := TXMLAttribute.create(CXMLAtribute);
          ChildAttributeTreeNode.Data := Pointer(XMLAttribute);
          { XML Node attribute value }
          ChildAttributeTreeNode := Tree.Items.AddChild(ChildAttributeTreeNode, xn.ChildNodes[i].AttributeNodes[j].NodeValue);
          XMLAttribute := TXMLAttribute.create(CXMLAtributeValue);
          ChildAttributeTreeNode.Data := Pointer(XMLAttribute);
        end;
      finally
        XMLAttribute.Free;
      end;
      { recursive call }
      IterateXMLNodes(xn.ChildNodes[i], ChildTreeNode, tree);
    end
    else if xn.ChildNodes[i].NodeType = TNodeType.ntText then
    begin
      try
        { XML Node value }
        ChildTextTreeNode := Tree.Items.AddChild(ParentNode, xn.ChildNodes[i].NodeValue);
        XMLAttribute := TXMLAttribute.create(CXMLText);
        ChildTextTreeNode.Data := Pointer(XMLAttribute);
      finally
        XMLAttribute.Free;
      end;
    end;
  end;
end;

procedure TXMLData.SaveToFile(const fn: String; const Tree: TTreeView);
begin
  FDOC := TXMLDocument.Create(nil);
  FDOC.Options := FDOC.Options + [doNodeAutoIndent];
  FDOC.Active := true;
  TreeToXML(tree);
  FDOC.SaveToFile(fn);
end;

procedure TXMLData.TreeToXML(const Tree: TTreeView);
var
  n: TTreeNode;
begin
  { Root node }
  FRootNode := FDOC.CreateElement('DSXMLExport', '');
  FDOC.DocumentElement := FRootNode;

  { iterate Tree }
  N := Tree.Items[0];
  while Assigned(N) do
  begin
    IterateTreeNodes(N, FRootNode);
    N := N.getNextSibling;
  end;
end;

procedure TXMLData.IterateTreeNodes(N: TTreeNode; var ParentXN: IXMLNode);
var
  CurrXMLNode: IXMLNode;
  Child: TTreeNode;
  s, t: string;
begin
  Child := N.getFirstChild;
  while Assigned(Child) do
  begin
    if Assigned(Child.Data) then
    begin
      { XML node value }
      s := Child.Text;
      try
        if TXMLAttribute(Child.Data).AttributeKey = CXMLText then
        begin
          ParentXN.Text := Child.Text
        end
        { XML node attribute }
        else if TXMLAttribute(Child.Data).AttributeKey = CXMLAtribute then
        begin
          ParentXN.Attributes[Child.Text] := Child.getFirstChild.Text;
        end;
      except
      on E : Exception do
        begin
          MessageDlg('Data of ' + s + ' could could not be read. Exception: '+ E.Message, mtInformation, [mbOK], 0);
        end;
      end;
    end
    else
    begin
      CurrXMLNode := ParentXN.AddChild(N.Text);
      //FDOC.SaveToXML(t);
      IterateTreeNodes(Child, CurrXMLNode);
    end;
    Child := Child.getNextSibling;
  end;
end;

procedure TXMLData.XMLToTree(var Tree: TTreeView; const FileName: String);
var
  Doc: IXMLDocument;
begin
  Doc := NewXMLDocument;
  Doc.LoadFromFile(FileName);
  Doc.Active;
  IterateXMLNodes(Doc.DocumentElement, nil, Tree);
end;

{ TXMLAttribute }

constructor TXMLAttribute.create(AttributeKey: string);
begin
  FAttributeKey := AttributeKey;
end;

function TXMLAttribute.GetAttributeKey: string;
begin
  result := FAttributeKey
end;

procedure TXMLAttribute.SetAttributeKey(s: string);
begin
  FAttributeKey := s;
end;

end.
UPDATE: Im Anhang die PAS-Datei für die XML Komponente
Angehängte Dateien
Dateityp: pas ServiceXMLData.pas (5,5 KB, 2x aufgerufen)

Geändert von michele_tedesco (31. Mär 2014 um 13:31 Uhr) Grund: PAS Datei hinzugefügt
  Mit Zitat antworten Zitat
Benutzerbild von Union
Union

Registriert seit: 18. Mär 2004
Ort: Luxembourg
3.487 Beiträge
 
Delphi 7 Enterprise
 
#2

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 12:33
Das passiert womöglich nicht beim Free, sondern hier:
Delphi-Quellcode:
procedure TXMLData.XMLToTree(var Tree: TTreeView; const FileName: String);
var
  Doc: IXMLDocument;
begin
  Doc := NewXMLDocument;
  Doc.LoadFromFile(FileName);
  Doc.Active; // Diese Zeile macht nichts. Es muß heißen Doc.Active := True
  IterateXMLNodes(Doc.DocumentElement, nil, Tree);
end;
Ibi fas ubi proxima merces
sudo /Developer/Library/uninstall-devtools --mode=all
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.016 Beiträge
 
Delphi 12 Athens
 
#3

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 12:54
Da hier an vielen Stellen mit Interfaces gearbeitet wird, solltest du dringend auch die XML-Klasse nur via Interface verwenden!
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
michele_tedesco

Registriert seit: 19. Mär 2014
50 Beiträge
 
#4

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 13:27
Das passiert womöglich nicht beim Free, sondern hier:
Delphi-Quellcode:
procedure TXMLData.XMLToTree(var Tree: TTreeView; const FileName: String);
var
  Doc: IXMLDocument;
begin
  Doc := NewXMLDocument;
  Doc.LoadFromFile(FileName);
  Doc.Active; // Diese Zeile macht nichts. Es muß heißen Doc.Active := True
  IterateXMLNodes(Doc.DocumentElement, nil, Tree);
end;

Danke für dein Feedback , aber das hat das Problem nicht gelöst
  Mit Zitat antworten Zitat
michele_tedesco

Registriert seit: 19. Mär 2014
50 Beiträge
 
#5

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 13:28
Da hier an vielen Stellen mit Interfaces gearbeitet wird, solltest du dringend auch die XML-Klasse nur via Interface verwenden!
Das ist mein nächster Schritt, jedoch will ich verstehen, wo der Fehler passiert, um diesen Fehler dann nicht mehr zu machen
  Mit Zitat antworten Zitat
Benutzerbild von baumina
baumina

Registriert seit: 5. Mai 2008
Ort: Oberschwaben
1.275 Beiträge
 
Delphi 11 Alexandria
 
#6

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 13:30
Wenn das Create schon gar nicht funktioniert, gibt's auch nichts das man freigeben könnte. Deswegen sollte das Create außerhalb vom try stehen.

Delphi-Quellcode:
  
XMLData := TXMLData.Create;
try
  XMLData.XMLToTree(tvXML, odXMLFile.FileName);
finally
  XMLData.Free;
end;
Hinter dir gehts abwärts und vor dir steil bergauf ! (Wolfgang Ambros)
  Mit Zitat antworten Zitat
michele_tedesco

Registriert seit: 19. Mär 2014
50 Beiträge
 
#7

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 13:51
gefunden

Ich habe beim Zuweisen von .Data eines TreeItem "Pointer(XMLAttribute)" geschrieben, weil ich mit Interfaces am spielen war.
Hatte nicht fertig aufgeräumt.

Der korrekte Aufruf ist natürlich TreeItem.Data := Object , nicht TreeItem.Data := Pointer(Object)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.016 Beiträge
 
Delphi 12 Athens
 
#8

AW: Free von XML-Komponente führt zu EInvalidPointer exception

  Alt 31. Mär 2014, 13:56
jedoch will ich verstehen, wo der Fehler passiert, um diesen Fehler dann nicht mehr zu machen
Wenn durch die Aufrufe der untergeordneten Interfaces die Referenzzählung in dem Interface-Objekt der XML-Klasse verändert werden, dann übernimmt die Referenzzählung die Kontrolle über das Objekt und ab dann darf Free nicht mehr aufgerufen werden.

Entweder die Freigabe eines Objektes geschieht manuell
oder die Freigabe geschieht ausschließlich über die automatische Referenzzählung. (also über Variablen des Interfacetyps, wobei es möglichst keine Objektreferenzen geben sollte)
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 20:30 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz