AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) Delphi Menu funktionalität ohne MainMenu

Menu funktionalität ohne MainMenu

Ein Thema von Mavarik · begonnen am 28. Mai 2015 · letzter Beitrag vom 29. Mai 2015
Antwort Antwort
Seite 2 von 3     12 3   
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.070 Beiträge
 
Delphi 10.3 Rio
 
#11

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 09:23
Danke für die Antworten...

HotKey nach dem Motto STRG+F2 sind kein Thema sondern eher z.B. Alt+A

Wenn ich in "Meinem Menu" Alt-A drin stehen habe, soll das natürlich nur ausgelöst werden, wenn nicht ein anderes (MDI-Child) Fenster
nicht auch ALT+A benutzt um zum Beinspiel einen Button "@Aufrufen" aus zu lösen.
Ich muss also wissen ob der Accelerator schon "verbraucht" ist.
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.070 Beiträge
 
Delphi 10.3 Rio
 
#12

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 09:28
Ich verwende hier ein TApplicationEvent-Object in der Mainform. Mit der folgenden Abfrage kann ich die Shortcuts aus dem Main-Manu verwenden und die Alt+Buchstabe-Abfrage machen, um z.B. den entsprechenden Menübandeintrag (Alt+S für "Start") anzeigen zu lassen. Gleichzeitig wird sichergestellt, dass bestimmte Alt (+Strg)-Kombinationen von den üblichen Objekten (z.T. TEdit für "@-Zeichen", das man normalerweise mit Alt+Strg+E aufruft) verarbeitet werden können.
Das Handel kann die aber nicht die Info geben, oder? Wieso Exit?

Bei einem MDI-Form ist das ActiveFormHandle immer das Form...?!?

Geändert von Mavarik (29. Mai 2015 um 09:57 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Union
Union

Registriert seit: 18. Mär 2004
Ort: Luxembourg
3.423 Beiträge
 
Delphi 7 Enterprise
 
#13

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 10:34
Das wäre vielleicht ein Ansatz, als Basis habe ich ein mit der "MDI-Anwendung" erstelltes Standardprojekt verwendet. Umgebogen wird Strg+V. Ist ein MDI-Child aktiv, wird der Tastendruck wieder an dieses per PostMessage weitergeleitet.

Delphi-Quellcode:
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    { Private-Deklarationen }
    const VK_V = $56; // "V"
    var idVK_V : Integer;
    procedure WMHotKey(var Msg: TWMHotKey); message WM_HOTKEY;

// Implementation
procedure TMainForm.FormCreate(Sender: TObject);
const
  MOD_CONTROL = 2;
begin
  idVK_V := GlobalAddAtom('Control+V');
  RegisterHotKey(Handle, idVK_V, MOD_CONTROL, VK_V);
end;

procedure TMainForm.FormDestroy(Sender: TObject);
begin
  UnregisterHotKey(Handle, idVK_V);
  GlobalDeleteAtom(idVK_V);
end;

procedure TMainForm.WMHotKey(var Msg: TWMHotKey);
begin
  if Msg.HotKey = idVK_V then
  begin
    if ActiveMDIChild <> nil then
    begin
      PostMessage(ActiveMDIChild.Handle, WM_KEYDOWN, VK_CONTROL, 0);
      PostMessage(ActiveMDIChild.Handle, WM_KEYDOWN, VK_V, 0);
      PostMessage(ActiveMDIChild.Handle, WM_KEYUP, VK_CONTROL, 0);
      PostMessage(ActiveMDIChild.Handle, WM_KEYUP, VK_V, 0);
    end
    else
      Showmessage('Strg+V');
  end;
end;
Ibi fas ubi proxima merces
sudo /Developer/Library/uninstall-devtools --mode=all
  Mit Zitat antworten Zitat
Perlsau
(Gast)

n/a Beiträge
 
#14

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 11:21
Der Maverik möchte die Tastaturfunktionalität, die in einem Mainmenu gegeben ist, ohne Mainmenu auf in seinem Programm nutzen.
Wird diese Tastaturfunktionalität nicht bereits durch die Verwendung einer TActionList zur Verfügung gestellt? Also wenn ich eine ActionList in meiner Form platziere, dort Aktionen eintrage, selbige mit entsprechenden Hotkeys versehe und die Ereignisbehandlungen dazu schreibe, brauche ich nicht zwangsläufig ein MainMenu, um die Ereignisse auszulösen. Das MainMenu würde hier lediglich der visuellen Darstellung der Menüpunkte dienen, die Mavarick ja explizit nicht wünscht.

@Mavarick: Was meinst du dazu?
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.070 Beiträge
 
Delphi 10.3 Rio
 
#15

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 11:32
Der Maverik möchte die Tastaturfunktionalität, die in einem Mainmenu gegeben ist, ohne Mainmenu auf in seinem Programm nutzen.
Wird diese Tastaturfunktionalität nicht bereits durch die Verwendung einer TActionList zur Verfügung gestellt? Also wenn ich eine ActionList in meiner Form platziere, dort Aktionen eintrage, selbige mit entsprechenden Hotkeys versehe und die Ereignisbehandlungen dazu schreibe, brauche ich nicht zwangsläufig ein MainMenu, um die Ereignisse auszulösen. Das MainMenu würde hier lediglich der visuellen Darstellung der Menüpunkte dienen, die Mavarick ja explizit nicht wünscht.

@Mavarick: Was meinst du dazu?
Hmm gute Frage muss ich testen..

Was ist ein ein Child Fenster einen La&bel mit Focus Control auf ein TEdit hat...
Kommt der Alt+B noch durch? Was fatal wäre! [Edit] Jo und so ist es auch...

Eine ActionList klaut alle Tasten...

@Union Aufwendig.. Muss ich mir auch näher anschauen...
[EDIT] Leider falsche Reigenfolge..
bzw.. Selbst wenn ein MDI-Child active ist aber die Taste "nicht gebrauchen" kann... Wird diese ja ans Menu weitergeleitet...

Geändert von Mavarik (29. Mai 2015 um 11:44 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von Dalai
Dalai

Registriert seit: 9. Apr 2006
1.635 Beiträge
 
Delphi 5 Professional
 
#16

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 11:54
Eine ActionList klaut alle Tasten...
Naja klar. Genau dazu ist sie da. Du müsstest innerhalb der Behandlungsroutine also noch prüfen, ob das richtige Formular aktiv ist, bevor die Aktion ausgelöst wird.

MfG Dalai
  Mit Zitat antworten Zitat
Benutzerbild von Mavarik
Mavarik

Registriert seit: 9. Feb 2006
Ort: Stolberg (Rhld)
4.070 Beiträge
 
Delphi 10.3 Rio
 
#17

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 11:57
Eine ActionList klaut alle Tasten...
Naja klar. Genau dazu ist sie da. Du müsstest innerhalb der Behandlungsroutine also noch prüfen, ob das richtige Formular aktiv ist, bevor die Aktion ausgelöst wird.

MfG Dalai
Cool... Bei jeder Taste alle offenen MDI-Childs durchsuchen, ob da auf irgendeinem Unterpanel oder Button ein Accelerator gebraucht wird?
  Mit Zitat antworten Zitat
Benutzerbild von Union
Union

Registriert seit: 18. Mär 2004
Ort: Luxembourg
3.423 Beiträge
 
Delphi 7 Enterprise
 
#18

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 13:12
Leider falsche Reigenfolge..
bzw.. Selbst wenn ein MDI-Child active ist aber die Taste "nicht gebrauchen" kann... Wird diese ja ans Menu weitergeleitet...
Das macht aber nichts. Wenn das Menü diesen Shortcut nicht bearbeitet, läuft der ja in's Leere.
Ibi fas ubi proxima merces
sudo /Developer/Library/uninstall-devtools --mode=all
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#19

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 13:44
Und wieso alle offnen MDIChilds durchsuchen? Das Delphi-Referenz durchsuchenTForm.ActiveMDIChild sollte da doch genügen.

Man kann natürlich auch Funktionen über ein Interface zur Verfügung stellen:
Delphi-Quellcode:
IPrintable = interface
  [{GUID}]
  function CanPrint : Boolean;
  procedure DoPrint;
end;
und dann ganz simpel abfragen
Delphi-Quellcode:
procedure TMainForm.PrintActionExecute(Sender:TObject);
var
  LPrintable : IPrintable;
begin
  if Supports( ActiveMDIChild, IPrintable, LPrintable ) then
    LPrintable.DoPrint;
end;

procedure TMainForm.PrintActionExecute(Sender:TObject);
var
  LPrintable : IPrintable;
begin
  TAction( Sender ).Enabled := Supports( ActiveMDIChild, IPrintable, LPrintable ) and LPrintable.CanPrint;
end;
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Benutzerbild von Sir Rufo
Sir Rufo

Registriert seit: 5. Jan 2005
Ort: Stadthagen
9.454 Beiträge
 
Delphi 10 Seattle Enterprise
 
#20

AW: Menu funktionalität ohne MainMenu

  Alt 29. Mai 2015, 14:53
Eine weitere Alternative ist das Versenden einer Nachricht
Delphi-Quellcode:
unit UserCommand;

interface

uses
  System.Messaging;

type
{$SCOPEDENUMS ON}
  TUserCommand = ( Print, Save, SaveAs );

  TUserCommandMessage = class( TMessage )
  private
    FCommand: TUserCommand;
    FIsQuery: Boolean;
    FHandled: Boolean;
  public
    constructor Create( ACommand : TUserCommand; AIsQuery : Boolean = False );
    property Command: TUserCommand read FCommand;
    property IsQuery: Boolean read FIsQuery;
    property Handled: Boolean read FHandled write FHandled;
  end;

implementation

{ TUserCommandMessage }

constructor TUserCommandMessage.Create(ACommand: TUserCommand;
  AIsQuery: Boolean);
begin
  inherited Create;
  FCommand := ACommand;
  FIsQuery := AIsQuery;
  FHandled := False;
end;

end.
die von der Action verschickt wird
Delphi-Quellcode:
procedure TMainForm.FilePrint1Execute( Sender: TObject );
begin
  TMessageManager.DefaultManager.SendMessage( Self, TUserCommandMessage.Create( TUserCommand.Print ), True );
end;

procedure TMainForm.FilePrint1Update( Sender: TObject );
var
  LCmd: TUserCommandMessage;
begin
  LCmd := TUserCommandMessage.Create( TUserCommand.Print, True );
  try
    TMessageManager.DefaultManager.SendMessage( Self, LCmd, False );
    TAction( Sender ).Enabled := LCmd.Handled;
  finally
    LCmd.Free;
  end;
end;
und von den Empfängern entsprechend behandelt wird
Delphi-Quellcode:
procedure TMDIChild.AfterConstruction;
begin
  inherited;
  TMessageManager.DefaultManager.SubscribeToMessage( TUserCommandMessage, HandleUserCommand );
end;

procedure TMDIChild.BeforeDestruction;
begin
  TMessageManager.DefaultManager.UnSubscribe( TUserCommandMessage, HandleUserCommand );
  inherited;
end;

procedure TMDIChild.HandleUserCommand( const Sender: TObject; const M: TMessage );
var
  LCmd: TUserCommandMessage absolute M;
begin
  if not Self.Active then
    Exit;

  case LCmd.Command of
    TUserCommand.Print:
      if LCmd.IsQuery then
        LCmd.Handled := ( Memo1.Text <> '' );
      else
        // Dokument drucken
    TUserCommand.Save:
      ;
    TUserCommand.SaveAs:
      ;
  end;

end;
Das geht dann ohne Interfaces ...
Kaum macht man's richtig - schon funktioniert's
Zertifikat: Sir Rufo (Fingerprint: ‎ea 0a 4c 14 0d b6 3a a4 c1 c5 b9 dc 90 9d f0 e9 de 13 da 60)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 02:05 Uhr.
Powered by vBulletin® Copyright ©2000 - 2022, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf