AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

Objekt erstellen

Offene Frage von "Bummi"
Ein Thema von LucaH97 · begonnen am 22. Sep 2013 · letzter Beitrag vom 22. Sep 2013
Antwort Antwort
LucaH97

Registriert seit: 22. Sep 2013
2 Beiträge
 
#1

Objekt erstellen

  Alt 22. Sep 2013, 16:10
Delphi-Version: 7
Hallo Delphi-Praxis Mitglieder!
Ich programmiere seit einiger Zeit in Delphi und habe einige Sachen, die ich nicht verstehe:
Ich möchte ein leines Spiel machen, eins in der art von Space Invaders, allerdings weiß ich
nicht, wie ich eine eigene Objekt Klasse für den Schuss erstelle. Zum bespiel ein TSchuss,
der, wenn ein objekt dieses Types aufgerufen wird, ein kleines Rechteck erzeugt, dass man
mit einem Timer nach oben fliegen lässt. Momentan kann man den Spieler schon bewegen, aber sonst
auch nichts:

Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls;

type
  TForm1 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    Timer1: TTimer;
    CircleCursor: TShape;
    Player: TShape;
    procedure Timer1Timer(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.Timer1Timer(Sender: TObject);
var p: TPoint;
begin
p := Mouse.CursorPos;
p := ScreenToClient(p);
Label1.Caption := IntToStr(p.X);
Label2.Caption := IntToStr(p.Y);

CircleCursor.Left := P.X;
CircleCursor.Top := P.Y;

if p.X < (Player.Left + round(Player.Width/2)) then
  begin
    Player.Left := Player.Left - 2;
  end;

if p.X > (Player.Left + round(Player.Width/2)) then
  begin
    Player.Left := Player.Left + 2;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
ShowCursor(false);
end;

end.

Kann mir jeamnd sagen, wie man ein solches Objekt oder eine solche klasse erstellt, und ein Objekt dieser Klasse beliebig oft aufrufen kann?
  Mit Zitat antworten Zitat
Benutzerbild von Bummi
Bummi

Registriert seit: 15. Jun 2010
Ort: Augsburg Bayern Süddeutschland
3.470 Beiträge
 
Delphi XE3 Enterprise
 
#2

AW: Objekt erstellen

  Alt 22. Sep 2013, 17:08
Ich würde nicht mit visuellen Controls wie Shapes arbeiten, sondern alle Objekte in einer Liste verwalten und z.B. im OnPaint des Formulares oder eine PaintBox malen.
Da Du aber bereits einen Ansatz hast, habe ich hier eine Beispiel wie es auf diese Art weitergehen könnte. Die einzige Besonderheit ist eigentlich die Freigabe der Objekte über eine Message, die per Postmessage abgeschickt wird, um ein Zerstören des Objekt innerhalb der Behandlungsroutinen des Objekts zu verhindern.

Delphi-Quellcode:
unit Unit2;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, TeEngine, ExtCtrls, TeeProcs, Chart;

const
  WM_KILL=WM_User + 123;
type
  TSchuss=Class(TShape)
   public
    Procedure NextStep(CollCheck:TShape);
    Constructor Create(AOwner:TComponent;aParent:TWinControl;x,y:Integer);Overload;
  End;

  TForm2 = class(TForm)
    Label1: TLabel;
    Label2: TLabel;
    CircleCursor: TShape;
    Player: TShape;
    Timer1: TTimer;
    procedure Timer1Timer(Sender: TObject);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
  private
    { Private-Deklarationen }
    Procedure WMKILL(var MSG:TMessage);message WM_KILL;
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
begin
  TSchuss.Create(self,self,Player.left,Player.Top);
  Caption := DateTimeToStr(now);
end;

procedure TForm2.Timer1Timer(Sender: TObject);
var p: TPoint;
    i:Integer;
begin
p := Mouse.CursorPos;
p := ScreenToClient(p);
Label1.Caption := IntToStr(p.X);
Label2.Caption := IntToStr(p.Y);

CircleCursor.Left := P.X;
CircleCursor.Top := P.Y;

if p.X < (Player.Left + round(Player.Width/2)) then
  begin
    Player.Left := Player.Left - 2;
  end;

if p.X > (Player.Left + round(Player.Width/2)) then
  begin
    Player.Left := Player.Left + 2;
  end;
 for I := 0 to ControlCount - 1 do
    if Controls[i] is TSchuss then
        TSchuss(Controls[i]).NextStep(CircleCursor);
end;

procedure TForm2.WMKILL(var MSG: TMessage);
begin
  TObject(MSG.WParam).Free;
end;

{ TSchuss }

constructor TSchuss.Create(AOwner:TComponent;aParent:TWinControl;x,y:Integer);
begin
   inherited Create(Aowner);
   Parent := aParent;
   Width := 10;
   Height := 10;
   Brush.Color := clBlack;
   Left := x;
   Top := y;
end;

procedure TSchuss.NextStep(CollCheck:TShape);
var
 hit:Boolean;
 r:TRect;
begin
  Top := Top - 5;
  hit := InterSectRect(r,BoundsRect,CollCheck.BoundsRect);
  if hit or (Top+Height < 0) then PostMessage(Parent.handle,WM_KILL,Integer(self),0);
  if Hit then CollCheck.Brush.Color := clRed;

end;

end.
Thomas Wassermann H₂♂
Das Problem steckt meistens zwischen den Ohren
DRY DRY KISS
H₂ (wenn bei meinen Snipplets nichts anderes angegeben ist Lizenz: WTFPL)
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 07:01 Uhr.
Powered by vBulletin® Copyright ©2000 - 2021, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2021 by Daniel R. Wolf