Fluent Design und Records

[Stevie]

Ihr meint sicher Fluent Interface und nicht Fluent Design.

[hschmid67]

Zitat:

Ihr meint sicher Fluent Interface und nicht Fluent Design.

Oh, natürlich meinte ich Fluent Interface - Danke für die Klarstellung.

Und vielen Dank auch an alle, die sich bisher beteiligt hatten. Hmmm, das mit der Adresse und dem ^ ist eine Lösung, aber irgendwie mag ich solche Operatoren in meinem normalen Code nicht - das sieht für mich immer nach Eingriff auf unterster Ebene aus. Und das ist in einer Bibliothek ok, aber für den täglichen Gebrauch... Ob ich dann wohl doch lieber bei den Interfaces bleibe?

Viele Grüße
Harald

[uligerhardt]

Zitat von hschmid67:

Hmmm, das mit der Adresse und dem ^ ist eine Lösung, aber irgendwie mag ich solche Operatoren in meinem normalen Code nicht - das sieht für mich immer nach Eingriff auf unterster Ebene aus. Und das ist in einer Bibliothek ok, aber für den täglichen Gebrauch... Ob ich dann wohl doch lieber bei den Interfaces bleibe?

Mit dem Haken siehst du halt, dass du dereferenzierst. Bei Variablen von Klassen- oder Interfacetypen dereferenzierst du genau so, nur ist es versteckt. De facto ist die zweite Variante also sogar weniger klar. (Vom erhöhten Overhead (dynamische Allozierung, virtuelle Methodenaufrufe) ganz zu schweigen.)

[hschmid67]

Hallo Zusammen,

jetzt habe ich den Vorschlag von uligerhardt mal ausprobiert, aber irgendwas scheine ich nicht richtig zu verstehen. Könnt Ihr mir nochmal weiterhelfen?

Also, ich hab mal folgende Unit gemacht:

Delphi-Quellcode:

unit hs.str2;

interface

type
  ThsStr2 = record
    FStr: string;
    function AsString: string;
    function Init(const mString: string): ThsStr2;
  end;

implementation

uses
  System.SysUtils;

{ ThsStr2 }

function ThsStr2.AsString: string;
begin
  Result := FStr;
end;

function ThsStr2.Init(const mString: string): ThsStr2;
begin
  FStr := mString;
//  Result := @Self;  // so war der Vorschlag, aber das kompiliert gar nicht "Pointer und ThsStr2"
  Result := ThsStr2(@Self);  // so kompiliert es, aber wirft eine AV bei der Ausführung
end;

end.

Testen wollte ich das Ganze so:

Delphi-Quellcode:

procedure Test;
var
  lStr: ThsStr2;
  lDummy: string;
begin
  lDummy := lStr.Init('dummy').AsString;
end;

Aber eben beim Init bekomme ich eine AV. Was mache ich falsch - oder wo ist mein Denkfehler?

Viele Grüße
Harald

[uligerhardt]

Sorry, ich hab's etwas kurz erklärt.
Du musst einen Zeigertyp zurückgeben, also etwas so:

Delphi-Quellcode:

type
  PhsStr2 = ^ThsStr2; // Zeiger auf ThsStr2
  ThsStr2 = record
    FStr: string;
    function AsString: string;
    function Init(const mString: string): PhsStr2; // <== Beachte den Rückgabetyp!
  end;

[hschmid67]

Super!

Vielen, vielen Dank. Jetzt hab ich es verstanden.

Hier noch mein vollständiges Beispiel, das jetzt funktioniert (natürlich nur im Anfangsstadium):

Delphi-Quellcode:

unit hs.str2;

interface

type
  PhsStr2 = ^ThsStr2;
  ThsStr2 = record
    FStr: string;
    function Init(const mString: string): PhsStr2;
    class operator implicit(const aValue: ThsStr2): string;
    class operator implicit(const aValue: string): ThsStr2;
  end;

implementation

uses
  System.SysUtils;

{ ThsStr2 }

class operator ThsStr2.implicit(const aValue: ThsStr2): string;
begin
  Result := aValue.FStr;
end;

class operator ThsStr2.implicit(const aValue: string): ThsStr2;
begin
  Result.FStr := aValue;
end;

function ThsStr2.Init(const mString: string): PhsStr2;
begin
  FStr := mString;
  Result := @Self;
end;

end.

Und der Aufruf läuft jetzt erfolgreich:

Delphi-Quellcode:

procedure Test;
var
  lStr: ThsStr2;
  lDummy: string;
begin
  lDummy := lStr.Init('dummy');
end;

Genau das, was ich gesucht hatte - und in meinen Augen dann richig schöner Code, denn man kann das Ganze ja beliebig erweitern, etwa


lDummy := lStr.Init('dummy').CopyFromChar('-').CopyToChar('#');

Das möchte ich nämlich gerade machen: All meine String-Funktionen in einen Aufruf, in ein Objekt/einen Record zu packen, ohne globale Proceduren oder besonderes Speichermanagement (zumindest nicht sichtbar).

Jetzt wäre es nur noch schön, wenn man es so aufrufen könnte:


lDummy := lStr('dummy').CopyFromChar('-').CopyToChar('#');

also ohne das Init, aber das geht wohl nicht...

Vielen Dank und viele Grüße
Harald

[uligerhardt]

Schaut gut aus. Bzgl. des letzten Satzes: Du könntest dem Record einen Konstruktor oder eine Factory-Funktion verpassen. Dann solltest du so etwas schreiben können:

Delphi-Quellcode:

lDummy := ThsStr2.Create('dummy').CopyFromChar('-').CopyToChar('#'); // Mit Record-Konstruktor
// oder
lDummy := MakehsStr2('dummy').CopyFromChar('-').CopyToChar('#'); // Mit Factory-Funktion