Bitte um Hilfe für Webservice/Gateway/PortListener

[Jumpy]

Service erstellen, einfache Variante:
Datei->Neu->Service-Anwendung

Die Ide erstellt den Rumpf des Programms.
Der TService hat eine Art Form, ist keine richtige Form, aber darauf kann man Komponenten klatschen, z.B. die HttpServer-Komponente von den Indys: IdHttoServer.

Dann ein paar Events des Services einrichten, z.B.:

Delphi-Quellcode:

//----------------------------------------------------------------------
// Service-Events
//----------------------------------------------------------------------

//Damit der Service in der Liste der Dienste
//auch eine vernünftige Beschreibung bekommt:
procedure TPortaleSperrenServer.ServiceAfterInstall(Sender: TService);
var
  Reg: TRegistry;
begin
  Reg := TRegistry.Create(KEY_READ or KEY_WRITE);
  try
    Reg.RootKey := HKEY_LOCAL_MACHINE;
    if Reg.OpenKey('\SYSTEM\CurrentControlSet\Services\' + Name, false) then
    begin
      Reg.WriteString('Description', ServiceDescription);
      //ServiceDescription ist eine String-Konstante mit der Beschr.
      Reg.CloseKey;
    end;
  finally
    Reg.Free;
  end;
end;

procedure TPortaleSperrenServer.ServiceStart(Sender: TService; var Started: Boolean);
begin
  CoInitialize(nil); //Brauch ich wg. Datenbankzugriffen, kann ggf. weg
  //Kann man im Prinzip alles reinmachen, was man sonst vllt.
  //bei Form Create reinmachen würde
end;

procedure TPortaleSperrenServer.ServiceExecute(Sender: TService);
begin
  //Hier auch:
  //Kann man im Prinzip alles reinmachen, was man sonst vllt.
  //bei Form Create reinmachen würde
  Server.Port:=5555;
  SA_Waitlist:=TStringlist.Create;
  Server.Open;

  //Nun die Schleife, in der der Eigentliche Service Thread läuft
  try
    while not Terminated do
      begin
      ServiceThread.ProcessRequests(true); //false
      //Sleep(10);
      end;
  except on E:Exception do
    begin
    LogEvent('Server als Dienst','Letzte Nachricht','',e.Message);
    end;
  end;
end;

procedure TPortaleSperrenServer.ServicePause(Sender: TService; var Paused: Boolean);
begin
  ServerSocket.Close;
end;

procedure TPortaleSperrenServer.ServiceContinue(Sender: TService; var Continued: Boolean);
begin
  Server.Open;
end;

procedure TPortaleSperrenServer.ServiceStop(Sender: TService; var Stopped: Boolean);
begin
  Server.Close;
  if SA_WaitList <> nil then SA_WaitList.Free;
  CoUnInitialize;
end;

procedure TPortaleSperrenServer.ServiceShutdown(Sender: TService);
begin
  Server.Close;
  if SA_WaitList <> nil then SA_WaitList.Free;
  CoUnInitialize;
end;

//----------------------------------------------------------------------
// HTTPServer-Events
//----------------------------------------------------------------------
//Einkommende Sendungen vom Programm A:
procedure TMain.HTTPServerCommandGet(AThread: TIdPeerThread;
  RequestInfo: TIdHTTPRequestInfo; ResponseInfo: TIdHTTPResponseInfo);
begin
  //Die direkte weiterleitung der Daten 
  if HTTPRedirect then Redirect(RequestInfo.UnparsedParams);
  //Wenn A eine Antwort braucht, das alles angekommen ist:
  if HTTPResponse then
    begin
    ResponseInfo.ResponseNo:=200;
    ResponseInfo.ResponseText:='OK';
    ResponseInfo.WriteContent;
    end;
  //(HTTPRedirect,HTTPResponse = Boolche Konstante):

  //Zur weiterbearbeitung der Daten:
  EvalCallInfo(RequestInfo.Params.Values['event'],
               RequestInfo.Params.Values['date'],
               RequestInfo.Params.Values['src_if'],
               RequestInfo.Params.Values['src_cgpn'],
               RequestInfo.Params.Values['src_cdpn'])
end;

//Die Funktion, um die Daten direkt weiterzusenden.
//Damit könnte man natürlich auch veränderte Daten senden.
//Benutzt wird ein IdHTTP-Client, der immer neu erzeugt wird,
//keine Ahnung, warum das nicht mit einer globalen Kompo gemacht wird
procedure TMain.Redirect(const Params: String);
var
  url:String;
  HTTP: TIdHTTP;
begin
  url:='http://'+RedirectIP+':'+RedirectHost+'/?'+Params;
  HTTP:=TIdHTTP.Create(self);
  try
    HTTP.Get(url);
  finally
    HTTP.Free;
  end;
end;

Hoffe das hilft als start!

[mjustin]

Zitat von Jumpy:

Service erstellen, einfache Variante

Im Falle eines Indy Servers im Service kann man in ServiceStart Server.Active auf True setzen und bei Stop auf False. Das ServiceExecute kann dann eigentlich wegfallen.

Quellen wie zum Beispiel http://stackoverflow.com/questions/1...service-design (die Antwort enthält den Code für ein Service-Grundgerüst) empfehlen statt ServerExecute, einen eigenen Thread zu starten. Im Falle eines einfachen Indy HTTP Servers wäre das dann dessen Threadpool.

Ich schlage vor einen Eintrag für einen Mini-HTTP Server Service in die Code Library zu stellen

[DeddyH]

[OT] Kleiner Hinweis:

Zitat:

if SA_WaitList <> nil then SA_WaitList.Free;

ist doppeltgemoppelt, da Free selbst auf nil prüft. Das ist auch der Grund, wieso man immer Free statt Destroy aufrufen soll. [/OT]

[Jumpy]

Zitat von DeddyH:

[OT] Kleiner Hinweis:

Zitat:

if SA_WaitList <> nil then SA_WaitList.Free;

ist doppeltgemoppelt, da Free selbst auf nil prüft. Das ist auch der Grund, wieso man immer Free statt Destroy aufrufen soll. [/OT]

Also egal, ob SA_WaitList
- nie erzeugt wurde (kann hier in dem Bsp. nicht sein, aber generell?) oder
- ob es schon vorher freigegeben wurde,
SA_WaitList.Free funktioniert?

[DeddyH]

Wenn es freigegeben und auf nil gesetzt oder mit nil initialisiert und nie instanziert wurde, richtig.

[Jumpy]

[OT] Kurzes Thread-Hijacking, da es hier aufkam:

Zitat von DeddyH:

Wenn es freigegeben und auf nil gesetzt oder mit nil initialisiert und nie instanziert wurde, richtig.

Nochmal nachgehakt. Wenn ich es nie instanziere und auch vorher nicht mit nil initialisiere, dann würde es kanllen?

Delphi-Quellcode:

var t:TStringlist;
begin
try
  Irgendwas, das eine Exception auslöst;
  t:=TStringlist.Create;
  Irgendwas anderees mit t;
finally
  t.Free;
end;
end;

Hier t nie erzeugt, da es schon vorher knallt, wird aber im finally freigegeben?

Delphi-Quellcode:

var t:TStringlist;
begin
t:=TStringlist.Create;
try
  Irgendwas, das eine Exception auslöst;
  Irgendwas anderees mit t;
finally
  t.Free;
end;
end;

Hier ist t vor der exception erzeugt worden und kann freigegeben werden?

[/OT]

[Bali]

oh je oh je ....

habe gestern den ganzen Tag mit euren Posts getestet ... und habe es leider nicht geschafft ...

Werde jetzt dann den ZIP file von BUMMI testen und mich dann wieder melden.

Dankeschön für all euren Support !

Tobi

[Sir Rufo]

Zitat von Jumpy:

[OT] Kurzes Thread-Hijacking, da es hier aufkam:

Zitat von DeddyH:

Wenn es freigegeben und auf nil gesetzt oder mit nil initialisiert und nie instanziert wurde, richtig.

Nochmal nachgehakt. Wenn ich es nie instanziere und auch vorher nicht mit nil initialisiere, dann würde es kanllen?

Delphi-Quellcode:

var t:TStringlist;
begin
try
  Irgendwas, das eine Exception auslöst;
  t:=TStringlist.Create;
  Irgendwas anderees mit t;
finally
  t.Free;
end;
end;

Hier t nie erzeugt, da es schon vorher knallt, wird aber im finally freigegeben?

Delphi-Quellcode:

var t:TStringlist;
begin
t:=TStringlist.Create;
try
  Irgendwas, das eine Exception auslöst;
  Irgendwas anderees mit t;
finally
  t.Free;
end;
end;

Hier ist t vor der exception erzeugt worden und kann freigegeben werden?

[/OT]

Genau so ... denn lokale Variablen werden nicht automatisch initialisiert wie globale oder Klassen-Variablen

Allerdings, wenn man sich das so ansieht, scheinst du hier doch eine globale Variable definiert zu haben

Delphi-Quellcode:

var
  globalSL : TStrings;

procedure Foo;
var
  localSL : TStrings;
begin
  // lokale Variablen sollten initialisiert werden
  // localSL := nil;
  try
    ...
    // mögliche Exception
    ...
    globalSL := TStringList.Create;
    localSL := TStringList.Create;
    ...
  finally
    globalSL.Free;
    localSL.Free; // mögliche Exception!!!
  end;
end;

[Jumpy]

Zitat von mjustin:

Zitat von Jumpy:

Service erstellen, einfache Variante

Bezog sich darauf, die entsprechenden VCL-Dinge zun nutzen. Es gibt z.B. ja auch aufwendigere Varianten, wo man alles selbst macht, wie z.B. in dem Tutorial vom Delphi-Treff.

Muss auch gestehen, dass in obigem Code, 2 Programme gemixt sind. Der Service nutzt eigentlich nur eine ServerSocket-Komponente. Das mit dem HTTP-Server ist aus einem anderen Programm. Darum ist das da glaub ich ins Execute gepackt worden. Oder läuft eine ServerSocket auch in einem eigenen Threadpool?

Die Empfehlung da generell einen eigenen Thread zu nehmen und beim Service-Start zu starten, hab ich auch von anderen hier (Bummi?) schon öfter gelesen, aber ich hab immer noch Respekt vor eigenen Threads, Kollisionen usw. Einfach zu wenig Gelegenheit das bisher mal einsetzen zu müssen, deswegen die "einfache" Variante, wo einem alles vorbereitet wird.