Try except - Functions - wie tief

[Dalai]

Zitat von BMI:

Ich habe verschiedene, unabhängige Funktionen - und diese möchte ich aus verschiedenen Prozeduren und anderen Funktionen heraus aufrufen können, möchte aber über den Erfolg informiert werden.

Dafür hast du ja die Rückgabewerte der Funktionen, nur auswerten tust du sie im Beispiel nicht. Exceptions rauschen von unten nach oben durch, bis zu der Ebene, wo sie behandelt werden. Werden sie gar nicht (im eigenen Code) behandelt, tut das der allgemeine Exception-Handler von TApplication (?) und sollte der aus irgendwelchen Gründen nicht anschlagen, kommt der vom Betriebssystem zum Tragen. Und dann gibt's noch die Fälle, in denen gar nichts anschlägt, aber die lass ich jetzt unter den Tisch fallen *plumps*.

Ach, übrigens sollte man Exceptions nicht zur Code-Steuerung benutzen. Exceptions sind Ausnahmen/Ausnahmesituationen, in denen etwas (ganz) schlimm fehlschlägt, und sollten als solche auch behandelt werden. Das nur zu "Vorbeugung", bevor du auf derartige Ideen kommst.

MfG Dalai

[himitsu]

Zitat von Dalai:

kommt der vom Betriebssystem zum Tragen

Das stimmt, aber dem sollte man besser keine Exception geben.

Was dann passiert, sieht man an Konolenanwendungen und an vielen Nicht-RTL-Threads (ohne TThread).
Denn Windows reagiert da sehr nett und schießt die komplette Anwendung ab.

Darum hat auch TThread.Execute nochmal ein Try-Except drumrum, wobei diese Exceptions leider nicht automatisch angezeigt werden.
Und auch die neuen Konsolenanwendungen in aktuelleren Delphis haben in der Codevorlage (der DPR) nun endlich ein Try-Except mit drin.

[Dalai]

Zitat von himitsu:

Das stimmt, aber dem sollte man besser keine Exception geben.

Jein. Man sollte Exceptions natürlich selbst und möglichst früh behandeln. Aber es gibt Situationen, in denen es gar nicht anders geht, weil irgendeine bekloppte Anwendung die Exception-Handler umgebogen hat, so dass die eigenen gar nicht anspringen, wie ich erst vergangenen Monat mitbekommen und debuggen "durfte".

Zitat:

Was dann passiert, sieht man an Konolenanwendungen und an vielen Nicht-RTL-Threads (ohne TThread).
Denn Windows reagiert da sehr nett und schießt die komplette Anwendung ab.

Und gibt eine entsprechende Meldung darüber ab - immer noch besser als eine ohne Kommentar komplett von selbst im Nirvana verschwindende Anwendung, bei der man die Ursache für den Crash nicht ermitteln kann (siehe oben bzw. verlinktes Thema).

MfG Dalai

[BMI]

Hier neu:

Also ich möchte nochmal fragen, weil ich nicht im ersten Thread den Code verändfern wollte, da sonst die Quotes nicht mehr stimmig sind = ich hoffe, das ist eine gute Entscheidung.

Ich habe auch versucht, Eure Ratschläge umzusetzen (soweit ich das verstanden habe - hoffentlich richtig)

Was ich nämlich brauche:

Delphi-Quellcode:

Function Umbenennen_vorbereiten()
begin
    BewegeDatei(Move/Überschreiben())
end;

Button.click()
begin
    if FileExists(neuerOrt) then
          Umbenennen_vorbereiten() // über Umweg mit AuswahlDialog
else
   BewegeDatei() // direkt
end

Die function BewegeDatei soll also so oder so aufgerufen werden [sie enthält u.A. moveFile() bzw. moveFileEx()=^Überschreiben, was je nach gesetzter Checkbox ausgeführt wird - entweder kann sie direkt sufgerufen werden (Datei existiert nicht) oder es wird erst in der Funktion Umbenennen_vorbereiten ein Dialog erstellt und abgefragt und von dort die Funktion BewegeDatei aufgerufen.

Delphi-Quellcode:

 // /////// ACHTUNG: GEÄNDERTE, aktuelle, reale FUNCTION NAMEN !
implementation

{$R *.DFM}

function BewegeDatei(Ort_A: string; Ort_B): boolean; // ehemals "Zweite Function"

begin
  try // wohl das einzige, try, was bleiben darf ?!!
      moveFile(Ort_A, Ort_B) //     ShowMessage('Verschieben klappt');
  except
    ShowMessage('Meldung aus zweiterFunc: Verschieben klappt irgendwie nicht');
  end;
end; // End Function BEWEGEN


function Umbenennen_vorbereiten(Bla: string; Blubb: string):  boolean; // ehemals "erste Funcition"
var erste: integer;
begin
//  try
    ExtensionExtrahieren(OrtB);
    NeuerDateiName := OrtB + inc(Zahl) + Extension; // Namensfindung abgekürzt!

       if NOT BewegeDatei(OrtA, NeuerDateiName ) then
//  except
    ShowMessage('Hier gibt s ein echtes Problem: Datei läßt sich nicht bewegen.');
  end;
end; // END FUNCTION Umbenennen


procedure TForm1.Button1Click(Sender: TObject); ///////// BUTTON
var SOURCE: integer;
begin
//try
   if  Bewege('C:\Datenlager.txt', ''E:\Datenlager.txt'') then
     Dateiliste.delete(MaximalwertDerListe-1)  //als erledigt von Liste streichen
else
//  except hier gibt es dann ein Problem // ehemals:
 ShowMessage('Es hat gar nix funktioniert');

  end;
end; // END BUTTON

end.

Mhh, kann das so ^^ klappen?

Danke.

[Sir Rufo]

Nein, es sollte eher so aussehen

Delphi-Quellcode:

unit Form.Main;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm1 = class( TForm )
    Button1: TButton;
    procedure Button1Click( Sender: TObject );
  private
    FDateiListe: TStringList;
  public
    procedure AfterConstruction; override;
    procedure BeforeDestruction; override;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.AfterConstruction;
begin
  inherited;
  FDateiListe := TStringList.Create;

  // Ausgangssituation im Ordner tmp
  // TestFoo.txt
  // TestBar.txt
  // TestBarMove.txt
  // TestFooBar.txt
  // TestFooBarMove.txt
  // TestFooBarMove_1.txt

  // Am Ende finden wir dort
  // TestFooMove.txt <- alte TestFoo.txt
  // TestBarMove.txt
  // TestBarMove_1.txt <- alte TestBar.txt
  // TestFooBar.txt <- konnte nicht kopiert werden
  // TestFooBarMove.txt
  // TestFooBarMove_1.txt

  FDateiListe.Values['.\tmp\TestFoo.txt'] := '.\tmp\TestFooMove.txt';
  FDateiListe.Values['.\tmp\TestBar.txt'] := '.\tmp\TestBarMove.txt';
  FDateiListe.Values['.\tmp\TestFooBar.txt'] := '.\tmp\TestFooBarMove.txt';
end;

procedure TForm1.BeforeDestruction;
begin
  FDateiListe.Free;
  inherited;
end;

procedure BewegeDatei( const ASource, ADestination: string );
begin
  if not MoveFile( PChar( ASource ), PChar( ADestination ) )
  then
    RaiseLastOSError;
end;

procedure DateiUmbenennen( const ASource, ADestination: string );
var
  LNewDestination: string;
begin
  LNewDestination := ChangeFileExt( ADestination, '_1.txt' );
  BewegeDatei( ASource, LNewDestination );
end;

procedure TForm1.Button1Click( Sender: TObject );
var
  LSource, LDestination, LNewDestination: string;
begin
  LSource := FDateiListe.Names[0];
  LDestination := FDateiListe.ValueFromIndex[0];
  try
    BewegeDatei( LSource, LDestination );
  except
    on E: EOSError do
      case E.ErrorCode of
        ERROR_ALREADY_EXISTS: // Hier können wir etwas machen
          DateiUmbenennen( LSource, LDestination );
      else
        raise;
      end;
  end;
  FDateiListe.Delete( 0 );
end;

end.

Du kannst jetzt 3 mal auf den Button klicken und es wird beim dritten Klick eine Exception angezeigt!

Zitat:

Systemfehler. Code: 183.
Eine Datei kann nicht erstellt werden, wenn sie bereits vorhanden ist.