AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Algorithmen, Datenstrukturen und Klassendesign Delphi Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

Ein Thema von Maliko · begonnen am 2. Sep 2021 · letzter Beitrag vom 2. Sep 2021
Antwort Antwort
Maliko

Registriert seit: 20. Jun 2019
38 Beiträge
 
Delphi 10.3 Rio
 
#1

Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

  Alt 2. Sep 2021, 12:22
Hoi,

ich verzweifle hier gerade an einem kleinen Problem. Und zwar habe ich eine Klasse, von welcher ich ein Objekt erzeuge. Wenn ich jetzt versuche dieses Objekt mittels Json.ObjectToJsonObjekt umzuwandeln, bekomme ich immer eine AccessViolation.

Ich kann mir nicht erklären warum. Kann mir von euch vieleicht jemand weiterhelfen? Folgendes Objekt Versuche ich umzuwandeln:

Delphi-Quellcode:
TLimit = class
    private
      Flimit : Double;
      FfreeLimit : Double;
      FopenInvoices : TArray<TLimitVorgang>;
    published
      property limit: Double read Flimit write Flimit;
      property freeLimit: Double read FfreeLimit write FfreeLimit;
      property openInvoices: TArray<TLimitVorgang> read FopenInvoices write FopenInvoices;
end;
TLimitVorgang hat dabei folgende Struktur:
Delphi-Quellcode:
TLimitVorgang = class
    private
      FinternalInvoiceId : string;
      Famount : double;
      FopenAmount : double;
      FpaymentTargetDate : string;
      FdateOfEntry : string;
      FpaymentDate : string;
    published
      property internalInvoiceId: string read FinternalInvoiceId write FinternalInvoiceId;
      property amount: double read Famount write Famount;
      property openAmount: double read FopenAmount write FopenAmount;
      property paymentTagetDate: string read FpaymentTargetDate write FpaymentTargetDate;
      property dateOfEntry: string read FdateOfEntry write FdateOfEntry;
      property paymentDate: string read FpaymentDate write FpaymentDate;
  end;
Das Array selbst existiert und man kann auch Daten daraus abrufen (das Feld FfreeLimit in der TLimit berechne ich indem ich das Feld Flimit nehme, durch das Array itariere und für jeden Eintrag amount davon abziehe). Ebenso bekomme ich keine Fehlermeldung wenn ich in TLimit anstatt TArray<TLimitVorgang> nur TLimitVorgang übergebe. Dann finde ich genau das Objekt auch im JSON wieder.

Der Fehler kommt definitiv nur, wenn TLimit.FopenInvoices vom Typ TArray<TLimitVorgang> ist und das Array nicht leer ist (wenn ich einfach ein leeres Array übergebe bekomme ich auch keinen Fehler).

Kann mir da vielleicht irgendjemand weiterhelfen, was ich da vergessen habe, bzw. falsch mache? Google hilft mir da leider auch nicht mehr weiter.
  Mit Zitat antworten Zitat
shebang

Registriert seit: 7. Feb 2020
37 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

  Alt 2. Sep 2021, 13:20
https://docwiki.embarcadero.com/RADS...ray_Properties
Zitat:
For array properties, access specifiers must list methods rather than fields.
Wobei dynamische Arrays dort nicht erwähnt werden.

Geändert von shebang ( 2. Sep 2021 um 13:23 Uhr)
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.713 Beiträge
 
Delphi 10 Seattle Enterprise
 
#3

AW: Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

  Alt 2. Sep 2021, 13:22
Toll dass du die Definitionen für TLimit und TLimitVorgang schon geliefert hast.

Hast du auch noch einen Dreizeiler zum Nachstellen?

Weil bei mir läuft das ohne Probleme durch:

Delphi-Quellcode:
uses
  System.SysUtils,
  System.JSON,
  Rest.JSON;

procedure p();
var
   limit: TLimit;
   limitAsJson: TJSONObject;
   convertedBack: TLimit;
begin
   limit := createLimit();
   limitAsJson := TJson.ObjectToJsonObject(limit);
   convertedBack := TJson.JsonToObject<TLimit>(limitAsJson);
end;
Der Vollständigkeit halber noch:
Delphi-Quellcode:
function createLimit(): TLimit;
var
   vorgang1, vorgang2: TLimitVorgang;
begin
   vorgang1 := TLimitVorgang.Create();
   vorgang1.internalInvoiceId := 'A';
   vorgang1.amount := 42.0;
   vorgang1.openAmount := 12.0;
   vorgang1.paymentTagetDate := 'B';
   vorgang1.dateOfEntry := 'C';
   vorgang1.paymentDate := 'D';

   vorgang2 := TLimitVorgang.Create();
   vorgang2.internalInvoiceId := 'X';
   vorgang2.amount := 99.9;
   vorgang2.openAmount := -15.5;
   vorgang2.paymentTagetDate := 'Y';
   vorgang2.dateOfEntry := 'Z';
   vorgang2.paymentDate := '?';

   Result := TLimit.Create();
   Result.limit := 44.4;
   Result.freeLimit := 0.1;
   Result.openInvoices := [vorgang1, vorgang2];
end;
  Mit Zitat antworten Zitat
Der schöne Günther

Registriert seit: 6. Mär 2013
5.713 Beiträge
 
Delphi 10 Seattle Enterprise
 
#4

AW: Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

  Alt 2. Sep 2021, 13:24
https://docwiki.embarcadero.com/RADS...ray_Properties
Zitat:
For array properties, access specifiers must list methods rather than fields.
Wobei dynamische Arrays dort nicht erwähnt werden.
Das greift hier nicht, weil er hat streng genommen keine "Array property" - Also das, was man in C# z.B. einen Indexer nennt.
Er hat eine normale Property, deren Typ halt ein Array ist.
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
8.635 Beiträge
 
Delphi 10.4 Sydney
 
#5

AW: Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

  Alt 2. Sep 2021, 13:35
Außerdem interessiert sich TJSON.ObjectToJsonObject gar nicht für die Properties, sondern nur für die Felder.

Ich finde auch, ein konkretes Beispiel zum Nachstellen wäre hilfreich.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
Maliko

Registriert seit: 20. Jun 2019
38 Beiträge
 
Delphi 10.3 Rio
 
#6

AW: Accessviolation bei TJSON.ObjectToJsonObject mit TArray<T>

  Alt 2. Sep 2021, 13:39
Args. Ich hab den Fehler. Es hatte überhaupt nichts mit dem Array an sich zu tun.

Ich benutze folgende Schleife um das Array zu füllen:
Delphi-Quellcode:
while not mQuery.Eof do
begin
  mData := TDiagonalLimitVorgang.Create;

  try
    mData.internalInvoiceId := mQuery.FieldAsString('referenzid');
    mData.amount := mQuery.FieldAsFloat('fakturabetrag');
    mData.openAmount := mQuery.FieldAsFloat('fakturabetragrest');
    mData.paymentTagetDate := TASDateUtils.ConvertDateToInternational(mQuery.FieldAsString('zahlungszieldatum'));
    mData.dateOfEntry := TASDateUtils.ConvertDateToInternational(mQuery.FieldAsString('fakturadatum'));

    if(mData.amount <> mData.openAmount) then
    begin
      mData.paymentDate := TASDateUtils.ConvertDateToInternational(DateToStr(Self.GetPaymentDateByInvoice(mQuery.FieldAsString('mandantid'), mQuery.FieldAsString('vorgangid'), mQuery.FieldAsString('fakturaid'), mQuery.FieldAsString('versionid'))));
    end;

    SetLength(Result, Length(Result) + 1);
    Result[Length(Result) - 1] := mData;
  finally
    FreeAndNil(mData);
  end;

  mQuery.Next;
end;
Was passiert wohl mit dem Objekt im Array wenn ich im finally ankomme? Nachdem ich das FreeAndNil entfernt habe, funktionierte es einwandfrei.
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +2. Es ist jetzt 20:31 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf