Bit-Tiefe in PNG ermitteln

[Amateurprofi]

Zitat von himitsu:

Aber für den Ressourcenschutzblock sollte jemand gesteinigt werden.

Zitat:

Delphi-Quellcode:

  bs := TBytesStream.Create();
  bs.LoadFromFile('bla.png');
  m := bs.Memory;
  try
    ...
  finally
    bs.Free;
  end;

Delphi-Quellcode:

  bs := TBytesStream.Create();
  try
    bs.LoadFromFile('bla.png');
    m := bs.Memory;
    ...
  finally
    bs.Free;
  end;

Denn wenn es im LoadFromFile knallt, dann war's das.

Und wenn es schon beim Create kracht?
Ich habe mir angewöhnt, in etwa so zu formulieren:

Delphi-Quellcode:

var BS:TBytesStream;
begin
   BS:=Nil;
   try
      try
         BS:=TBytesStream.Create();
         ...
         ...
      except
         on E:Exception do ShowMessage(E.Message);
      end;
   finally
      BS.Free;
   end;
end;

Mache ich da einen Denkfehler?

[himitsu]

Kann man auch machen, aber lohnt sich nur, wenn das Create erst irgendwo in der Mitte kommt, bzw. wenn man mehrere Sachen erstellen will.

Wenn es im Create kracht, dann wird der Varible nichts zugewiesen und da es nicht mehr bis zum TRY kommt, ist das Finally auch egal ... also alles OK.
Wenn es dort kracht, dann wird bereits im Constructor die Instanz wieder freigegeben ... dort ist quasi ein Try-Except integriert.



Zusammenfassen von mehreren Try-Finally/Except (einfaches Beispiel) :

Im StringList.Free kann es eigentlich nicht knallen
und auch ein TStringList.Create kann "eigentlich" keinen Fehler erzeugen. (außer es ist garkein RAM mehr frei oder der Speichermanager ist kaputt)
Eigentlich: Falls doch, dann ist so viel im Argen, dass man eh alles vergessen kann.

Delphi-Quellcode:

a := TFileStream.Create('dat.ei');  // hier natürlich das "eine" Schlimme vor dem einen/mehreren Ungefährlichen
b := TStringList.Create;
try
  ...
finally
  b.Free;
  a.Free;
end;

oder eben

Delphi-Quellcode:

b := nil;
a := TFileStream.Create('dat.ei');
try
  b := TStringList.Create;
  ...
finally
  b.Free;
  a.Free;
end;

oder

Delphi-Quellcode:

a := nil;
b := nil;
try
  a := TFileStream.Create('dat.ei');
  b := TStringList.Create;
  ...
finally
  b.Free;
  a.Free;
end;

oder wer ganz auf nummer sicher gehn will

Delphi-Quellcode:

a := TFileStream.Create('dat.ei');
try
  b := TStringList.Create;
  try
    ...
  finally
    b.Free;
  end;
finally
  a.Free;
end;

[Amateurprofi]

Danke himitsu.