AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Tutorials Kleiner Exkurs zu Exceptions (try finally/except)

Kleiner Exkurs zu Exceptions (try finally/except)

Ein Tutorial von MaBuSE · begonnen am 7. Feb 2020 · letzter Beitrag vom 7. Feb 2020
Antwort Antwort
Benutzerbild von MaBuSE
MaBuSE
Registriert seit: 23. Sep 2002
In meinem Lieblingsthread "Eure besten Quellcode Kommentare..." wurde folgender Quellcode Kommentar gesendet.

Delphi-Quellcode:
{$IFDEF MSWINDOWS}
procedure DLLShutdown; stdcall;
begin
  try
    if @DLLShutdownProc <> nil then
      DLLShutdownProc;
  finally
    // eat all exception.
  end;
end;
{$ENDIF MSWINDOWS}
Die DLLShutdown-Methode die ich gepostet habe ist übrigens aus der System.pas. (10.3.2)
Genau so geschrieben und kommentiert.


Da es wohl auch bei Borland /Embarcadero / Idera Leute gibt, die sich noch nicht richtig mit dem Thema befasst haben, habe ich hier mal eine kleine Zusammenfassung geschrieben.


try ... finally ... end; Block
Delphi-Quellcode:
...
  WriteLn('Null - ohne Exception');
  try
    WriteLn('Eins');
    WriteLn('Zwei');
    WriteLn('Drei');
  finally
    WriteLn('Vier');
  end; // hier wird die Exception nochmal geworfen (analog raise)
  WriteLn('Fünf');
...
  WriteLn('Null - mit Exception');
  try
    WriteLn('Eins');
    WriteLn(StrToInt('Zwei'));
    WriteLn('Drei');
  finally
    WriteLn('Vier');
  end; // hier wird die Exception nochmal geworfen (analog raise)
  WriteLn('Fünf');
...
Gibt Ausgabe:
Code:
...
Null - ohne Exception
Eins
Zwei
Drei
Vier
Fünf
Null - mit Exception
Eins
Vier
Exception
Vier wird auf jeden Fall ausgeführt. Egal ob eine Exception auftritt oder nicht.

try ... except ... end; Block
Delphi-Quellcode:
...
  WriteLn('Null - Ohne Exception');
  try
    WriteLn('Eins');
    WriteLn('Zwei');
    WriteLn('Drei');
  except
    WriteLn('Vier');
  end;
  WriteLn('Fünf');
...
  WriteLn('Null - mit Exception');
  try
    WriteLn('Eins');
    WriteLn(StrToInt('Zwei'));
    WriteLn('Drei');
  except
    WriteLn('Vier');
  end;
  WriteLn('Fünf');
...
Gibt Ausgabe:
Code:
...
Null - Ohne Exception
Eins
Zwei
Drei
Fünf
Null - mit Exception
Eins
Vier
Fünf
Vier wird nur ausgeführt, wenn eine Exception auftritt.


Verschachtelungen:
finally-except

Delphi-Quellcode:
...
  WriteLn('Null');
  try
    try
      WriteLn('Eins');
      WriteLn(StrToInt('Zwei'));
      WriteLn('Drei');
    finally
      WriteLn('Vier');
    end; // hier wird die Exception nochmal geworfen (analog raise)
  except
    WriteLn('Fünf');
  end;
  WriteLn('Sechs');
...
Gibt Ausgabe:
Code:
...
Null
Eins
Vier
Fünf
Sechs
...
except-finally
Delphi-Quellcode:
...
  WriteLn('Null');
  try
    WriteLn('Eins');
    try
    WriteLn(StrToInt('Zwei'));
    except
      WriteLn('Drei');
    end; // Exception abgefangen
    WriteLn('Vier');
  finally
    WriteLn('Fünf');
  end; // hier wird die Exception nochmal geworfen (analog raise), falls eine aufgetreten ist und nicht abgefangen wurde.
  WriteLn('Sechs');
...
Gibt Ausgabe:
Code:
...
Null
Eins
Drei
Vier
Fünf
Sechs
Warum das ganze?
try ... finally wird dazu verwendet, sicherzustellen, dass bestimmter Code auch nach einer Exception ausgeführt wird. Z.B. das Freigaben eines Objekts.
Der Code zwischen finally und end wird also auf jeden Fall ausgeführt, egal ob ein Fehler auftritt oder nicht.
Delphi-Quellcode:
...
  MyObject := TMyObject.Create
  try
    MyObject.DoSomething;
  finally
    MyObject.Free;
  end;
...
try except wird dazu verwendet Fehler abzufangen und darauf zu reagieren.
Der Code zwischen except und end wird nur im Fehlerfall ausgeführt
Delphi-Quellcode:
...
  try
    i := StrToInt(s);
  except
    WriteLn('Es ist ein Fehler aufgetreten. s ist kein Integer');
  end;
...
  // oder
  try
    i := StrToInt(s);
  except
    on E: Exception do
    begin
      WriteLn('Es ist ein Fehler aufgetreten.');
      WriteLn('Fehlermeldung: ', E.Message);
    end;
  end;
...
Besser ist es aber bei "erwarteten" Fehlern nur die entsprechende Fehlerklasse abzufangen.
(Anmerkung: Noch besser wäre es natürlich den erwarteten Fehler zu vermeiden, statt per Exception abzufangen.)
Delphi-Quellcode:
...
  try
    i := StrToInt(s);
  except
    on E: EConvertError do
    begin
      WriteLn('Es ist ein Fehler aufgetreten.');
      WriteLn('Fehlermeldung: s ist keine Ganzzahl');
    end;
    on E: EAnderErwarteterFehler do WriteLn('Andere Fehlermeldung');
  end; // Hier wird dann für jeden anderen Fehler außer EConvertError und EErwarteterFehler eine Exception geworfen.
...
Es gibt aber auch ein paar Fallstricker bei verschachtelten Exceptions.
Z.B. werden bei manchen Exceptions die objekte, in denen der Fehler aufgetreten ist referenziert.
Wenn hier in einem finally das objekt freigegeben wird, gibt's beim Zugriff auf die Referenz im Exception Objekt evtl eine allgemeine Schutzverletzung.

Zu dem Thema gibt es noch viel zu Schreiben: globales Exception handling, Unterstützung durch z.B. jcl, MAD-Except, ...
(°¿°) MaBuSE - proud to be a DP member
(°¿°) MaBuSE - proud to be a "Rüsselmops" ;-)

Geändert von MaBuSE ( 7. Feb 2020 um 08:32 Uhr)
 
Gyrospeter

 
Delphi XE2 Professional
 
#2
  Alt 7. Feb 2020, 07:38
Vielen Dank, für mich als Programmier-Azubi eine gute Exkursion
  Mit Zitat antworten Zitat
jobo

 
Delphi 2010 Enterprise
 
#3
  Alt 7. Feb 2020, 08:27
Mir ist die Sache durch die Quellcodekommentare aufgefallen.

Deine Beispiel erscheint mir aber etwas seltsam. (Randnotiz, wieso kann man das nicht zitieren?)

Zitat:
...
try
i := IntToStr(s);
except
WriteLn('Es ist ein Fehler aufgetreten. s ist kein Integer);
end;
...
Es würde wohl einen Kompilerfehler ergeben. Das fehlende Anführungszeichen deutet auch darauf hin, dass Du es nur getippt und nicht laufen lassen hast.

So oder so:
Bei
intToStr würde man wohl eher
s := IntToStr(i);

verwenden und das Beispiel würde Sinn ergeben, wenn man wie oben irgendwo die Funktion StrToInt() verwendet, was Du vermutlich eigentlich machen wolltest. Hier können prima Laufzeitfehler auftreten, die als Opfer für Try Except herhalten können:

i := StrToInt(s);

Geändert von jobo ( 7. Feb 2020 um 08:30 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von MaBuSE
MaBuSE

 
Delphi 10 Seattle Enterprise
 
#4
  Alt 7. Feb 2020, 08:30
Mir ist die Sache durch die Quellcodekommentare aufgefallen.
Deine Beispiel erscheint mir aber etwas seltsam. ...
Es würde wohl einen Kompilerfehler ergeben. Das fehlende Anführungszeichen deutet auch darauf hin, dass Du es nur getippt und nicht laufen lassen hast.
Danke
Du hast absolut Recht. Ich hab hier gerade kein Delphi zur Hand.

Ich hab das mal schnell korrigiert

Geändert von MaBuSE ( 7. Feb 2020 um 08:32 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

 
Delphi 10.4 Sydney
 
#5
  Alt 7. Feb 2020, 08:36
Die CLI-Vorlage hat IMHO auch schon immer eine kleines Fehlerchen.
Wenn die Anwendung direkt und nicht aus einer Konsole mit Output-Stream gestartet wurde, dann sollte nach dem Except+WriteLn(E.Message) noch ein ReadLn rein, denn sonst kann doch niemand die Exception lesen


Schade ist tzwar, dass man Try/Finally/Except bzw. Try/Except/Finally nicht "direkt" kombinieren kann (also ein Try gefolgt von mehreren Except/Finaly).
Aber naja.

Indirekt geht es, allerdings nur zum Antzeigen der Exception, bzw. zum zusätzlich darauf reagieren.
Zitat:
try
...
finally

E := System.ExceptObject as Exception; // analog zum "on E: Exception" im except, aber das implizite "raise;" bleibt drin
...

end;

Geändert von himitsu ( 7. Feb 2020 um 08:41 Uhr)
  Mit Zitat antworten Zitat
Benutzerbild von MaBuSE
MaBuSE

 
Delphi 10 Seattle Enterprise
 
#6
  Alt 7. Feb 2020, 08:44
Die CLI-Vorlage hat IMHO auch schon immer eine kleines Fehlerchen.
Wenn die Anwendung direkt und nicht aus einer Konsole mit Output-Stream gestartet wurde, dann sollte nach dem Except+WriteLn(E.Message) noch ein ReadLn rein, denn sonst kann doch niemand die Exception lesen
Nein

Du kannst auch aus einer GUI Anwendung jederzeit mit AllocConsole; eine Console öffen, um mit Write darin zu schreiben.
Mach ich oft für Debugausgaben
  Mit Zitat antworten Zitat
Themen-Optionen Tutorial durchsuchen
Tutorial durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 02:38 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2020 by Daniel R. Wolf