AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Win32/Win64 API (native code) IMAPI2 - Wie weise ich die EventHandler zu?
Thema durchsuchen
Ansicht
Themen-Optionen

IMAPI2 - Wie weise ich die EventHandler zu?

Ein Thema von DeddyH · begonnen am 28. Mai 2017 · letzter Beitrag vom 7. Jun 2017
 
Benutzerbild von DeddyH
DeddyH

Registriert seit: 17. Sep 2006
Ort: Barchfeld
27.666 Beiträge
 
Delphi 12 Athens
 
#9

AW: IMAPI2 - Wie weise ich die EventHandler zu?

  Alt 30. Mai 2017, 18:31
So, hier mal mein bisheriger Versuch. Ich wollte nicht gleich einen A***h voll Rohlinge für Tests verbraten, daher habe ich mir den "einfachsten" EventHandler vorgenommen.
Delphi-Quellcode:
type

  ICookie = interface
    ['{595032D1-92D4-4001-AB44-F40A6A9F16F3}']
    function GetCookie: integer;
    procedure SetCookie(const Value: integer);
    property Cookie: integer read GetCookie write SetCookie;
  end;

  TDiscMasterEvents = class(TInterfacedObject, DDiscMaster2Events, ICookie)
  private
    FTypeLib: ITypeLib;
    FTypeInfo: ITypeInfo;
    FCookie: integer;
  public
    constructor Create;
    function GetTypeInfoCount(out Count: Integer): HResult; stdcall;
    function GetTypeInfo(Index, LocaleID: Integer; out TypeInfo): HResult; stdcall;
    function GetIDsOfNames(const IID: TGUID; Names: Pointer;
      NameCount, LocaleID: Integer; DispIDs: Pointer): HResult; stdcall;
    function Invoke(DispID: Integer; const IID: TGUID; LocaleID: Integer;
      Flags: Word; var Params; VarResult, ExcepInfo, ArgErr: Pointer): HResult; stdcall;
    function NotifyDeviceAdded(const object_: IDispatch; const uniqueId: WideString): HResult; stdcall;
    function NotifyDeviceRemoved(const object_: IDispatch; const uniqueId: WideString): HResult; stdcall;
    function GetCookie: integer;
    procedure SetCookie(const Value: integer);
  end;

...

constructor TDiscMasterEvents.Create;
begin
  inherited Create;
  if LoadRegTypeLib(LIBID_IMAPI2, IMAPI2MajorVersion, IMAPI2MinorVersion,
    LOCALE_SYSTEM_DEFAULT, FTypeLib) = S_OK then
    FTypeLib.GetTypeInfoOfGuid(IID_DDiscMaster2Events, FTypeInfo);
end;

function TDiscMasterEvents.GetCookie: integer;
begin
  Result := FCookie;
end;

function TDiscMasterEvents.GetIDsOfNames(const IID: TGUID; Names: Pointer;
  NameCount, LocaleID: Integer; DispIDs: Pointer): HResult;
begin
  Result := DispGetIDsOfNames(FTypeInfo, Names, NameCount, DispIDs);
end;

function TDiscMasterEvents.GetTypeInfo(Index, LocaleID: Integer;
  out TypeInfo): HResult;
begin
  ITypeInfo(TypeInfo) := nil;
  if Index <> 0 then
    Result := DISP_E_BADINDEX
  else
    begin
      FTypeInfo._AddRef;
      ITypeInfo(TypeInfo) := FTypeInfo;
      Result := S_OK;
    end;
end;

function TDiscMasterEvents.GetTypeInfoCount(out Count: Integer): HResult;
begin
  Count := 1;
  Result := S_OK;
end;

function TDiscMasterEvents.Invoke(DispID: Integer; const IID: TGUID;
  LocaleID: Integer; Flags: Word; var Params; VarResult, ExcepInfo,
  ArgErr: Pointer): HResult;
begin
  Result := DispInvoke(self,
    FTypeInfo,
    DispID,
    Flags,
    TDispParams(Params),
    VarResult,
    ExcepInfo,
  ArgErr);
end;

function TDiscMasterEvents.NotifyDeviceAdded(const object_: IDispatch;
  const uniqueId: WideString): HResult;
begin
  //Nur mal zum Testen
  ShowMessage(uniqueId);
  Result := S_OK;
end;

function TDiscMasterEvents.NotifyDeviceRemoved(const object_: IDispatch;
  const uniqueId: WideString): HResult;
begin
  //Nur mal zum Testen
  ShowMessage(uniqueId);
  Result := S_OK;
end;

procedure TDiscMasterEvents.SetCookie(const Value: integer);
begin
  FCookie := Value;
end;

...

constructor TDiscBurner.Create;
var
  lCookie: integer;
begin
  inherited Create;
  ...
  FDiscMaster := CoMsftDiscMaster2.Create;
  FDiscMasterEvents := TDiscMasterEvents.Create;
  InterfaceConnect(FDiscMaster, IID_DDiscMaster2Events, FDiscMasterEvents,
    lCookie);
  (FDiscMasterEvents as ICookie).Cookie := lCookie;
  ...
end;
Als Cookie (Verbindungskennung) bekomme ich eine 1 zurück, das scheint also funktioniert zu haben. Allerdings scheint es mir, dass ich mich doch nicht verlesen bzw. die Beschreibung falsch verstanden habe:
Zitat:
NotifyDeviceAdded

Receives notification when an optical media device is added to the computer.
Media Device? Das soll also heißen, dass das Event gefeuert wird, wenn ein Laufwerk hinzugefügt wird und nicht bloß ein Medium eingelegt? Sollte ich das aber falsch verstanden haben, funktioniert mein Code nicht, das Event wird nicht gefeuert. Ich muss dann wohl doch in den sauren Apfel beißen und es mit einem anderen EventHandler versuchen, aber ich fahre morgen erst einmal zum CodeCamp, komme also frühestens Freitag dazu.
Detlef
"Ich habe Angst vor dem Tag, an dem die Technologie unsere menschlichen Interaktionen übertrumpft. Die Welt wird eine Generation von Idioten bekommen." (Albert Einstein)
Dieser Tag ist längst gekommen
  Mit Zitat antworten Zitat
 


Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 21:29 Uhr.
Powered by vBulletin® Copyright ©2000 - 2025, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024-2025 by Thomas Breitkreuz