Eklatante Probleme mit Debuggen

[jaenicke]

Zitat von bobokonijn:

Was für mich gut funktioniert in solchen Fällen ist den Debugger erst *nach* Programmstart mit dem Programm zu verbinden (Run-> Attach To Process). Ggf muss man im Programm eine Messagebox einbauen damit das Programm absichtlich anhält und man die Zeit hat, den Debugger zu verbinden.

Oder:

Delphi-Quellcode:

while not  IsDebuggerPresent do
  Sleep(10);

Das funktioniert auch bei Diensten.

[dummzeuch]

Zitat von jaenicke:

Zitat von bobokonijn:

Was für mich gut funktioniert in solchen Fällen ist den Debugger erst *nach* Programmstart mit dem Programm zu verbinden (Run-> Attach To Process). Ggf muss man im Programm eine Messagebox einbauen damit das Programm absichtlich anhält und man die Zeit hat, den Debugger zu verbinden.

Oder:

Delphi-Quellcode:

while not  IsDebuggerPresent do
  Sleep(10);

Das funktioniert auch bei Diensten.

Interessante Methode, aber sie birgt die Gefahr, dass man einfacher vergessen kann, es wieder zu löschen. Dann wundert man sich, weshalb das Programm hängt, kann das aber im Debugger nicht nachvollziehen, und sucht sich einen Wolf, nur um am Ende mit dem Kopf auf der Tischkante zu landen, wenn man seine Dummheit bemerkt hat.

[jaenicke]

Das ist natürlich richtig, aber wenn man alle Änderungen überprüft und z.B. vor und nachher ein paar Leerzeilen und/oder eine Compilerwarnung einfügt, kann das kaum passieren.

Im Dienst fällt mir z.B. gar keine andere sinnvolle Variante ein, wenn man den Start des Dienstes debuggen möchte.

[himitsu]

Da der normale Code des TService sofort wieder stoppt, wenn das Programm nicht aus dem Service-Host gestartet wird, hatte ich den Code mal etwas nachgebaut.
Dann noch ein kleines Dummy-Fenster, damit man den Dienst "sieht" und was Einfaches zum Beenden hat.

Somit lässt es sich auch einfach über Debugger oder normals starten. (beim Kunden auch mal "manuell" und mit einigen Logausgaben im Consolenfenster, falls es dort mal wieder Probleme beim Starten gibt)
Wenn nur über Debugger, dann ginge auch IsDebuggerPresent, aber hier einfach mit einem Parameter gelöst, damit es auch einzeln starten kann.


Das TService vom Windows ist eh etwas "beschränkt".
z.B. läßt sich der Dienst nur einmal registrieren&installieren (außer man schmuggelt z.B. noch einen Start-Parameter mit rein)

[MyRealName]

Beim Service gibt es doch diesen DDService, der noch mehr Methoden als TService implementiert, den kann man auch debuggen...

[himitsu]

Ist jetzt schon über 10 Jahre her, aber im Grunde ging es darauf hinaus, jenes SvcMgr.Application.Run nachzubauen, damit es eben nicht mehr abbricht, wenn nicht als Dienst gestartet.
Falls ich nichts vergessen oder zu viel rausgelöscht habe.

ServiceExecute läuft eigentlich in einem Thread und könnte man dort noch ein CreateAnonymusThread drumrummachen, aber hatte ich mir zum einfacheren Debuggen damals erspart.

Delphi-Quellcode:

procedure TMyService.ServiceCreate(Sender: TObject);  // TService.OnCreate
var
  Started:     Boolean;
  DebugWindow: TForm;
begin
  FIsDebugging := IsDebuggerPresent or FindCmdLineSwitch('DEBUG', ['-', '/'], True);

  // Das war der Teil, damit es sich mit der Console verbindet und man dann einfach z.B. via WriteLn('log message'); was ausgeben kann.
  // Oder z.B. noch ein Memo ins DebugWindow.
  // Gebe in die Console, sowie ins Windows-EreignisLog, eh nur wichtigsten Stati aus, damit der Admin vor Ort einen Überblick bekommt (der Rest in normale Logdateien)
  if FIsDebugging then
    AttachConsole(ATTACH_PARENT_PROCESS);

  try
    if FIsDebugging then begin
      MyService := Self;  // wird sonst von Application.CreateForm gesetzt, aber durch die Messageloop kommt es dort nicht vorbei

      Forms.Application.MainFormOnTaskBar := False;      // geht leider doch nicht ohne Form
      Forms.Application.CreateForm(TForm, DebugWindow);  // Form zum Beenden und für Eintrag in Taskbar
      DebugWindow.Name         := 'DebugWindow';
      DebugWindow.Caption      := 'Debug-Mode: ' + DM1.DSDisplayName + GenerateViewID(True);
      DebugWindow.OnCloseQuery := DebugServiceClose;
      DebugWindow.Width        := 500;
      DebugWindow.Height       := 125;
      DebugWindow.Visible      := True;
      with TButton.Create(DebugWindow) do begin
        Name    := 'DebugWindowsClose';
        Parent  := DebugWindow;
        Caption := 'Close';
        Width   := 100;
        OnClick := DebugServiceClose2;
      end;

      { SvcMgr.Application.Run;  // bricht ab, wenn nicht als Service gestartet, darum dessen Code hier nachgebaut }
      if FindCmdLineSwitch('INSTALL', ['-', '/'], True) then begin
        TServiceApplicationAccess(SvcMgr.Application).RegisterServices(True, FindCmdLineSwitch('SILENT', ['-', '/'], True));
      end else if FindCmdLineSwitch('UNINSTALL', ['-', '/'], True) then begin
        TServiceApplicationAccess(SvcMgr.Application).RegisterServices(False, FindCmdLineSwitch('SILENT', ['-', '/'], True));
      end else begin
        Started := True;
        ServiceStart(Self, Started);
        if Started then begin
          ServiceExecute(nil);  // der Service-Thread existiert/läuft nicht, wenn die EXE nicht aus der Service-Verwaltung gestartet wurde, daher manueller Aufruf, um die BackgroundThreads zu starten
          while not Terminated and not Forms.Application.Terminated do
            try
              Forms.Application.ProcessMessages;
              Sleep(10);
            except
              {error logging ...}
            end;
          Forms.Application.Terminate;
          for i := 1 to 30 do begin   // Bissl warten, damit sich die BackgroundThreads sich noch rechtzeitig beenden können.
            (DebugWindow.FindComponent('DebugWindowsClose') as TButton).Caption := Format('Terminate (%ds)', [31 - i]);
            Forms.Application.ProcessMessages;
            Sleep(1*MSecsPerSec);
          end;
          try DebugWindow.Free; except end;
        end else begin
          Forms.Application.Terminate;
        end;
      end;
    end;
  except
    on E: Exception do begin
      if ExitCode = 0 then
        ExitCode := 38;  // Fehlercode für IF ERRORLEVEL im aufrufenden Batch
      raise;
    end;
  end;
end;

procedure TMyService.DebugServiceClose(Sender: TObject; var CanClose: Boolean);
begin
  if not Forms.Application.Terminated then
    DebugServiceClose2((Sender as TForm).FindComponent('DebugWindowsClose'));
end;

procedure TMyService.DebugServiceClose2(Sender: TObject);
begin
  if not ContainsText(TButton(Sender).Caption, 'Terminate') then begin
    //if Assigned(MyService) then
    //  MyService.Terminate;  // hier gibt es zwar ein Terminated, aber kein Terminate -> Status wird aus ServiceThread.Terminated geholt
    if Assigned(MyService) and Assigned(MyService.ServiceThread) then
      MyService.ServiceThread.Terminate;  // eigentlich aktuell nicht nötig, da im Debugmodus der Service-Thread nicht existiert/läuft -> siehe ServiceExecute(nil);
    Forms.Application.Terminate;
    TButton(Sender).Caption := 'Terminate (30s)';
  end else begin
    // Wenn der Apps nicht auf Terminate hören will, dann eben die harte Tour. (beim zweiten Klicken auf Close)
    TerminateProcess(GetCurrentProcess, 1);  // Halt() versucht noch die Units zu entladen, wobei es hängen bleiben kann.
    Halt(1);
  end;
end;

Kurzfassung:

Delphi-Quellcode:

procedure TMyService.ServiceCreate(Sender: TObject);  // TService.OnCreate
begin
  if IsDebuggerPresent or FindCmdLineSwitch('DEBUG', ['-', '/'], True) then begin
    MyService := Self;  // wird sonst von Application.CreateForm gesetzt, aber durch die MessageLoop kommt es dort nicht vorbei

    { wie SvcMgr.Application.Run; }
    if FindCmdLineSwitch('INSTALL', ['-', '/'], True) then
      TServiceApplicationAccess(SvcMgr.Application).RegisterServices(True, FindCmdLineSwitch('SILENT', ['-', '/'], True))
    else if FindCmdLineSwitch('UNINSTALL', ['-', '/'], True) then begin
      TServiceApplicationAccess(SvcMgr.Application).RegisterServices(False, FindCmdLineSwitch('SILENT', ['-', '/'], True))
    else begin
      Started := True;
      ServiceStart(Self, Started);
      if Started then begin
        ServiceExecute(nil);
        while not Terminated and not Forms.Application.Terminated do  // allerdings wird die Schleife ohne TForm sich eventuell vorzeitig beenden
          try
            Forms.Application.ProcessMessages;
            Sleep(10);
          except
            {error logging ...}
          end;
        Forms.Application.Terminate;
      end else
        Forms.Application.Terminate;
    end;
  end;
end;

[jaenicke]

Ich habe das mit dem Dienst auch mal gemacht, indem ich einfach geschaut habe, ob die Exe von der services.exe gestartet wurde. Wenn nicht, wurde ein Formular angezeigt, mit dem man den Installationsstatus sehen konnte und den Dienst auch z.B. installieren konnte.
Leider verhält sich aber ein Dienst nicht immer genauso, weshalb ich das Warten eingebaut habe, bis der Debugger dran hängt.

Aber das ist hier ja nicht das Thema.