AGB  ·  Datenschutz  ·  Impressum  







Anmelden
Nützliche Links
Registrieren

VCL Formular in ein Panel einbetten

Ein Thema von delphicoder123 · begonnen am 11. Jun 2019 · letzter Beitrag vom 12. Jun 2019
Antwort Antwort
Seite 2 von 3     12 3   
delphicoder123

Registriert seit: 14. Feb 2019
102 Beiträge
 
#11

AW: VCL Formular in ein Panel einbetten

  Alt 11. Jun 2019, 22:23
Hallo,

alt
Delphi-Quellcode:
procedure TForm1.FormCreate(Sender: TObject);
begin
  Form1 := TForm1.Create(Panel1);
neu
Delphi-Quellcode:
procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2 := TForm2.Create(Panel1);

Ich müsste noch mindestens einen Fehler haben. Zwar wird jetzt, dass Formular angezeigt aber das Form2 ist immer noch nicht im Panel von Form1. Gerne können auch andere antworten, wenn man die Antwort weiß.
Hier nochmal der aktuelle Code.

Code:
unit parent;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.ExtCtrls, child;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2 := TForm2.Create(Panel1);
  with Form2 do
    Parent := Panel1;
    Width := 500;
    Height := 500;
    Top := 10;
    Left := 10;
    Show;
end;

end.
Code:
unit child;

interface

uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;

type
  TForm2 = class(TForm)
    btnCalc: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Edit3: TEdit;
    Label1: TLabel;
    procedure btnCalcClick(Sender: TObject);
  private
    { Private-Deklarationen }
  public
    { Public-Deklarationen }
  end;

var
  Form2: TForm2;

implementation

{$R *.dfm}

procedure TForm2.btnCalcClick(Sender: TObject);
begin
edit3.Text:=edit1.Text+edit2.Text;
end;

end.
  Mit Zitat antworten Zitat
EWeiss
(Gast)

n/a Beiträge
 
#12

AW: VCL Formular in ein Panel einbetten

  Alt 11. Jun 2019, 22:30
Dann Debug doch mal das ganze.
Eventuell findest du den Fehler dann selbst.

gruss
  Mit Zitat antworten Zitat
Benutzerbild von uligerhardt
uligerhardt

Registriert seit: 19. Aug 2004
Ort: Hof/Saale
1.672 Beiträge
 
Delphi 2007 Professional
 
#13

AW: VCL Formular in ein Panel einbetten

  Alt 11. Jun 2019, 22:53
Außerdem: Wenn möglich, nimm Frames statt Forms, wenn du es einbetten willst.
Du meinst, dass ich ein VCL-Frame anstatt eines VCL Formular nehmen soll?
Genau. Das wäre meine erste Wahl, solange nichts Triftiges dagegenspricht.
Uli Gerhardt
  Mit Zitat antworten Zitat
Heuman
(Gast)

n/a Beiträge
 
#14

AW: VCL Formular in ein Panel einbetten

  Alt 11. Jun 2019, 23:04
Hallo,

falls ich es jetzt richtig verstanden. Dem Konstruktor 'self' übergeben.

procedure Tform1.FormCreate(Sender: TObject);
begin

Form2 := TForm2.Create(self);



with Form2 do
begin
Parent := Panel1;

Width := 500;
Height := 500;
Top := 10;
Left := 10;
Show;
end;
end;

Gruß

Geändert von Heuman (11. Jun 2019 um 23:10 Uhr) Grund: Fehler gefunden.
  Mit Zitat antworten Zitat
Benutzerbild von Uwe Raabe
Uwe Raabe

Registriert seit: 20. Jan 2006
Ort: Lübbecke
7.029 Beiträge
 
Delphi 10.3 Rio
 
#15

AW: VCL Formular in ein Panel einbetten

  Alt 11. Jun 2019, 23:26
Hier nochmal der aktuelle Code.
...
Code:
procedure TForm1.FormCreate(Sender: TObject);
begin
  Form2 := TForm2.Create(Panel1);
  with Form2 do
    Parent := Panel1;
    Width := 500;
    Height := 500;
    Top := 10;
    Left := 10;
    Show;
end;


Bei der with -Anweisung fehlt das begin/end .
Uwe Raabe
Certified Delphi Master Developer
Embarcadero MVP
Blog: The Art of Delphi Programming
  Mit Zitat antworten Zitat
hoika

Registriert seit: 5. Jul 2006
Ort: Magdeburg
7.249 Beiträge
 
Delphi XE4 Professional
 
#16

AW: VCL Formular in ein Panel einbetten

  Alt 12. Jun 2019, 06:20
Hallo,
eigentlich fehlt das begin end nicht, das with ist zu viel

Genau deshalb sollte man with vermeiden.

Was wäre z.B., wenn es das Show in TForm2 nicht geben würde?
Dann würde das Show von Form1 aufgerufen.
Da beide vom Typ TForm sind, klappt das hier (wenn begin/end da wären),
muss aber nicht.
Dumm wäre es, wenn es z.B. in TForm2 eine Methode Halt geben würde ...
Heiko
  Mit Zitat antworten Zitat
Benutzerbild von haentschman
haentschman

Registriert seit: 24. Okt 2006
Ort: Seifhennersdorf / Sachsen
4.249 Beiträge
 
Delphi 10.1 Berlin Professional
 
#17

AW: VCL Formular in ein Panel einbetten

  Alt 12. Jun 2019, 08:21
Zitat:
Genau deshalb sollte man with vermeiden.
+
  Mit Zitat antworten Zitat
Andreas L.

Registriert seit: 23. Mai 2011
Ort: Sulzbach-Rosenberg
256 Beiträge
 
Delphi 2009 Professional
 
#18

AW: VCL Formular in ein Panel einbetten

  Alt 12. Jun 2019, 09:08
So würde ich den Code formulieren:

Delphi-Quellcode:
unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, child;

type
  TForm1 = class(TForm)
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
  private
    // Feld für das Form anlegen
    FEmbeddedForm: TForm2;
  public
    { Public-Deklarationen }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
  // Das Form soll Form1 als Owner haben
  // deshalb wird Self angegeben.
  // Dadurch wird das Form automatisch freigegeben
  // wenn das Form1 gechlossen/freigegeben wird...
  FEmbeddedForm := TForm2.Create(Self);

  // Als Parent wird Panel1 verwendet.
  // Parent gibt an auf welchen Control
  // das Form platziert werden soll.
  FEmbeddedForm.Parent := Self.Panel1;

  // Ein paar Eigenschaften des Forms festlegen.
  // Ich würde eher Align verwenden.
  // Deshalb habe ich das auskommentiert...
  //FEmbeddedForm.Width := 500;
  //FEmbeddedForm.Height := 500;
  //FEmbeddedForm.Top := 10;
  //FEmbeddedForm.Left := 10;
  // Mit Align := alClient ist das Form
  // immer genau so groß wie das Panel1...
  FEmbeddedForm.Align := alClient;

  // Zu guter letzt das Form noch sichtbar machen
  FEmbeddedForm.Visible := True;
end;

end.
Wichtig: Form2 muss noch aus der Liste der automatisch zu erstellenden Formulare entfernt werden. Menü > Projekt > Optionen > Formulare > In der Liste links Form2 markieren und auf den ">"-Button klicken. Dann landet Form2 in der rechten Liste!

Geändert von Andreas L. (12. Jun 2019 um 09:13 Uhr)
  Mit Zitat antworten Zitat
EWeiss
(Gast)

n/a Beiträge
 
#19

AW: VCL Formular in ein Panel einbetten

  Alt 12. Jun 2019, 09:17
Frage mich was der Aufwand soll pack doch ne MDI Form rein und gut ist.
Warum da selbst was frickeln wenn man das unbedingt haben muss.

gruss
  Mit Zitat antworten Zitat
hoika

Registriert seit: 5. Jul 2006
Ort: Magdeburg
7.249 Beiträge
 
Delphi XE4 Professional
 
#20

AW: VCL Formular in ein Panel einbetten

  Alt 12. Jun 2019, 13:21
Hallo,
FEmbeddedForm ist nirgendwo definiert.

MDI:
Ich dachte, dass wäre tot?
(Obwohl das hier ja nach Wunsch genau das Richtige wäre.)
Heiko
  Mit Zitat antworten Zitat
Themen-Optionen Thema durchsuchen
Thema durchsuchen:

Erweiterte Suche
Ansicht

Forumregeln

Es ist dir nicht erlaubt, neue Themen zu verfassen.
Es ist dir nicht erlaubt, auf Beiträge zu antworten.
Es ist dir nicht erlaubt, Anhänge hochzuladen.
Es ist dir nicht erlaubt, deine Beiträge zu bearbeiten.

BB-Code ist an.
Smileys sind an.
[IMG] Code ist an.
HTML-Code ist aus.
Trackbacks are an
Pingbacks are an
Refbacks are aus

Gehe zu:

Impressum · AGB · Datenschutz · Nach oben
Alle Zeitangaben in WEZ +1. Es ist jetzt 23:46 Uhr.
Powered by vBulletin® Copyright ©2000 - 2019, Jelsoft Enterprises Ltd.
LinkBacks Enabled by vBSEO © 2011, Crawlability, Inc.
Delphi-PRAXiS (c) 2002 - 2019 by Daniel R. Wolf