AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren
Zurück Delphi-PRAXiS Sprachen und Entwicklungsumgebungen Sonstige Fragen zu Delphi Delphi Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

Ein Thema von Friday · begonnen am 30. Jan 2020 · letzter Beitrag vom 30. Jan 2020
Antwort Antwort
Friday

Registriert seit: 6. Mai 2008
53 Beiträge
 
Delphi XE3 Professional
 
#1

Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

  Alt 30. Jan 2020, 12:30
Hallo,
ich habe eine
IList<IMyIntf> nun möchte ich diese Liste nach bestimmten Eigenschaften filtern, wozu ich diese Liste einer Funktion als Parameter übergebe und als Rückgabewert wieder eine IList<IMyIntf> bekomme / bekommen möchte.
Delphi-Quellcode:
function FilterNachBlau(aList: IList<IMyIntf>): IList<IMyIntf>;
begin
  Result := IList<IMyIntf>(aList.Where(function(const aMyIntf: IMyIntf): boolean
                          begin
                            Result := aMyIntf.InnerColor = clBlau;
                          end);
end;
Den Typecast ist notwendig da die Where Methode ein IEnumerable zurück gibt. Da IList von IEnumerable abgeleitet ist, sollte es keine Schwierigkeiten geben.

Der Debugger sagt mir nun aber dass der zurück gelieferte Typ "TWhereIterator" ist.
Und sobald ich auf die zurück gelieferte IList (die wohl keine IList ist) zugreife, kommt eine Exception "privileged instruction at 0x00e638e2"

Was mache ich falsch, bzw. geht das filtern auch anders? (natürlich ginge es in einer for schleife alles einzeln durchzugehen, das sollte aber nicht Sinn der Sache sein)

danke
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
3.683 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#2

AW: Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

  Alt 30. Jan 2020, 12:43
Da IList von IEnumerable abgeleitet ist, sollte es keine Schwierigkeiten geben.
Falsch - nur weil eine Banane eine Frucht ist, ist nicht jede Frucht eine Banane.
Das Ergebnis von Where ist eine verzögert ausgeführte Sequenz und nicht eine auf das Filterprädikat gefilterte Liste, wo ich auch wieder Dinge hinzufügen kann.
Die Where Methode ist von IEnumerable<T>, wovon IList<T> erbt und diese somit auch bereitstellt.

Ändere den Ergebnistyp von FilterNachBlau auf IEnumerable<IMyIntf>.
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight
  Mit Zitat antworten Zitat
Friday

Registriert seit: 6. Mai 2008
53 Beiträge
 
Delphi XE3 Professional
 
#3

AW: Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

  Alt 30. Jan 2020, 13:07
das stimmt natürlich...

danke, mit IEnumerable geht es wie gewünscht.

Wenn man nun dennoch aus IEnumerable eine IList machen wollen würde, ginge das nur mit durchiterieren, sprich
Delphi-Quellcode:
for i := 0 to IEnumerable.count-1 do
  IList.Add(IEnumerable.ElementAt(i);
?
  Mit Zitat antworten Zitat
Benutzerbild von Stevie
Stevie

Registriert seit: 12. Aug 2003
Ort: Soest
3.683 Beiträge
 
Delphi 10.1 Berlin Enterprise
 
#4

AW: Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

  Alt 30. Jan 2020, 13:25
Arg, bitte nicht so - ein IEnumerable ist eine Sequenz - ja, die hat Count und ElementAt aber das macht sie nicht zu einer Liste, auf die mit O(1) auf einzelne Elemente zugegriffen werden kann.
Wenn du bei einem IEnumerable, was das Ergebnis eines Where Aufrufs ist, auf Count zugreifst, wird die komplette Ausgangsmenge genommen und auf jedes Element das in Where übergebene predicate angewandt. Greifst du dann auf ElementAt zu, wird das wieder gemacht, bis zu der Stelle. Und beim nächsten wieder. Damit erzeugst du dir einen O(n²) Algorithmus.

Wenn du das Ergebnis einer Sequenz in einer neuen Liste materialisieren möchtest, dann füg sie am besten per AddRange hinzu.
Delphi-Quellcode:
var
  neueListe: IList<IMyIntf>;
begin
  neueListe := TCollections.CreateList<IMyIntf>;
  neueListe.AddRange(FilterNachBlau(alteListe));
Um zu veranschaulichen, was hinter dem Where (und vielen anderen Methoden) steckt, mal ein Beispiel:

Delphi-Quellcode:
var
  nummern: IList<Integer>;
  geradeNummern1: IEnumerable<Integer>;
  geradeNummern2: IList<Integer>;
  i: Integer;
begin
  nummern := TCollections.CreateList<Integer>([1, 2, 3, 4, 5, 6, 7]);
  geradeNummern1 := nummern.Where(function(const x: Integer): Boolean begin Result := x mod 2 = 0 end);
  geradeNummern2 := TCollections.CreateList<Integer>;
  geradeNummern2.AddRange(geradeNummern1);

  nummern.AddRange([8, 9, 10]);

  for i in geradeNummern1 do
    Writeln(i);

  for i in geradeNummern2 do
    Writeln(i);
Hier wird bei der ersten Schleife 2 4 6 8 10 kommen und bei der zweiten 2 4 6.
Das liegt daran, dass hinter dem von Where zurückgelieferten IEnumerable keine materialisierte Datenmenge sondern eine Sequenz oder Query liegt, die verzögert und "on-demand" materialisiert. Und dann auch jedes mal zu dem Zeitpunkt, wenn ich sie iteriere oder Informationen abfrage, die das erfordern. Somit hast du dann immer die aktuellen Werte aus der Datenmenge auf die du das aufgerufen hast.
Stefan
“Simplicity, carried to the extreme, becomes elegance.” Jon Franklin

Delphi Sorcery - DSharp - Spring4D - TestInsight
  Mit Zitat antworten Zitat
Friday

Registriert seit: 6. Mai 2008
53 Beiträge
 
Delphi XE3 Professional
 
#5

AW: Spring4D Collections: IList.Where gibt ein TWhereIterator zurück

  Alt 30. Jan 2020, 14:11
Danke, wieder was gelernt
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 07:58 Uhr.
Powered by vBulletin® Copyright ©2000 - 2020, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf