AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Programmierung allgemein Programmieren allgemein Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

Ein Thema von Andreas13 · begonnen am 27. Mai 2022 · letzter Beitrag vom 30. Mai 2022
Antwort Antwort
Seite 1 von 2  1 2   
Andreas13

Registriert seit: 14. Okt 2006
Ort: Nürnberg
709 Beiträge
 
Delphi XE5 Professional
 
#1

Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 17:51
Hallo Community,
ich erzeuge zur Laufzeit eine spezielle zweidimensionale dynamische Struktur: Eine dreieckige Matrix gemäß nachfolgendem Demo-Programm. Die Dreieckmatrix wird von der Procedure Make_3EckMatrix(..) erzeugt. Die Procedure PrintMatrixX(..) hilft Euch bei der simplen Visualisierung dieser Struktur.
Delphi-Quellcode:
program _3Eck_Matrix_2;

{$APPTYPE CONSOLE}

{$R *.res}

uses
  System.SysUtils;

Type
  TDynExtendedVektor = TArray<Extended>; // = Array of Extended;
  TMatrix = Array of TDynExtendedVektor;

  
Procedure PrintMatrixX(CONST Matrix: TMatrix; Name: String); Overload;
// Nur zum Debuggen

VAR
  Zeile, Spalte, n_Zeilen, n_Spalten: Integer;

CONST
  Leer = ' ';
  Pad = 6;

Begin
  WriteLn;
  WriteLn(Name + '[', Low(Matrix), '..', High(Matrix), ' ; ', Low(Matrix[0]), '..', High(Matrix[0]), ']');
  WriteLn('--------------------------');

  n_Zeilen:= Length(Matrix);

  For Zeile:= 0 To n_Zeilen - 1 Do
  Begin
    n_Spalten:= Length(Matrix[Zeile]);
    
    For Spalte:= 0 To n_Spalten - 1 Do
    Begin
      Write(Matrix[Zeile, Spalte].ToString.PadLeft(Pad));
      Write(Leer);
    End;
    WriteLn;
  End;
  WriteLn('--------------------------');
  WriteLn;
End;{PrintMatrixX}
{----------------}

Procedure Make_3EckMatrix(VAR DreiEckMatrix: TMatrix;
                              n_Spalten_Max: Integer);
// Dynamische DreiEckMatrix dimensionieren

VAR
  Zeile : Integer;
  Spalten: Integer;

Begin
  SetLength(DreiEckMatrix, N_Spalten_Max, 0); // Zunächst NUR einen Vektor anlegen

  Spalten:= N_Spalten_Max;

  For Zeile:= Low(DreiEckMatrix) To High(DreiEckMatrix) Do
  Begin
    SetLength(DreiEckMatrix[Zeile], Spalten);
    Dec(Spalten);
  End;
End;{Make_3EckMatrix}
{-------------------}

VAR
  n_Spalten_Max: Integer;
  DreiEckMatrix: TMatrix;
  
Begin
  ReportMemoryLeaksOnShutdown:= True;

  Try
    Try
      n_Spalten_Max:= 10;
      WriteLn('n_Spalten_Max = ', n_Spalten_Max);
      
      Make_3EckMatrix(DreiEckMatrix, n_Spalten_Max);
      PrintMatrixX(DreiEckMatrix, 'DreiEckMatrix');

      ReadLn;
     
    Finally
      // DreiEckMatrix:= NIL; // Nicht nötig? Wird anscheinend automatisch freigegeben?
    End;
  Except
    On E: Exception Do
      Writeln(E.ClassName, ': ', E.Message);
  End;
End.
Meine Frage:
Wieso meldet weder ReportMemoryLeaksOnShutdown:= True; noch madExcept einen Speicherleck, wenn ich die dynamische Struktur gar nicht freigebe?

Vorsichtshalber habe ich ein  DreiEckMatrix:= NIL; im Finally-Block hinzugefügt, frage ich mich jedoch, ob nicht eine Speicher-Freigabe analog zum Anlegen via Make_3EckMatrix(..) per For-Schliefe notwendig wäre.

Weiß jemand eine Antwort?
Danke im Voraus!

Viele Grüße
Andreas
Grüße, Andreas
Wenn man seinem Nächsten einen steilen Berg hinaufhilft, kommt man selbst dem Gipfel näher. (John C. Cornelius)
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
10.934 Beiträge
 
Delphi 12 Athens
 
#2

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 18:08
Dynamische Arrays werden bei Verlassen des Scopes automatisch freigegeben.
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
TurboMagic

Registriert seit: 28. Feb 2016
Ort: Nordost Baden-Württemberg
2.772 Beiträge
 
Delphi 12 Athens
 
#3

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 18:10
Also wenn ich's richtig sehe ist da nirgends ein Create in deinem Code, oder?
Dann wird auch kein Objekt irgendwo erzeugt und damit gibt's auch kein Speicherleck weil du dann
nur einen dynamischen Array erzeugst und der wird ja automatisch verwaltet.
  Mit Zitat antworten Zitat
Andreas13

Registriert seit: 14. Okt 2006
Ort: Nürnberg
709 Beiträge
 
Delphi XE5 Professional
 
#4

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 18:22
Ich habe es - noch zu Zeiten von Delphi 5 so gelernt - und dies seither auch stets so gehandhabt, daß jedes mit SetLegth(My_Array, Len) erzeugte dynamische Array am Ende mit My_Array:= NIL; freigegeben werden muß.
Von diesem (für mich neuen) Comfort habe ich bis jetzt nichts mitbekommen...
Danke!
Grüße, Andreas
Grüße, Andreas
Wenn man seinem Nächsten einen steilen Berg hinaufhilft, kommt man selbst dem Gipfel näher. (John C. Cornelius)
  Mit Zitat antworten Zitat
Benutzerbild von dummzeuch
dummzeuch

Registriert seit: 11. Aug 2012
Ort: Essen
1.449 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#5

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 18:45
Ich habe es - noch zu Zeiten von Delphi 5 so gelernt - und dies seither auch stets so gehandhabt, daß jedes mit SetLegth(My_Array, Len) erzeugte dynamische Array am Ende mit My_Array:= NIL; freigegeben werden muß.
Ich erinnere mich nicht, dass das bei Delphi 5 notwendig gewesen wäre. Das mag aber meinem schlechten Gedächtnis geschuldet sein. Ich könnte ja jetzt mein Notebook mit der Delphi 5 Installation rauskramen...
Thomas Mueller
  Mit Zitat antworten Zitat
Andreas13

Registriert seit: 14. Okt 2006
Ort: Nürnberg
709 Beiträge
 
Delphi XE5 Professional
 
#6

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 20:39
Hallo Thomas,
Du magst recht haben. Allerdings konnte ich nach einigem Suchen herausfinden, wo ich das gelernt habe: In einem von mir hochgeschätzten und vielbenutzen Buch:
Doberenz + Gewinnus: Borland Delphi 7: Grundlagen Profiwissen, 2003. S. 93/94.
Bis jetzt hat es meine Programme nicht gestört, wahrscheinlich war es aber, wie Ihr alle schreibt, überflüssig.
Man(n) lernt ja bekanntlich nie aus.
Danke Euch allen!

Viele Grüße
Andreas
Grüße, Andreas
Wenn man seinem Nächsten einen steilen Berg hinaufhilft, kommt man selbst dem Gipfel näher. (John C. Cornelius)
  Mit Zitat antworten Zitat
TurboMagic

Registriert seit: 28. Feb 2016
Ort: Nordost Baden-Württemberg
2.772 Beiträge
 
Delphi 12 Athens
 
#7

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 21:25
Naja, der Code für den Multimedia Timer dieser beiden Herren ist jedenfalls etwas fehlerhaft und nicht wie gezeigt lauffähig...

Soviel zur Schätzung
Aber ja, es gibt schlechtere Bücher...
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.014 Beiträge
 
Delphi 12 Athens
 
#8

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 27. Mai 2022, 22:46
Managed Typen verwaltet Delphi automatisch, also Speicherfreigabe und deswegen auch immer eine autmatische Initialisierung der Variable mit 0 (nil).

Interfaces
Variants
dynamische Arrays
LongStrings (alle Strings außer ShortString, aber der ist ein statisches Array und somit auch automatisch weg)
und neuerdings auch Custom Managed Records (wenn man Initialize und Finalize implementiert hat)
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests
  Mit Zitat antworten Zitat
TiGü
Online

Registriert seit: 6. Apr 2011
Ort: Berlin
3.058 Beiträge
 
Delphi 10.4 Sydney
 
#9

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 30. Mai 2022, 09:24
Bevor du das Rad neu erfindest, schau dir doch auch die Unit System.Math.Vectors an.
Vielleicht ist da was dabei, was du gebrauchen kannst.
Gibt es meines Wissens nach ab Delphi Seattle aufwärts.

https://docwiki.embarcadero.com/Libr...m.Math.Vectors
  Mit Zitat antworten Zitat
Redeemer

Registriert seit: 19. Jan 2009
Ort: Kirchlinteln (LK Verden)
1.010 Beiträge
 
Delphi 2009 Professional
 
#10

AW: Warum wird eine dynamisch erzeugte Matrix scheinbar automatisch freigegeben?

  Alt 30. Mai 2022, 10:32
Ich habe es - noch zu Zeiten von Delphi 5 so gelernt - und dies seither auch stets so gehandhabt, daß jedes mit SetLegth(My_Array, Len) erzeugte dynamische Array am Ende mit My_Array:= NIL; freigegeben werden muß.
Gilt nur für threadvar, oder? Bei threadvar muss man auch Strings leeren.
Janni
2005 PE, 2009 PA, XE2 PA
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 13:21 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz