AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Passwort in Ini-datei speichern

Ein Thema von lucy · begonnen am 6. Nov 2022 · letzter Beitrag vom 9. Nov 2022
Antwort Antwort
Seite 1 von 2  1 2   
lucy

Registriert seit: 25. Okt 2017
63 Beiträge
 
Delphi XE7 Starter
 
#1

Passwort in Ini-datei speichern

  Alt 6. Nov 2022, 14:16
Folgendes Problem beim Verschlüsseln:

Delphi-Quellcode:
procedure TForm1.Button1Click(Sender: TObject);
var
  Ini: TIniFile;
    s: String[255];
    c: array[0..255] of Byte absolute s;
    i: Integer;
begin
  Ini:=TIniFile.Create(ExtractFilePath(ParamStr( 0 )) + '\settings.ini');
  try
     s := Edit4.Text;
     for i := 1 to Length(s) do s[i] := Char(23 xor Ord(c[i])); // das Problem ist Char
    Ini.WriteString('mySQl', 'Server', Edit1.Text);
    Ini.WriteString('mySQl', 'Port', Edit2.Text);
    Ini.WriteString('mySQl', 'User', Edit3.Text);
    Ini.WriteString('mySQl', 'Passwort', s);
    Ini.WriteString('mySQl', 'Datenbank', Edit5.Text);
  finally
    Ini.Free;
  end;
end;
Miniaturansicht angehängter Grafiken
fehler.jpg  
  Mit Zitat antworten Zitat
Benutzerbild von Bernhard Geyer
Bernhard Geyer

Registriert seit: 13. Aug 2002
17.169 Beiträge
 
Delphi 10.4 Sydney
 
#2

AW: Passwort in Ini-datei speichern

  Alt 6. Nov 2022, 14:37
Unverschlüsselt speichern ist immer eine schlechte Idee!
XOR ist keine Verschlüsselung!
Windows Vista - Eine neue Erfahrung in Fehlern.
  Mit Zitat antworten Zitat
EdAdvokat

Registriert seit: 1. Mai 2016
Ort: Berlin
414 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#3

AW: Passwort in Ini-datei speichern

  Alt 6. Nov 2022, 15:22
mach mal aus dem s : string[255]; ein string.
Norbert
  Mit Zitat antworten Zitat
Benutzerbild von himitsu
himitsu

Registriert seit: 11. Okt 2003
Ort: Elbflorenz
43.017 Beiträge
 
Delphi 12 Athens
 
#4

AW: Passwort in Ini-datei speichern

  Alt 6. Nov 2022, 15:46
mach mal aus dem s : string[255]; ein string.
Nein.

Man beachte das absolute.
Wenn, dann muß man noch mehr umbauen.


Problem ist hier, dass seit Delphi 2009 der String Unicode ist,
aber der Typ String[x] blieb weiterhin ANSI.

Auch bei der Ver-/Entschlüsselung von Zeichen über #127 (kein ASCII) kommt eventuell was Falsches raus, wenn man es einfach so auf Unicode umstellt. (2 Byte statt 1 Byte)

Delphi-Quellcode:
s := AnsiString(Edit4.Text);
for i := 1 to Length(s) do s[i] := AnsiChar(23 xor Ord(c[i])
Garbage Collector ... Delphianer erzeugen keinen Müll, also brauchen sie auch keinen Müllsucher.
my Delphi wish list : BugReports/FeatureRequests

Geändert von himitsu ( 6. Nov 2022 um 18:16 Uhr)
  Mit Zitat antworten Zitat
lucy

Registriert seit: 25. Okt 2017
63 Beiträge
 
Delphi XE7 Starter
 
#5

AW: Passwort in Ini-datei speichern

  Alt 6. Nov 2022, 17:50
Zitat:
Nein.

Man beachte das absolute.
Wenn, dann muß man noch mehr umbauen.


Problem ist hier, dass seit Delphi 2009 der String Unicode ist,
aber der Typ String[x] blieb weiterhin ANSI.

Auch bei der Ver-/Entschlüsselung von Zeichen über #127 (kein ASCII) kommt eventuell was Falsches raus, wenn man es einfach so auf Unicode umstellt. (2 Byte statt 1 Byte)
es funktioniert, danke
  Mit Zitat antworten Zitat
DaCoda

Registriert seit: 21. Jul 2006
Ort: Hamburg
73 Beiträge
 
Delphi 12 Athens
 
#6

AW: Passwort in Ini-datei speichern

  Alt 8. Nov 2022, 16:27
Also XOR ist nicht gerade schön und wirklich nicht zu empfehlen.
Wenn es minimale Sicherheit sein soll, dann würde ich das eventuell so machen:

Delphi-Quellcode:
const
  Code64 = '0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz+/';

function Encode64(S: string): string;
function Decode64(S: string): string;

{-------------------------------------------------------------------------------}

function Encode64(S: string): string;
var
  I: Integer;
  a: Integer;
  x: Integer;
  b: Integer;
begin
  Result := '';
  a := 0;
  b := 0;
  for I := 1 to Length(S) do begin
      x := Ord(S[I]);
    b := b * 256 + x;
    a := a + 8;
    while a >= 6 do begin
      a := a - 6;
      x := b div (1 shl a);
      b := b mod (1 shl a);
      Result := Result + Code64[x + 1];
    end;
  end;
  if a > 0 then begin
      x := b shl (6 - a);
    Result := Result + Code64[x + 1];
  end;
end;

function Decode64(S: string): string;
var
  I: Integer;
  a: Integer;
  x: Integer;
  b: Integer;
begin
  Result := '';
  a := 0;
  b := 0;
  for I := 1 to Length(S) do begin
    x := Pos(S[I], Code64) - 1;
    if x >= 0 then begin
        b := b * 64 + x;
      a := a + 6;
      if a >= 8 then begin
          a := a - 8;
        x := b shr a;
        b := b mod (1 shl a);
        x := x mod 256;
        Result := Result + chr(x);
      end;
    end else
      Exit;
  end;
end;
Debuggers don’t remove bugs, they only show them in slow-motion.
  Mit Zitat antworten Zitat
stifflersmom

Registriert seit: 8. Dez 2005
Ort: 24994 Holt
370 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#7

AW: Passwort in Ini-datei speichern

  Alt 9. Nov 2022, 12:09
Ich möchte hier auf Synopse verweisen.

Code:
unit uSimpleEncryption;


interface

uses SynCommons, SynCrypto;

function encrypt(aString:String):String;
function decrypt(aString:String):String;

implementation

const
  my_key = 'derVerschLuessElLungsKeyimmerWiederNett';

function encrypt(aString:String):String;
var
  key : TSHA256Digest;
  aes : TAESCFB;
  s:RawByteString;
begin
  SynCommons.HexToBin(Pointer(SHA256(my_key)), @key, 32);

  aes := TAESCFB.Create(key, 256);
  try
    s := StringToUTF8(aString);
    s := BinToBase64(aes.EncryptPKCS7(s, True));
    Result := UTF8ToString(s);
  finally
    aes.Free;
  end;
end;


function decrypt(aString:String):String;
var
  key : TSHA256Digest;
  aes : TAESCFB;
  s:RawByteString;
begin
  SynCommons.HexToBin(Pointer(SHA256(my_key)), @key, 32);

   aes := TAESCFB.Create(key, 256);
  try
    s := StringToUTF8(aString);
    s := aes.DecryptPKCS7(Base64ToBin(s), True);
    Result := UTF8ToString(s);
  finally
    aes.Free;
  end;
end;

end.
Und dann nutzen mit
Code:
 Encrypt(sApiPassword);
bzw.
Code:
Decrypt(sEncryptedString);
  Mit Zitat antworten Zitat
Andreas13

Registriert seit: 14. Okt 2006
Ort: Nürnberg
709 Beiträge
 
Delphi XE5 Professional
 
#8

AW: Passwort in Ini-datei speichern

  Alt 9. Nov 2022, 13:27
Ich möchte hier auf Synopse verweisen...
Du meinst bestimmt Synapse, nehme ich an: https://github.com/dimmaq/delphi-synapse.
Grüße, Andreas
Grüße, Andreas
Wenn man seinem Nächsten einen steilen Berg hinaufhilft, kommt man selbst dem Gipfel näher. (John C. Cornelius)
  Mit Zitat antworten Zitat
stifflersmom

Registriert seit: 8. Dez 2005
Ort: 24994 Holt
370 Beiträge
 
Delphi 10.2 Tokyo Professional
 
#9

AW: Passwort in Ini-datei speichern

  Alt 9. Nov 2022, 13:33
Uuups, man sollte die Brille beim Schreiben aufsetzen...

https://synopse.info
  Mit Zitat antworten Zitat
Andreas13

Registriert seit: 14. Okt 2006
Ort: Nürnberg
709 Beiträge
 
Delphi XE5 Professional
 
#10

AW: Passwort in Ini-datei speichern

  Alt 9. Nov 2022, 13:46
Danke für die Richtigstellung und den korrekten Link! Ich habe nur die Version mit a gekannt.
Grüße, Andreas
Grüße, Andreas
Wenn man seinem Nächsten einen steilen Berg hinaufhilft, kommt man selbst dem Gipfel näher. (John C. Cornelius)
  Mit Zitat antworten Zitat
Antwort Antwort
Seite 1 von 2  1 2   

Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 23:08 Uhr.
Powered by vBulletin® Copyright ©2000 - 2024, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2023 by Daniel R. Wolf, 2024 by Thomas Breitkreuz