AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Summe aus vorgegebenen Zahlen Bilden

Summe aus vorgegebenen Zahlen Bilden

Ein Thema von jacky213 · begonnen am 27. Mai 2019 · letzter Beitrag vom 28. Mai 2019
Antwort Antwort
jacky213

Registriert seit: 2. Mär 2011
128 Beiträge
 
#1

Summe aus vorgegebenen Zahlen Bilden

  Alt 27. Mai 2019, 21:13
Moin Moin,

ich habe mal wieder ein kleines Problem. Auf meiner Form befindet sich 1 Listview mit drei Spalten.

bb.png

In der mittleren Spalte trägt man die Anzahl der gezählten Scheine und Münzen ein. Am Ende erhält man den Gesamtumsatz und das erzielte Trinkgeld.

Das Trinkgeld wird direkt entnommen und unter den Kellnern aufgeteilt. Nun wollte ich mit einem Click das die Summe des Trinkgeldes vom Gesamtumsatz abgezogen wird. Also alle Spalten werden durchlaufen und die eingaben so angepasst, dass am Ende das Trinkgeld bei 0 Steht und genau da weis ich nicht weiter.

Hat jemand eine Idee wie ich das machen kann?

Danke
  Mit Zitat antworten Zitat
Schokohase
(Gast)

n/a Beiträge
 
#2

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 27. Mai 2019, 21:42
Wie würdest du das denn ohne Rechner machen?

Denn genau den Weg musst du programmieren.

Also, stell dir vor, du willst EUR 11,75 aus der Kasse nehmen.

Dann kann man

- einen 10-Euro-Schein
- eine 1-Euro-Münze
- eine 50-Cent-Münze
- zwei 10-Cent-Münzen
- eine 5 Cent-Münze

nehmen und hat genau den Betrag.

Du müsstest dir anschließend noch etwas überlegen, wie das Programm reagieren soll, wenn du das Trinkgeld nicht aus den vorhandenen Scheinen/Münzen aus der Kasse entnehmen kannst. Denn dann müsstest du erst Geld wechseln.

Geändert von Schokohase (27. Mai 2019 um 21:44 Uhr)
  Mit Zitat antworten Zitat
jacky213

Registriert seit: 2. Mär 2011
128 Beiträge
 
#3

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 27. Mai 2019, 21:58
Genau das mit dem wechseln macht mir Probleme. Ich bräuchte einen Beispielcode
  Mit Zitat antworten Zitat
Benutzerbild von p80286
p80286

Registriert seit: 28. Apr 2008
Ort: Stolberg (Rhl)
6.449 Beiträge
 
Delphi 7 Personal
 
#4

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 27. Mai 2019, 22:38
Welcher Art sind denn Deine Probleme?

Z.B. 47,29€ auf 4 Personen zu verteilen?

Gruß
K-H
Programme gehorchen nicht Deinen Absichten sondern Deinen Anweisungen
R.E.D retired error detector
  Mit Zitat antworten Zitat
jacky213

Registriert seit: 2. Mär 2011
128 Beiträge
 
#5

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 28. Mai 2019, 01:02
Nein, ich habe beispielsweise 6 Werte
Delphi-Quellcode:
1 x 200€
2 x 20€
6 x 5
9 x 2€
10 x 0,50€
3 x 0,05€
Dann habe ich 25,10€ Trinkgeld

Wie schaffe ich es das mein Programm mit den vorhandenen Werten die 25,10€ bildet und diesen Wert von den vorhandenen Werten abzieht.

Ergebnis sollte also so aussehen:
Delphi-Quellcode:
1 x 200€
1 x 20€
5 x 5
9 x 2€
10 x 0,50€
1 x 0,05€

Geändert von jacky213 (28. Mai 2019 um 01:30 Uhr)
  Mit Zitat antworten Zitat
hoika

Registriert seit: 5. Jul 2006
Ort: Magdeburg
7.283 Beiträge
 
Delphi XE4 Professional
 
#6

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 28. Mai 2019, 05:32
Hallo,
das klappt doch meistens nicht.
Weil Teile des Trinkgeldes wieder zum Bezahlen benutzt worden sind,
also gewechselt worden sind.

Die gewünschte Anzahl von Scheinen und Münzen steht dann einfach nicht zur Verfügung.
Heiko
  Mit Zitat antworten Zitat
Benutzerbild von Luckie
Luckie
(Moderator)

Registriert seit: 29. Mai 2002
37.328 Beiträge
 
Delphi 2006 Professional
 
#7

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 28. Mai 2019, 09:20
Aber je mehr Geld du in der Kasse hast, desto höher ist die Chance dass es funktionieren kann. Also warum nicht probieren und wenn es nicht möglich ist, wird eben eine Fehlermeldung ausgegeben.

Aber das Problem ist nicht neu. Such mal nach "münzautomat programmieren", "wechselgeld rausgeben" oder ähnlichen. Übrigens auch ein sehr beliebtes Problem in Anfängerkursen, richtig wieder rausgeben mit den vorhandenen Geldwerten.

Ansatz wäre das Trinkgeld in mögliche Kombinationen zu zerlegen und dann zu gucken, ob von allen benötigten Scheinen und Münzen genug vorhanden sind. Wir könne das Problem also auf eine Aufgabe reduzieren: Zerlegen des Trinkgeldes. Das Gucken, ob alle benötigten Geldwerte vorhanden sind, ist dann eher trivial.
Michael
Ein Teil meines Codes würde euch verunsichern.
  Mit Zitat antworten Zitat
Schokohase
(Gast)

n/a Beiträge
 
#8

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 28. Mai 2019, 09:41
Hier etwas worauf du aufbauen kannst:
Delphi-Quellcode:
program KassenSturz;

{$APPTYPE CONSOLE}
{$R *.res}

uses
  System.SysUtils,
  System.Generics.Defaults,
  System.Generics.Collections;

type
  TWallet = TDictionary<Currency, UInt32>;

procedure MoveMoney(const ASource: TWallet; AValue: Currency; const ADest: TWallet);
var
  Amount: Currency;
  Values: TArray<Currency>;
  Val: Currency;
begin
  if not Assigned(ASource) then
    raise EArgumentNilException.Create('ASource');
  if not Assigned(ADest) then
    raise EArgumentNilException.Create('ADest');

  Amount := AValue;
  Values := ASource.Keys.ToArray();
  TArray.Sort<Currency>(Values, TComparer<Currency>.Construct(
    function(const Left, Right: Currency): Integer
    begin
      Result := -TComparer<Currency>.Default.Compare(Left, Right);
    end));

  for Val in Values do
  begin
    while (Val <= Amount) and (ASource[Val] > 0) do
    begin
      ASource[Val] := ASource[Val] - 1;
      if not ADest.ContainsKey(Val) then
        ADest.Add(Val, 1)
      else
        ADest[Val] := ADest[Val] + 1;
      Amount := Amount - Val;
    end;
  end;

  if Amount > 0 then
    raise Exception.Create('Fehlermeldung');
end;

procedure WriteWallet(const Value: TWallet; IgnoreEmpty: Boolean = false);
var
  Values: TArray<Currency>;
  Val, Tot: Currency;
  Cnt: Integer;

begin
  Values := Value.Keys.ToArray();
  TArray.Sort<Currency>(Values, TComparer<Currency>.Construct(
    function(const Left, Right: Currency): Integer
    begin
      Result := -TComparer<Currency>.Default.Compare(Left, Right);
    end));

  Tot := 0;
  for Val in Values do
  begin
    Cnt := Value[Val];
    if IgnoreEmpty and (Cnt = 0) then
      Continue;
    Tot := Tot + Cnt * Val;
    Writeln(string.Format('%0.2f x %d = %0.2f', [Val, Cnt, Val * Cnt]));
  end;
  Writeln('======');
  Writeln(string.Format('Total: %0.2f', [Tot]));
end;

procedure Main;
var
  s, d: TWallet;
begin
  s := nil;
  d := nil;
  try
    s := TWallet.Create();
    s.Add(500.00, 0);
    s.Add(200.00, 1);
    s.Add(100.00, 0);
    s.Add(50.00, 0);
    s.Add(20.00, 2);
    s.Add(10.00, 0);
    s.Add(5.00, 6);
    s.Add(2.00, 9);
    s.Add(1.00, 0);
    s.Add(0.50, 10);
    s.Add(0.20, 0);
    s.Add(0.10, 0);
    s.Add(0.05, 3);
    s.Add(0.02, 0);
    s.Add(0.01, 0);

    d := TWallet.Create();

    Writeln('Source:');
    WriteWallet(s, true);
    Writeln('Destination:');
    WriteWallet(d, true);

    MoveMoney(s, 25.10, d);

    Writeln;
    Writeln('Source:');
    WriteWallet(s, true);
    Writeln('Destination:');
    WriteWallet(d, true);

  finally
    s.Free();
    d.Free();
  end;
end;

begin
  try
    { TODO -oUser -cConsole Main : Code hier einfügen }
    Main;
  except
    on E: Exception do
      Writeln(E.ClassName, ': ', E.Message);
  end;
  Readln;

end.
PS Ja, ich weiß, das das noch nicht fertig ist, es ist ja auch etwas worauf man aufbauen kann.
  Mit Zitat antworten Zitat
Benutzerbild von Moombas
Moombas

Registriert seit: 22. Mär 2017
Ort: bei Flensburg
300 Beiträge
 
FreePascal / Lazarus
 
#9

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 28. Mai 2019, 09:55
Vom Prinzip müsste es doch so funktionieren:

Delphi-Quellcode:
procedure Button1Click(Sender: TObject);
var
  iZweihundertE : Integer;
  iEinhundertE : Integer;
  iFuenfzigE : Integer;
  iZwanzigE : Integer;
  iZehnE : Integer;
  iFuenfE : Integer;
  iZweiE : Integer;
  iEinE : Integer;
  iFuenfzigC : Integer;
  iZwanzigC : Integer;
  iZehnC : Integer;
  iFuenfC : Integer;
  iZweiC : Integer;
  iEinC : Integer;
  iTrinkgeldE : Integer;
  iTrinkgeldC : Integer;
begin
  iZweihundertE := 1;
  iEinhundertE := 0;
  iFuenfzigE := 0;
  iZwanzigE := 2;
  iZehnE := 0;
  iFuenfE := 6;
  iZweiE := 9;
  iEinE := 0;
  iFuenfzigC := 10;
  iZwanzigC := 0;
  iZehnC := 0;
  iFuenfC := 3;
  iZweiC := 0;
  iEinC := 0;
  iTrinkgeldE := 25;
  iTrinkgeldC := 10;

  while (iTrinkgeldE >= 200) and
        (iZweihundertE > 0 ) do
  begin
    dec(iZweihundertE);
    iTrinkgeldE := iTrinkgeldE - 200;
  end;
  while (iTrinkgeldE >= 100) and
        (iEinhundertE > 0 ) do
  begin
    dec(iEinhundertE);
    iTrinkgeldE := iTrinkgeldE - 100;
  end;
  while (iTrinkgeldE >= 50) and
        (iFuenfzigE > 0 ) do
  begin
    dec(iFuenfzigE);
    iTrinkgeldE := iTrinkgeldE - 50;
  end;
  while (iTrinkgeldE >= 20) and
        (iZwanzigE > 0 ) do
  begin
    dec(iZwanzigE);
    iTrinkgeldE := iTrinkgeldE - 20;
  end;
  while (iTrinkgeldE >= 10) and
        (iZehnE > 0 ) do
  begin
    dec(iZehnE);
    iTrinkgeldE := iTrinkgeldE - 10;
  end;
  while (iTrinkgeldE >= 5) and
        (iFuenfE > 0 ) do
  begin
    dec(iFuenfE);
    iTrinkgeldE := iTrinkgeldE - 5;
  end;
  while (iTrinkgeldE >= 2) and
        (iZweiE > 0 ) do
  begin
    dec(iZweiE);
    iTrinkgeldE := iTrinkgeldE - 2;
  end;
  while (iTrinkgeldE >= 1) and
        (iEinE > 0 ) do
  begin
    dec(iEinE);
    iTrinkgeldE := iTrinkgeldE - 1;
  end;
  while (iTrinkgeldC >= 50) and
        (iFuenfzigC > 0 ) do
  begin
    dec(iFuenfzigC);
    iTrinkgeldC := iTrinkgeldC - 50;
  end;
  while (iTrinkgeldC >= 20) and
        (iZwanzigC > 0 ) do
  begin
    dec(iZwanzigC);
    iTrinkgeldC := iTrinkgeldC - 20;
  end;
  while (iTrinkgeldC >= 10) and
        (iZehnC > 0 ) do
  begin
    dec(iZehnC);
    iTrinkgeldC := iTrinkgeldC - 10;
  end;
  while (iTrinkgeldC >= 5) and
        (iFuenfC > 0 ) do
  begin
    dec(iFuenfC);
    iTrinkgeldC := iTrinkgeldC - 5;
  end;
  while (iTrinkgeldC >= 2) and
        (iZweiC > 0 ) do
  begin
    dec(iZweiC);
    iTrinkgeldC := iTrinkgeldC - 2;
  end;
  while (iTrinkgeldC >= 1) and
        (iEinC > 0 ) do
  begin
    dec(iEinC);
    iTrinkgeldC := iTrinkgeldC - 1;
  end;
  if (iTrinkgeldE > 0) or
     (iTrinkgeldC > 0) then
    showmessage('Das Trinkgeld kann nicht komplett aufgeteilt werden. Restbtrag: ' + inttostr(iTrinkgeldE) + ',' + inttostr(iTrinkgeldC))
  else
    showmessage('Das Trinkgeld kann komplett aufgeteilt werden.');
end;
Das man das über eine eigene Funktion regeln kann, anstatt C&P ist mir klar, soll ja nur als Beispiel dienen.
Zudem lässt es sich beim abarbeiten der Listview (wenn es in eine externe Funktion gelagert wird) recht einfach umsetzen. Aber der TE soll ja auch noch was zu tun haben^^
Der Weg ist das Ziel aber man sollte auf dem Weg niemals das Ziel aus den Augen verlieren.

Geändert von Moombas (28. Mai 2019 um 09:59 Uhr)
  Mit Zitat antworten Zitat
Michael II

Registriert seit: 1. Dez 2012
Ort: Region Bern CH
317 Beiträge
 
Delphi 10.3 Rio
 
#10

AW: Summe aus vorgegebenen Zahlen Bilden

  Alt 28. Mai 2019, 10:07
Du sprichst hier (#5) ein interessantes mathematisches Problem an, welches vor langer Zeit gelöst worden ist. Tipp: Suche nach "Lineare Diophantische Gleichungen"

Sehr allgemeine Infos zu Diophantischen Gleichungen findest du hier:
https://de.wikipedia.org/wiki/Diophantische_Gleichung

Speziell für dein Problem:
https://de.wikipedia.org/wiki/Linear...sche_Gleichung

Ein weiteres Beispiel:
https://www.lernhelfer.de/schuelerlexikon/mathematik/artikel/diophant
(dort unten das Beispiel mit den Geschenken)


Hier gibt's ein Onlinetool. Du kannst eine Lineare Diophantische Gleichung eingeben und es wird erklärt, wie diese gelöst werden kann:
http://www.arndt-bruenner.de/mathe/s...ant.htm#script
Michael Gasser

Geändert von Michael II (28. Mai 2019 um 10:16 Uhr)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 05:05 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf